Скопіюйте оригінал, перетягуючи псевдонім

У мене є папка, повна псевдоніму з будь-якої точки моєї системи. Тепер я хочу надати саме ці файли як оригінали зовнішньому жорсткому диску або іншому.

Чи є спосіб просто взяти ці псевдоніми та скопіювати їх оригінали у другу папку?

Я склав трохи AppleScript для вас. Якщо ви використовуєте редактор сценаріїв, щоб зберегти його як аплет, ви можете перетягувати папки на нього. Сценарій спочатку запитає папку призначення, а потім сканує випалі папки на наявність будь-яких псевдонімів. Якщо він знайде який-небудь, він скопіює оригінальні елементи у вказану папку призначення.

Ось код:

on open droppedItems
    try
        set destinationFolder to choose folder with prompt "Select destination folder:"
    on error
        return
    end try

    repeat with itemCount from 1 to length of droppedItems
        set theFolder to item itemCount of droppedItems

        tell application "Finder"
            if folder (theFolder as string) exists then
                set folderItems to list folder theFolder without invisibles

                repeat with folderItemCount from 1 to length of folderItems
                    set filename to (item folderItemCount of folderItems)
                    set theAlias to ((theFolder as text) & filename) as alias
                    try
                        set originalFile to original item of theAlias -- is Finder alias?
                        duplicate originalFile to destinationFolder
                    on error
                        display dialog (theAlias as string) & " doesn't seem to be an alias. Skipping."
                    end try
                end repeat
            else
                display dialog (theFolder as string) & "is not a folder. Skipping."
            end if
        end tell
    end repeat
end open

Це ні гарненька, ні функція повноцінна, а скоріше призначена показати вам можливий шлях. І. е. він не обходить жодних папок. Крім того, перед копіюванням не перевіряється наявність файлу. У будь-якому випадку це все одно може бути те, що вам потрібно. Веселіться!