Відображення гарячих клавіш прихованих файлів на Mavericks зникло?

У попередніх версіях OS X можна було відобразити приховані файли в діалоговому вікні Finder (Відкрити, Зберегти тощо) за допомогою Command-Shift-Period.

У Mavericks ця функція не працює для мене. Чи є інша команда, яку можна використовувати? Я вважаю за краще не вмикати глобально приховані файли.

EDIT: Я пропоную щедроту. Здається, я не можу коментувати, тому що зараз мені не вистачає реп. :)

Отже ... так, я також бігаю 10.9.1 і це не працює. Я використовував його в попередніх версіях OSX, і він працював чудово. Згаданий сценарій в порядку, щоб показати приховані файли в Finder, але він не працює так добре, коли використовується діалогове вікно відкриття / збереження.

Мій випадок використання: іноді мені потрібно відкрити / зберегти файли до /tmpкаталогу. У попередніх версіях OSX я просто використовував діалогове вікно, щоб дістатися до кореня диска, а потім натиснути, CommandShift.і тоді я зміг побачити /tmpкаталог (власне /private/tmp).

Отже, якщо ви, хлопці, використовуєте ту саму версію OSX, і вона спрацьовує для вас, я думаю, має бути спосіб повторно активувати це. Будь-які ідеї?

Ключові прив’язки не працюють у режимі перегляду стовпців на Maverick, але вони працюють, наприклад, у режимі перегляду списку. Після повернення до режиму перегляду стовпців після перемикання в режимі перегляду списку відображаються приховані файли.

Зараз я запускаю OS X (10.9.1) і просто спробував комбінацію клавіш ⌘+ ⇧+ .у діалоговому вікні збереження, і він працював чудово.

Я також налаштував AppleScript на своїй машині за допомогою комбінації клавіш ^+ ⌘+ ⇧+, .яка перемикає видимість прихованих файлів у Finder, коли я захочу. Таким чином, мені не потрібно вручну запускати команду термінала для показу прихованих файлів, і я можу швидко вимкнути її, щоб уникнути випадкових змін системних файлів. Я використовую FastScripts (також доступний у магазині додатків Mac ), щоб дозволити мені встановити ярлик клавіатури для свого AppleScript і помістити AppleScript у свою ~/Library/Scriptsпапку.

Оновлення

Я оновив свій сценарій, щоб Finder не потрібно вбивати кожен раз, коли ви хочете показати / приховати відображення прихованих файлів. Як зазначив markhunte, ви можете переключити стан перегляду вікна Finder, що оновить список вмісту. Дякую markhunte, що вказали на мене! Ось оновлений сценарій:

(*
    Author: Anil Natha
    Description: 
        This script toggles the visibility of hidden files in OS X. This includes
        showing hidden files in Finder windows and on the desktop.
    Last Updated: 2015-02-20
*)
tell application "System Events"

    try
        set hiddenFilesDisplayStatus to do shell script "defaults read com.apple.finder AppleShowAllFiles"
    on error
        set hiddenFilesDisplayStatus to "NO"
    end try
    set hiddenFilesNewDisplayStatus to "NO"

    if hiddenFilesDisplayStatus is "NO" then
        set hiddenFilesNewDisplayStatus to "YES"
    end if

    do shell script "defaults write com.apple.finder AppleShowAllFiles " & hiddenFilesNewDisplayStatus

end tell

tell application "Finder"

    set allWindows to windows

    repeat with currentWindow in allWindows
        set currentWindowView to get the current view of the currentWindow
        set alternateWindowView to list view
        if currentWindowView is list view then
            set alternateWindowView to icon view
        end if
        set the current view of the currentWindow to alternateWindowView
        set the current view of the currentWindow to currentWindowView
    end repeat

end tell

Старіша версія сценарію наведена нижче. Хоча він працює, я не рекомендую більше використовувати його тепер, коли вищезазначений сценарій працює більш ефективно.

tell application "System Events"

    set hiddenFilesDisplayStatus to do shell script "defaults read com.apple.finder AppleShowAllFiles"
    set hiddenFilesNewDisplayStatus to "NO"

    if hiddenFilesDisplayStatus is "NO" then
        set hiddenFilesNewDisplayStatus to "YES"
    end if

    do shell script "defaults write com.apple.finder AppleShowAllFiles " & hiddenFilesNewDisplayStatus
    do shell script "killall Finder"

end tell

Ніколи не знав, що ця особливість існує. Але тоді я завжди використовував інший спосіб, який все ще працює в 10,9:

Системне розширення Folder X за замовчуванням . Це стара смакота, і досі добре працює.

Один з його додаткових варіантів - утримувати Optionпри виборі Відкрити / Зберегти тощо, щоб показати всі файли, включаючи приховані.

Це все ще працює, але для мене це було баггі.

Мені довелося змінити каталоги, а потім повернутися до першої папки. Потім він відображав приховані файли.

Це не допомагає закрити / повторно відкрити діалогове вікно. Я не впевнений, наскільки поширена помилка чи що може бути спусковим гачком (у цього ноутбука менше 48 годин поза коробкою).

Ярлик ⌘⇧. як і раніше добре працює для мене в Mavericks. Схоже, це не було змінено з попередніх версій ОС X.

Деякі речі, які ви можете спробувати ...

• Переконайтеся, що в папці, яку ви переглядаєте, є приховані файли / папки.

  • Ви можете використовувати lsв Terminal, щоб побачити, чи є приховані файли / папки:

    cd /path/to/folder && ls -la
    

• Переконайтеся, що ви не переробили ярлик на щось інше.

  • Перевірте Налаштування системи → Клавіатура → Ярлики для будь-яких відображень до ⌘⇧.
  • Перевірте будь ^-які додатки ^{третьої} партії, щоб вони відобразили відображення на ⌘⇧.

Як багато хто казав, він все ще працює чудово. Можливо, ви змінили ярлик до цього, і це маскує ваше передбачуване завдання - показати приховані файли.

Це не є рішенням гарячої клавіші, але я поділюсь тим, що використовую для цього завдання. Весела програма

Ви можете увімкнути його за замовчуванням, виконавши цю команду Terminal:

defaults write com.apple.finder AppleShowAllFiles -boolean true
killall Finder

... але це менш ніж зручно порівняно з комбінацією клавіш ... але ви можете створити робочий процес Автоматизатора, який запускає службу, яка виконує команду Термінал, всі призначені для клавіатурної комбінації системних налаштувань ..., але все ж не так зручно.