Чи є спосіб відображення AppleScript у меню?

Перш ніж читати далі: я знаю про butler та подібні програми. Я шукаю BUILT-IN спосіб зробити це без сторонньої програми.

У всякому разі, я написав AppleScript, який виконує команду shell. Я хочу відобразити цей вихід у меню вгорі ... без Батлера, як це зробити?

Взагалі, без сторонньої програми, такої як Growl, не існує побудованого способу зробити це.

Однак ви можете написати сценарій або іншу програму, таку, яку я знайшов тут, яка надає послугу меню. Я впевнений, що інтеграцію Гроула було б набагато простіше здійснити.

Не існує вбудованого способу зробити це в OS X. Однак, використовуючи Growl , ви можете отримувати сповіщення. Ось зразок сценарію для цього:

--Make sure Growl is running
tell application "System Events"
    set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
end tell

if isRunning then
    tell application id "com.Growl.GrowlHelperApp"
        set the allNotificationsList to ¬
            {"Test Notification", "Another Test Notification"}
        --Notifications can be enabled in System Preferences>Growl>Applications>Display Options
        set the enabledNotificationsList to ¬
            {"Test Notification"}
        register as application ¬
            "Growl AppleScript Sample" all notifications allNotificationsList ¬
            default notifications enabledNotificationsList ¬
                    -- Set the icon. You can use any icon from any application
            icon of application "AppleScript Editor"

        notify with name ¬
            "Test Notification" title ¬
            "Test Notification" description ¬
            "This is a test AppleScript notification." application name "Growl AppleScript Sample"

        notify with name ¬
            "Another Test Notification" title ¬
            "Another Test Notification :) " description ¬
            "Alas — you won't see me until you enable me..." application name "Growl AppleScript Sample"

    end tell
end if

Це повинно відображати це:

І якщо у вас також увімкнено інше сповіщення:

Тут описані більш досконалі методи .

Оскільки AppleScriptObjC є частиною macOS, можна використовувати його "Фонд" (включаючи методи NSMenu), щоб досягти того, що, ймовірно, було неможливо в 2012 році.

Я знайшов цікавий сценарій для створення власних меню з AppleScript; з цього я витягнув відповідний код для розміщення тексту в рядку меню macOS . Насправді він використовує лише "назву" меню для вставки деякого вмісту.

Для того, щоб продемонструвати це, я реалізував дуже базовий діалоговий скрипт, який просить користувачів вводити текст (чекаючи 6 сек.), Який потім тимчасово відображається на панелі меню (5 сек.).
Ось:

use framework "Foundation"
use framework "AppKit"
use scripting additions
property StatusItem : missing value
property newMenu : class "NSMenu"

display dialog "Write something:" default answer "" giving up after 6
set myText to text returned of the result
if myText is "" then set myText to "TOOOOO slow … try again !"
set myText to ">>    " & myText & "    <<"

set bar to current application's NSStatusBar's systemStatusBar
set StatusItem to bar's statusItemWithLength:-1.0
StatusItem's setTitle:myText
set newMenu to current application's NSMenu's alloc()'s initWithTitle:"Custom"
StatusItem's setMenu:newMenu

delay 5
current application's NSStatusBar's systemStatusBar()'s ¬
        removeStatusItem:StatusItem  

Цей код AppleScript можна використовувати в будь-якому вашому сценарії. (Його "діалогова" частина необов'язкова ...)

user3439894 допоміг закрити моє "меню", дивіться останній рядок сценарію. Дуже дякую!