Змініть ім'я за замовчуванням "Нова папка"

Коли ми створимо «нову папку» у пошуку, вона автоматично отримає назву «папка без назви».

Чи можна змінити назву папки за замовчуванням на назву поточної дати, наприклад "20151223"?

За допомогою AppleScript ви можете це досягти.

Відкрийте редактор AppleScript, створіть новий документ і вставте наступні викрадені рядки:

tell application "Finder"
    try
        if exists Finder window 1 then
            set thisPath to (the target of the front window) as alias
        else
            set thisPath to (path to desktop)
        end if
    on error
        return
    end try
end tell
set x to my the_perfect_datestring()
if x is not "-ERROR" then
    set fullPath to thisPath & x as text
    tell application "Finder"
        try
            --activate
            if not (exists fullPath) then
                set y to make new folder at thisPath with properties {name:x}
            end if
            activate
            open y
        end try
    end tell
end if
on the_perfect_datestring()
    try
        set cd to (the current date)
        set the_year to year of (cd) as number
        set the_month to month of (cd) as number
        set the_day to day of (cd) as number
        if the_month < 10 then set the_month to "0" & the_month
        if the_day < 10 then set the_day to "0" & the_day
        return ((the_year & the_month & the_day) as string)
    on error
        return "-ERROR"
    end try
end the_perfect_datestring

Збережіть файл як програму AppleScript (наприклад, DateFolder.app) десь (наприклад, ~ / Applications).

Відкрийте папку та опустіть на панель інструментів DateFolder.app:

Щоб створити папку у відкритій папці, просто натисніть значок програми на панелі інструментів. Нова папка відкриється автоматично. Видаліть рядок 22 у скрипті ( open y), якщо ви не хочете, щоб нова папка була відкрита. Якщо ви додасте додаток у док-станцію і відкриєте його, воно створить нову папку в передній папці або на робочому столі (якщо папка не відкрита).

Тестується лише в Mac OS X 10.7.5. Лев!

Щоб додати дефіс і поточний час, додайте наступні рядки (замінюючи рядок 32-34 у сценарії вище):

        set the_hour to hours of (cd) as number
        set the_minute to minutes of (cd) as number
        set the_second to seconds of (cd) as number
        if the_month < 10 then set the_month to "0" & the_month
        if the_day < 10 then set the_day to "0" & the_day
        if the_hour < 10 then set the_hour to "0" & the_hour
        if the_minute < 10 then set the_minute to "0" & the_minute
        if the_second < 10 then set the_second to "0" & the_second
        return ((the_year & the_month & the_day & "-" & the_hour & the_minute & the_second) as string)