Apple Script - надішліть (вставте скріншот із буфера обміну?) Та theTime до imessagebuddy

У мене є робочий процес автоматизатора, починаючи з "Зробити скріншот", щоб зробити знімок екрана та вставити у буфер обміну.

Слідом за цим у мене є

set theTime to time string of (current date)

tell application "Messages"
    set iMessageService to 1st service whose service type = iMessage
    set imessagebuddy to buddy "imessagebuddy@domain.com" of iMessageService
    send theTime to imessagebuddy
end tell

Я хочу включити скріншот у повідомлення з часом.

mac applescript automator

— Томас
джерело

Хоча можна вручну вставити або використовувати сценарій користувальницького інтерфейсу, щоб вставити зображення з буфера обміну в додаток Повідомлення, якщо ви хочете це робити програмно без сценарію користувальницького інтерфейсу, і повірте, ви не хочете використовувати для цього сценарій інтерфейсу, тоді вміст зображення з буфера обміну потрібно записати на файл диска, який потрібно надіслати у Messages. Це може бути тимчасовий файл, але для його надсилання все одно потрібно бути на диску, а не в буфері обміну.

— користувач3439894

Ось спосіб зняти скріншот із буфера обміну та надіслати його в Повідомленнях .

Приклад коду AppleScript :

if ((clipboard info) as string) contains JPEG picture then

    set jpgData to the clipboard as JPEG picture        
    set fileName to "/tmp/IMG_" & (random number from 1000 to 9999) & ".JPG" as string

    try
        set thisFile to open for access POSIX file fileName with write permission
        write jpgData to thisFile
        close access thisFfile
    on error
        close access thisFile
        return
    end try

    set theTime to time string of (current date)
    set thePicture to POSIX file fileName as alias

    tell application "Messages"
        set iMessageService to 1st service whose service type = iMessage
        set imessagebuddy to buddy "imessagebuddy@domain.com" of iMessageService
        send theTime to imessagebuddy
        send thePicture to imessagebuddy
    end tell

    tell application "System Events"
        delete alias fileName
    end tell

end if

Примітка . Приклад коду AppleScript - це саме те, що не використовує жодних інших способів обробки помилок, ніж те, що показано, і призначений лише для показу одного з багатьох способів виконання завдання. Користувач завжди зобов’язаний додавати / використовувати відповідне поводження з помилками, якщо потрібно / хотілося.

— користувач3439894
джерело