Будь-який спосіб встановити / додати теги у файл із Applescript під Mavericks?

9

Намагаюся перенести деякі мої сценарії з міток на теги під Mavericks, але я не можу знайти спосіб встановити / додати теги з Applescript.

Хто-небудь, хто знає, як це зробити? Наскільки я можу зрозуміти, теги насправді не нові, а лише нові з точки зору того, що вони є центральною частиною оновленого Finder.

applescript mavericks

— Крістіан А. Стрьоммен
джерело

7

Можна використовувати xattr. Це копіює теги з файлу1 у файл2:

xattr -wx com.apple.metadata:_kMDItemUserTags "$(xattr -px com.apple.metadata:_kMDItemUserTags file1)" file2
xattr -wx com.apple.FinderInfo "$(xattr -px com.apple.FinderInfo file1)" file2

Теги зберігаються у списку властивостей як єдиний масив рядків:

$ xattr -p com.apple.metadata:_kMDItemUserTags file3|xxd -r -p|plutil -convert xml1 - -o -
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<array>
    <string>Red
6</string>
    <string>aa</string>
    <string>Orange
7</string>
    <string>Yellow
5</string>
    <string>Green
2</string>
    <string>Blue
4</string>
    <string>Purple
3</string>
    <string>Gray
1</string>
</array>
</plist>

Теги для кольорів мають такі значення, як Red\n6(де \nє стрічковий канал).

Якщо прапор kColor у com.apple.FinderInfo не встановлений, Finder не показує кола для кольорів поруч із файлами. Якщо для прапора kColor встановлено помаранчевий колір, а файл має червоний тег, Finder показує червоні та оранжеві кола. Ви можете встановити прапор kColor за допомогою AppleScript:

do shell script "xattr -w com.apple.metadata:_kMDItemUserTags '(\"Red\\n6\",\"new tag\")' ~/desktop/file4"
tell application "Finder" to set label index of file "file4" of desktop to item 1 of {2, 1, 3, 6, 4, 5, 7}

'("Red\n6","new tag")' це синтаксис плістів старого стилю для цього:

<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE plist PUBLIC "-//Apple//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
<plist version="1.0">
<array>
    <string>Red
6</string>
    <string>new tag</string>
</array>
</plist>

xattr -p com.apple.FinderInfo file|head -n1|cut -c28-29друкує значення бітів, використаних для прапора kColor. Червоний - це C, помаранчевий - E, жовтий - A, зелений - 4, синій - 8, пурпурний - 6, а сірий - 2. (Прапор, який додав би значення 1, не використовується в OS X.)

— Лрі
джерело

це "зображення зображень" .PNG або кольорова графіка? не вдалося знайти щось на кшталт "C.png" на жорсткому диску :)

1

Відповідь розміщено у списку користувачів Applescript:

http://lists.apple.com/archives/applescript-users/2015/Jan/msg00193.html

цитата зі сторінки - код, написаний Шейн Стенлі

Ви можете зробити це досить легко за допомогою AppleScriptObjC. Ось обробники для отримання тегів, встановлення тегів та додавання тегів:

use scripting additions
use framework "Foundation"

on returnTagsFor:posixPath -- get the tags
    set aURL to current application's |NSURL|'s fileURLWithPath:posixPath -- make URL
    set {theResult, theTags} to aURL's getResourceValue:(reference) forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
    if theTags = missing value then return {} -- because when there are none, it returns missing value
    return theTags as list
end returnTagsFor:

on setTags:tagList forPath:posixPath -- set the tags, replacing any existing tags
    set aURL to current application's |NSURL|'s fileURLWithPath:posixPath -- make URL
    aURL's setResourceValue:tagList forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
end setTags:forPath:

on addTags:tagList forPath:posixPath -- add to existing tags
    set aURL to current application's |NSURL|'s fileURLWithPath:posixPath -- make URL
    -- get existing tags
    set {theResult, theTags} to aURL's getResourceValue:(reference) forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
    if theTags ≠ missing value then -- add new tags
        set tagList to (theTags as list) & tagList
        set tagList to (current application's NSOrderedSet's orderedSetWithArray:tagList)'s allObjects() -- delete any duplicates
    end if
    aURL's setResourceValue:tagList forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
end addTags:forPath:

Якщо ви збережете їх у бібліотеці сценаріїв, ви також можете використовувати їх у Mavericks.

- Шейн Стенлі www.macosxautomation.com/applescript/apps/

— бранделун
джерело