Як відкрити файл DMG, як змусити його відкритись перед вікнами?

Щоразу, коли я завантажую .dmgфайл, а потім відкриваю його (як правило, з панелі завантаження в Chrome), він відкривається у фоновому режимі. Чи є спосіб, щоб він відкрився перед моїм вікном?

Редагувати

Для уточнення: я хочу, щоб вікно DMG з'являлося як активне вікно.

Я створив сценарій дій папки в Applescript, який може робити саме те, що ви хочете. Скопіюйте та вставте його в новий Applescript і збережіть його як додаток (без початку діалогу!) У "/ Бібліотека / Сценарії / Сценарії дій папок /". Потім ви можете приєднати її до будь-якої папки (швидше за все, до своєї папки ~ / Downloads / folder), клацнувши правою кнопкою миші на папці та вибравши "Налаштувати дії з папками" у спадному меню служб. Активуйте дії з папками та дозвольте скрипту дивитися папку.

Те, що в основному робить сценарій, - це реагувати на елементи, що потрапляють у папку, до якої він доданий, і якщо випадаючий елемент має вигляд: "Зображення", він додає Зображення як об'єм через інструмент командного рядка "hdiutil".

Ви можете налаштувати його поведінку, встановивши OpenWindow та зробивши властивості FFestmost у сценарії; це також можна зробити, двічі клацнувши по сценарію, після того як ви збережете його як додаток - він запитає в двох діалогах про те, якою має бути стандартна поведінка.

Я сподіваюся, що це допомагає,

Асмус

 property openWindow : true
 property makeFrontmost : true

 on run

    display dialog "Do you want to bring the Finder to the front after new items are added?" buttons {"Don't Activate", "Activate"} default button 2
    if the button returned of the result is "Don't Activate" then
        set makeFrontmost to false
    else
        set makeFrontmost to true
    end if


    display dialog "Open Folder after adding new files?" buttons {"Don't Open", "Open"} default button 2
    if the button returned of the result is "Don't Open" then
        set openWindow to false
    else
        set openWindow to true
    end if


 end run

 on adding folder items to thisFolder after receiving addedItems

    repeat with i from 1 to number of items in addedItems
        set itemKind to the kind of (info for item i of addedItems) as string

        if itemKind is "Disk Image" then
            set itemPath to (quoted form of POSIX path of item i of addedItems)
            try
                showImage(itemPath)
            end try
        end if

    end repeat

 end adding folder items to


 on showImage(itemPath)

    set volumeMountpointInfo to do shell script "/usr/bin/hdiutil  attach " & itemPath & " | grep Volumes"


    if (openWindow is true) then
        if (makeFrontmost is true) then
            tell application "Finder" to activate
        end if

       set currentDelim to text item delimiters
       set text item delimiters to tab

       set volumeMountpoint to POSIX file (text item 3 of volumeMountpointInfo)

       set text item delimiters to currentDelim

       tell application "Finder" to open folder volumeMountpoint

    end if

 end showImage

====

другий Applescript для визначення виду файлу, що потрапив у папку

On adding folder items to thisFolder after receiving addedItems
repeat with i from 1 to number of items in addedItems
    set itemKind to the kind of (info for item i of addedItems) as string
    display dialog itemKind
end repeat
end adding folder items to

Відредаговані потреби повинні бути "зображеннями диска", а не "зображеннями"

З того, що я можу сказати, OS X автоматично відображатиме вміст зображення диска лише у тому випадку, коли він є лише для читання. На це вказує олівець з косою рисою в нижній лівій частині вікна Finder під час перегляду вмісту зображення.

Якщо ви хочете змінити образ диска, щоб він це зробив, ви можете зробити наявне зображення диска лише для читання за допомогою Disk Utility. На жаль, це не змінить поведінку щодо неправильно створених зображень, які ви можете завантажити з Інтернету.

1. Змонтуйте зображення диска, яке ви хочете автоматично відкрити.
2. Відкрийте утиліту Disk, шукаючи її за допомогою прожектора.
3. Виберіть піктограму «Нове зображення» на панелі інструментів.
4. Назвіть файл і виберіть "лише для читання" у розділі "Формат зображення".
5. Натисніть "Зберегти". Коли ви змонтуєте це нове зображення, воно автоматично відкриється вікно Finder.

Це, мабуть, також недостатньо відповідає на питання, але ...

Якщо ви натиснете команду і натисніть на елемент на панелі завантаження, він відобразить елемент у пошуку. Після цього, просто натиснувши команду-O (або двічі клацнувши файл dmg), змонтуєте її та відкриєте у новому вікні на передньому плані.