Як розділити вхідний рядок?

Я надсилаю перелік сервісних позицій через послідовне з'єднання в arduino у наступному форматі

1:90&2:80&3:180

Який би розбирався як:

servoId : Position & servoId : Position & servoId : Position

Як би я розділив ці значення вгору і перетворив їх на ціле число?

Всупереч іншим відповідям, я б не пішов з Stringтаких причин:

• динамічне використання пам'яті (що може швидко призвести до роздроблення купи та виснаження пам'яті )
• досить повільний через операторів будівництва / руйнування / присвоєння

У вбудованому середовищі, як Arduino (навіть у Мега, яка має більше SRAM), я б краще використовувати стандартні функції C :

• strchr(): пошук символу в рядку C (тобто char *)
• strtok(): розділяє рядок C на підрядки на основі символу роздільника
• atoi(): перетворює рядок C у int

Це призведе до наступного зразка коду:

// Calculate based on max input size expected for one command
#define INPUT_SIZE 30
...

// Get next command from Serial (add 1 for final 0)
char input[INPUT_SIZE + 1];
byte size = Serial.readBytes(input, INPUT_SIZE);
// Add the final 0 to end the C string
input[size] = 0;

// Read each command pair 
char* command = strtok(input, "&");
while (command != 0)
{
    // Split the command in two values
    char* separator = strchr(command, ':');
    if (separator != 0)
    {
        // Actually split the string in 2: replace ':' with 0
        *separator = 0;
        int servoId = atoi(command);
        ++separator;
        int position = atoi(separator);

        // Do something with servoId and position
    }
    // Find the next command in input string
    command = strtok(0, "&");
}

Перевага тут у тому, що не відбувається динамічного розподілу пам'яті; можна навіть оголосити inputлокальну змінну всередині функції, яка б читала команди та виконувала їх; Після повернення функції inputвідновлюється розмір, зайнятий (у стеку).

Ця функція може бути використана для відокремлення рядка на шматки, виходячи з того, що є роздільним символом.

String xval = getValue(myString, ':', 0);
String yval = getValue(myString, ':', 1);

Serial.println("Y:" + yval);
Serial.print("X:" + xval);

Перетворити рядок до int

int xvalue = stringToNumber(xval);
int yvalue = stringToNumber(yval);

Цей фрагмент коду бере рядок і відокремлює його на основі заданого символу і повертає елемент між роздільним символом

String getValue(String data, char separator, int index)
{
    int found = 0;
    int strIndex[] = { 0, -1 };
    int maxIndex = data.length() - 1;

    for (int i = 0; i <= maxIndex && found <= index; i++) {
        if (data.charAt(i) == separator || i == maxIndex) {
            found++;
            strIndex[0] = strIndex[1] + 1;
            strIndex[1] = (i == maxIndex) ? i+1 : i;
        }
    }
    return found > index ? data.substring(strIndex[0], strIndex[1]) : "";
}

Ви можете зробити щось подібне, але врахуйте кілька речей:

Якщо ви використовуєте readStringUntil(), він буде чекати, поки він не отримає символу або таймаути. Таким чином, у вашому поточному рядку остання позиція триватиме трохи довше, оскільки її потрібно чекати. Ви можете додати трейлінг, &щоб уникнути цього тайм-ауту. Ви можете легко перевірити цю поведінку на своєму моніторі, спробувати надіслати рядок з додатковими та без них, &і ви побачите таку затримку очікування.

Ви на самому справі не потрібен індекс серво, ви можете просто відправити рядок позицій, і отримати індекс серво по позиції значення в рядку, що - щось на кшталт: 90&80&180&. Якщо ви використовуєте серво-індекс, можливо, ви хочете перевірити його (перетворити на int, а потім відповідати циклу i), щоб переконатися, що з вашим повідомленням нічого не пішло.

Ви повинні перевірити, що рядок, що повертається readStringUntil, не порожній. Якщо час очікування функції, ви не отримали достатньо даних, і, отже, будь-яка спроба вилучення ваших intзначень дасть дивні результати.

void setup() {
    Serial.begin(9600);
}

void loop() {
    for(int i=1; i<=3; i++) {
        String servo = Serial.readStringUntil(':');
        if(servo != ""){
            //here you could check the servo number
            String pos = Serial.readStringUntil('&');
            int int_pos=pos.toInt();
            Serial.println("Pos");
            Serial.println(int_pos);
        }
    }
}

Stream.readStringUntil(terminator)Для кожної деталі можна використовувати пропуск іншого термінатора.

Після цього кожну частину ви телефонуєте String.toInt

Найпростішим рішенням є використання sscanf () .

  int id1, id2, id3;
  int pos1, pos2, pos3;
  char* buf = "1:90&2:80&3:180";
  int n = sscanf(buf, "%d:%d&%d:%d&%d:%d", &id1, &pos1, &id2, &pos2, &id3, &pos3);
  Serial.print(F("n="));
  Serial.println(n);
  Serial.print(F("id1="));
  Serial.print(id1);
  Serial.print(F(", pos1="));
  Serial.println(pos1);
  Serial.print(F("id2="));
  Serial.print(id2);
  Serial.print(F(", pos2="));
  Serial.println(pos2);
  Serial.print(F("id3="));
  Serial.print(id3);
  Serial.print(F(", pos3="));
  Serial.println(pos3);

Це дає такий результат:

n=6
id1=1, pos1=90
id2=2, pos2=80
id3=3, pos3=180

Ура!

Дивіться приклад за адресою: https://github.com/BenTommyE/Arduino_getStringPartByNr

