Позиція піктограм на робочому столі зліва замість правої

Будь-який спосіб автоматично зробити псевдонім або піктограми, які відображатимуться в лівій частині яблучного робочого столу. За замовчуванням вони йдуть праворуч.

Немає способу змусити піктограми автоматично переходити ліворуч (і залишатись упорядкованим за критерієм, який ви вибрали).

Як вирішення, ви можете змінити параметри перегляду в Finder, щоб не упорядкувати елементи за будь-яким критерієм і розмістити піктограми вручну зліва.

• Клацніть на порожньому місці на робочому столі.
• Натисніть Cmd+ Jабо скористайтесь мишкою, щоб перейти до меню «Пошук» > «Показати параметри перегляду ».
• У спадному меню " Сортувати за:" виберіть " Ні" або " Прив’язати до сітки" .
• Ви зможете видаляти файли будь-де на робочому столі, і вони там залишатимуться.

Див. Основи Mac: Змінення вікон для отримання додаткової інформації.

Також перейдіть на сторінки Основи Mac, щоб дізнатися більше про використання Mac.

Це не найкраще рішення, але воно може працювати, якщо нічого іншого не робити ...

1. Створіть дію папки автоматизатора, пов’язану з робочим столом.
2. Додати елемент: "запустити яблучний сценарій"

3. Вставте наступний код у текстове поле яблучного сценарію:

   -- https://gist.github.com/mrienstra/8330528
   -- Based on http://www.tuaw.com/2012/12/24/applescript-desktop-icon-race/
   -- Inspired by http://namesakecomic.com/comic/happy-new-year-from-namesake/#comment-1182035013
   
   -- Rearranges Desktop icons to flow from left to right, top to bottom.
   
   -- To have this run automatically every time files are added or removed from the Desktop, set this script to run as a Desktop "Folder Action". (See https://developer.apple.com/library/mac/documentation/applescript/conceptual/applescriptlangguide/reference/ASLR_folder_actions.html )
   
   -- This is currently a rough proof-of-concept. It has only been tested with OS X 10.8.5 (Mountain Lion).
   
   -- Current known limitations: Does not work with "Label position" set to "Right" (specifically, icons will overlap).
   
   
   
   -- Adjust these for different spacing
   property theSpacingFactor : 1.0
   property theGutterXFactor : 0.57
   property theGutterYFactor : 0.57
   
   
   
   on rearrangeDesktopIcons()
       tell application "Finder"
           tell icon view options of window of desktop
               set theArrangement to arrangement
               set theArrangementString to theArrangement as string
               if {"not arranged", "«constant ****narr»", "snap to grid", "«constant ****grda»"} does not contain theArrangementString then
                   display alert "\"Rearrange Desktop Icons\" AppleScript says:" message "Cannot rearrange Desktop items, please change Desktop \"Sort by\" to \"None\" or \"Snap to Grid\"." giving up after 10
                   return
               end if
               set theIconSize to icon size
               set theLabelSize to text size
           end tell
   
           set theDesktopBounds to bounds of window of desktop
           set theDesktopWidth to item 3 of theDesktopBounds
           set theDesktopHeight to item 4 of theDesktopBounds
   
           -- Retrieve a list of items on the desktop
           set theDesktopItems to every item of desktop
           set theContestantOffset to theIconSize / 2
   
           set theSpacing to (theIconSize + theLabelSize + theContestantOffset) * theSpacingFactor
           set theGuttersX to theSpacing * theGutterXFactor
           set theGuttersY to theSpacing * theGutterYFactor
           set theMaxColumns to ((theDesktopWidth - theGuttersX * 2) / theSpacing) as integer
           set theMaxRows to ((theDesktopHeight - theGuttersY * 2) / theSpacing) as integer
           set theMaxLocations to theMaxRows * theMaxColumns
   
           set y to 1
           repeat with a from 1 to length of theDesktopItems
               set x to a mod theMaxColumns
               if x is 0 then
                   set x to theMaxColumns
               end if
   
               if a is greater than theMaxLocations then
                   set desktop position of item a of theDesktopItems to {theGuttersX, theGuttersY}
               else
                   set desktop position of item a of theDesktopItems to {theGuttersX + (x - 1) * theSpacing, theGuttersY + (y - 1) * theSpacing}
               end if
   
               if a mod theMaxColumns is 0 then
                   set y to y + 1
               end if
           end repeat
       end tell
   end rearrangeDesktopIcons
   
   
   
   on adding folder items to alias after receiving listOfAlias
       rearrangeDesktopIcons()
   end adding folder items to
   
   on removing folder items from alias after losing listOfAliasOrText
       rearrangeDesktopIcons()
   end removing folder items from
   
   rearrangeDesktopIcons()
   

Отже, коли файл додається на робочий стіл, усі файли будуть переставлені в алфавітному порядку ...

Впорядкуйте всі папки в тому порядку, в якому ви їх бажаєте. Потім під переглядом "Очистити". Це добре вирівняє все. Тоді ви можете просто виділити всі папки і розташувати їх саме там, де вам потрібно. Маки не впорядковують папки зліва, а праворуч, але за допомогою декількох простих кроків ви можете зробити все чітко організовано зліва.

Я просто виділив усі папки з правого боку, потім схопив їх усі і встав ліворуч.