Я в основному використовую цю функцію:
cf() {
cd "$(osascript -e 'tell app "Finder" to POSIX path of (insertion location as alias)')"
}
Ви також можете призначити ярлик такому сценарію, як наведений нижче.
Використовуйте повторно існуючу вкладку або створіть нове вікно (Термінал):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if (exists window 1) and not busy of window 1 then
do script "cd " & quoted form of p in window 1
else
do script "cd " & quoted form of p
end if
activate
end tell
Використовуйте повторно існуючу вкладку або створіть нову вкладку (Термінал):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if not (exists window 1) then reopen
activate
if busy of window 1 then
tell application "System Events" to keystroke "t" using command down
end if
do script "cd " & quoted form of p in window 1
end tell
Завжди створюйте нову вкладку (iTerm 2):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "iTerm"
if exists current terminal then
current terminal
else
make new terminal
end if
tell (launch session "Default") of result to write text "cd " & quoted form of p
activate
end tell
Перші два сценарії мають кілька переваг порівняно з послугами, доданими в 10.7:
- Станом на 10.9 є помилка, коли служби, які отримують папки як вхідні дані, ніколи не відображаються в меню послуг у режимі перегляду стовпців. Якщо ви присвоїли вкладці Новий термінал у службі «Папка» клавіатурний ярлик, він не працює в режимі перегляду стовпців.
- Вони використовують папку в рядку заголовка, а не вимагають, щоб ви спочатку обрали папку.
- Вони використовують повторно передню вкладку, якщо вона не зайнята, наприклад, виконайте команду, відображайте довідкову сторінку або запускаєте emacs.
Якщо ви використовуєте 10,7 або 10,8, змініть tell application "Finder" to set p to POSIX path of (insertion location as alias)на:
tell application "Finder"
if exists Finder window 1 then
set p to POSIX path of (target of Finder window 1 as alias)
else
set p to POSIX path of (path to desktop)
end if
end tell
Існує помилка в 10,7 та 10,8 (але не в 10,9 або 10,6), де Finder ігнорує вікна, створені після того, як востаннє фокус було переміщено до іншої програми та назад при отриманні insertion locationвласності.
