Збільшення дозволу біт ШІМ

Я хотів би збільшити роздільну здатність ШІМ для Arduino Uno. На даний момент це 8-бітний, який я вважаю занадто низьким. Чи можливо це без втрати здатності переривань і затримок?

Koen

РЕДАКТУВАННЯ Ця настройка забезпечує 16-бітну результативність

void setupPWM16() {
    DDRB |= _BV(PB1) | _BV(PB2);        /* set pins as outputs */
    TCCR1A = _BV(COM1A1) | _BV(COM1B1)  /* non-inverting PWM */
        | _BV(WGM11);                   /* mode 14: fast PWM, TOP=ICR1 */
    TCCR1B = _BV(WGM13) | _BV(WGM12)
        | _BV(CS11);                    /* prescaler: clock / 8 */
    ICR1 = 0xffff;                      /* TOP counter value (freeing OCR1A*/
}
/* Comments about the setup
Changing ICR1 will effect the amount of bits of resolution.
ICR1 = 0xffff; (65535) 16-bit resolution
ICR1 = 0x7FFF; (32767) 15-bit resolution
ICR1 = 0x3FFF; (16383) 14-bit resolution etc....

Changing the prescaler will effect the frequency of the PWM signal.
Frequency[Hz}=CPU/(ICR1+1) where in this case CPU=16 MHz
16-bit PWM will be>>> (16000000/8)/(65535+1)=30.5175Hz
*/

/* 16-bit version of analogWrite(). Works only on pins 9 and 10. */
void analogWrite16(uint8_t pin, uint16_t val)
{
    switch (pin) {
        case  9: OCR1A = val; break;
        case 10: OCR1B = val; break;
    }
}

Arduino Uno базується на мікроконтролері ATmega382P. Цей чіп має два 8-бітових таймерів, що управляють двома ШІМ-каналами кожен, і один 16-бітний таймер, що управляє останніми двома каналами.

Ви не можете збільшити роздільну здатність 8-бітових таймерів. Однак ви можете помістити 16-бітний таймер в 16-бітний режим замість 8-бітного режиму, який використовується в основній бібліотеці Arduino. Це дасть вам два 16-бітні ШІМ-канали зі зниженою частотою 244 Гц (максимум). Ймовірно, вам доведеться самостійно налаштувати таймер, і це не скористається простотою у користуванні analogWrite()функцією. Детальніше дивіться розділ про Таймер 1 в таблиці ATmega328P .

Оновлення : Ось реалізація 16-бітної analogWrite(). Він працює лише на штифтах 9 і 10, оскільки це єдині штирі, підключені до 16-бітного таймера.

/* Configure digital pins 9 and 10 as 16-bit PWM outputs. */
void setupPWM16() {
    DDRB |= _BV(PB1) | _BV(PB2);        /* set pins as outputs */
    TCCR1A = _BV(COM1A1) | _BV(COM1B1)  /* non-inverting PWM */
        | _BV(WGM11);                   /* mode 14: fast PWM, TOP=ICR1 */
    TCCR1B = _BV(WGM13) | _BV(WGM12)
        | _BV(CS10);                    /* no prescaling */
    ICR1 = 0xffff;                      /* TOP counter value */
}

/* 16-bit version of analogWrite(). Works only on pins 9 and 10. */
void analogWrite16(uint8_t pin, uint16_t val)
{
    switch (pin) {
        case  9: OCR1A = val; break;
        case 10: OCR1B = val; break;
    }
}

Ви можете помітити, що вершина послідовності лічильників налаштована явно. Ви можете змінити це на менше значення, щоб зробити ШІМ швидше, ціною зменшеної роздільної здатності.

Ось приклад ескізу, що ілюструє його використання:

void setup() {
    setupPWM16();
}

/* Test: send very slow sawtooth waves. */
void loop() {
    static uint16_t i;
    analogWrite16(9, i);
    analogWrite16(10, 0xffff - i);
    i++;
    delay(1);
}

За допомогою деякої калібрування ви можете підсумувати виходи двох каналів ШІМ з різними ваговими резисторами. В крайньому випадку, ви можете навмисно використати один вихід, щоб надати 8 біт роздільної здатності та масштабувати інший на 1/256-й рівень та додати їх, щоб 2-й канал охоплював один біт діапазону, і ви (знову усвідомлено) отримуєте 16 біт роздільної здатності. Без величезної турботи та налаштування все, що ви отримаєте, було б безладом.
Однак, розділивши 2-й канал на 16 або 32, ви можете додати кілька додаткових розрядів ШІМ. Лише додаючи 2 канали ШІМ аналогових відфільтрованих виходів, ви додаєте додатковий біт (оскільки діапазон потенціалів збільшується вдвічі за незмінний мВ / біт).
Умовно (знову ж таки) за кожен додатковий поділ на 2 ви отримуєте додатковий біт роздільної здатності, але це може бути здійснено лише для, можливо, 4 або 5 або 6 додаткових біт, із збільшенням вимог до точності масштабування резисторів та більш важкої калібрування та схильності до помилок .

Короткий приклад.
Якщо одну ШІМ зменшити, щоб сказати 0 - 255 мВ на кроці 1 мВ, то підсумовування двох ШІМ з однаковою амплітудою дало б діапазон від 0 до 510 мВ за кроки 1 мВ.
Якщо одну ШІМ зменшити на коефіцієнт 32, то замість того, щоб додати початковий діапазон ШІМ 255 мВ, до верхнього кінця було б додано лише 8 мВ (0,256,32 = 8 мВ, але роздільна здатність буде 0,03125 (1/32 ) кроки мВ.

Хоча це, можливо, може бути досягнуто виключно за допомогою підбиття резисторів та фільтрації на RC, використання літрів підсилювача значно покращить результати.

Також пульсація ШІМ може бути відфільтрована за допомогою простого RC-фільтра, але використання одного оппаму в якості буфера (або навіть просто одного транзистора як послідовник випромінювача) дасть вам 3 або 5 полюсів низькочастотної фільтрації та набагато більше шансів на отримання додаткової ШІМ дозвіл. Я не перевіряв "фазову узгодженість" виходів ШІМ, але очікую, що вони рухаються у відносному стоп-шасі, щоб ви не отримали корисної переваги додавання двох некоррельованих форм сигналів.

Більше коментарів можна зробити за потреби. Запитайте, чи зацікавлені.