// splitting a string and return the part nr index split by separator
String getStringPartByNr(String data, char separator, int index) {
    int stringData = 0;        //variable to count data part nr 
    String dataPart = "";      //variable to hole the return text

    for(int i = 0; i<data.length()-1; i++) {    //Walk through the text one letter at a time
        if(data[i]==separator) {
            //Count the number of times separator character appears in the text
            stringData++;
        } else if(stringData==index) {
            //get the text when separator is the rignt one
            dataPart.concat(data[i]);
        } else if(stringData>index) {
            //return text and stop if the next separator appears - to save CPU-time
            return dataPart;
            break;
        }
    }
    //return text if this is the last part
    return dataPart;
}

String getValue(String data, char separator, int index)
{
    int maxIndex = data.length() - 1;
    int j = 0;
    String chunkVal = "";

    for (int i = 0; i <= maxIndex && j <= index; i++)
    {
        chunkVal.concat(data[i]);

        if (data[i] == separator)
        {
            j++;

            if (j > index)
            {
                chunkVal.trim();
                return chunkVal;
            }

            chunkVal = "";
        }
        else if ((i == maxIndex) && (j < index)) {
            chunkVal = "";
            return chunkVal;
        }
    }   
}

jfpoilpret дав чудову відповідь для розбору послідовних команд на Arduino. Однак Attiny85 не має двонаправленої послідовності - слід використовувати SoftwareSerial. Таким чином ви переносите той же код для Attiny85

#include <SoftwareSerial.h>

// Calculate based on max input size expected for one command
#define INPUT_SIZE 30

// Initialize SoftwareSerial
SoftwareSerial mySerial(3, 4); // RX=PB3, TX=PB4

// Parameter for receiving Serial command (add 1 for final 0)
char input[INPUT_SIZE + 1];

void setup() {
  mySerial.begin(9600);
}

void loop() {
  // We need this counter to simulate Serial.readBytes which SoftwareSerial lacks
  int key = 0;

  // Start receiving command from Serial
  while (mySerial.available()) {
    delay(3);  // Delay to allow buffer to fill, code gets unstable on Attiny85 without this for some reason
    // Don't read more characters than defined
    if (key < INPUT_SIZE && mySerial.available()) {
      input[key] = mySerial.read();
      key += 1;
    }
  }

  if (key > 0) {
    // Add the final 0 to end the C string
    input[key] = 0;

    // Read each command pair
    char* command = strtok(input, "&");
    while (command != 0)
    {
      // Split the command in two values
      char* separator = strchr(command, ':');
      if (separator != 0)
      {
        // Actually split the string in 2: replace ':' with 0
        *separator = 0;
        int servoId = atoi(command);
        ++separator;
        int position = atoi(separator);
      }
      // Find the next command in input string
      command = strtok(0, "&");
    }
  }
}

Схеми Attiny85 для номерів контактів

Ескіз компілюється в:

Sketch uses 2244 bytes (27%) of program storage space. Maximum is 8192 bytes.
Global variables use 161 bytes (31%) of dynamic memory, leaving 351 bytes for local variables. Maximum is 512 bytes.

Таким чином, є достатньо місця та пам'яті для решти коду

char str[] = "1:90&2:80&3:180";     // test sample serial input from servo
int servoId;
int position;

char* p = str;
while (sscanf(p, "%d:%d", &servoId, &position) == 2)
{
    // process servoId, position here
    //
    while (*p && *p++ != '&');   // to next id/pos pair
}

void setup() {
Serial.begin(9600);
char str[] ="1:90&2:80";
char * pch;
pch = strtok(str,"&");
printf ("%s\n",pch);

pch = strtok(NULL,"&"); //pch=next value
printf ("%s\n",pch);
}
void loop(){}

Ось метод Arduino для розділення рядка як відповідь на питання "Як розділити рядок на підрядку?" задекларований як дублікат цього питання.

Мета рішення - проаналізувати ряд GPS- позицій, зафіксованих у файлі SD-карти . Замість того, щоб String отриманий від Serial, String читається з файлу.

Функція StringSplit()розбору рядка sLine = "1.12345,4.56789,hello"до 3 рядків sParams[0]="1.12345", sParams[1]="4.56789"& sParams[2]="hello".

1. String sInput: рядки входу для розбору,
2. char cDelim: символ роздільника між параметрами,
3. String sParams[]: вихідний масив параметрів,
4. int iMaxParams: максимальна кількість параметрів,
5. Вихід int: кількість проаналізованих параметрів,

Функція заснована на String::indexOf()і String::substring():

int StringSplit(String sInput, char cDelim, String sParams[], int iMaxParams)
{
    int iParamCount = 0;
    int iPosDelim, iPosStart = 0;

    do {
        // Searching the delimiter using indexOf()
        iPosDelim = sInput.indexOf(cDelim,iPosStart);
        if (iPosDelim > (iPosStart+1)) {
            // Adding a new parameter using substring() 
            sParams[iParamCount] = sInput.substring(iPosStart,iPosDelim-1);
            iParamCount++;
            // Checking the number of parameters
            if (iParamCount >= iMaxParams) {
                return (iParamCount);
            }
            iPosStart = iPosDelim + 1;
        }
    } while (iPosDelim >= 0);
    if (iParamCount < iMaxParams) {
        // Adding the last parameter as the end of the line
        sParams[iParamCount] = sInput.substring(iPosStart);
        iParamCount++;
    }

    return (iParamCount);
}

А використання дуже просто:

String sParams[3];
int iCount, i;
String sLine;

// reading the line from file
sLine = readLine();
// parse only if exists
if (sLine.length() > 0) {
    // parse the line
    iCount = StringSplit(sLine,',',sParams,3);
    // print the extracted paramters
    for(i=0;i<iCount;i++) {
        Serial.print(sParams[i]);
    }
    Serial.println("");
}