машинний код x86-64, 44 байти
(Цей же машинний код працює і в 32-бітному режимі.)
Відповідь Даніеля Шеплера стала відправною точкою для цього, але в цьому є принаймні одна нова алгоритмічна ідея (не просто краща гольф однакової ідеї): коди ASCII для 'B'( 1000010) і 'X'( 1011000) дають 16 і 2 після маскування0b0010010 .
Отже, виключаючи десятковий (ненульовий провідний розряд) і восьмеричний (char після '0'- менше 'B'), ми можемо просто встановити base = c & 0b0010010і перейти в цикл цифр.
Викликається з системою x86-64 як V unsigned __int128 parse_cxx14_int(int dummy, const char*rsi); Витягувати значення повернення EDX з високої половини unsigned __int128результату tmp>>64.
.globl parse_cxx14_int
## Input: pointer to 0-terminated string in RSI
## output: integer in EDX
## clobbers: RAX, RCX (base), RSI (points to terminator on return)
parse_cxx14_int:
xor %eax,%eax # initialize high bits of digit reader
cdq # also initialize result accumulator edx to 0
lea 10(%rax), %ecx # base 10 default
lodsb # fetch first character
cmp $'0', %al
jne .Lentry2
# leading zero. Legal 2nd characters are b/B (base 2), x/X (base 16)
# Or NUL terminator = 0 in base 10
# or any digit or ' separator (octal). These have ASCII codes below the alphabetic ranges
lodsb
mov $8, %cl # after '0' have either digit, apostrophe, or terminator,
cmp $'B', %al # or 'b'/'B' or 'x'/'X' (set a new base)
jb .Lentry2 # enter the parse loop with base=8 and an already-loaded character
# else hex or binary. The bit patterns for those letters are very convenient
and $0b0010010, %al # b/B -> 2, x/X -> 16
xchg %eax, %ecx
jmp .Lentry
.Lprocessdigit:
sub $'0' & (~32), %al
jb .Lentry # chars below '0' are treated as a separator, including '
cmp $10, %al
jb .Lnum
add $('0'&~32) - 'A' + 10, %al # digit value = c-'A' + 10. we have al = c - '0'&~32.
# c = al + '0'&~32. val = m+'0'&~32 - 'A' + 10
.Lnum:
imul %ecx, %edx
add %eax, %edx # accum = accum * base + newdigit
.Lentry:
lodsb # fetch next character
.Lentry2:
and $~32, %al # uppercase letters (and as side effect,
# digits are translated to N+16)
jnz .Lprocessdigit # space also counts as a terminator
.Lend:
ret
Змінені блоки проти версії Даніеля (здебільшого) з відступом менше, ніж інші інструкції. Також основна петля має внизу свою умовну гілку. Це виявилося нейтральною зміною, тому що жодна стежка не могла потрапити у верхню частину її, іdec ecx / loop .Lentry ідея ввести цикл виявилась не виграшною, якщо по-іншому поправляти восьмери. Але в ньому є менша кількість інструкцій всередині циклу з циклом в ідіоматичній формі do {} в той час як структура, тому я зберігав її.
C ++ тестовий джгут Даніеля працює в незмінному режимі в 64-бітному режимі з цим кодом, який використовує ту саму умову виклику, що і його 32-розрядна відповідь.
g++ -Og parse-cxx14.cpp parse-cxx14.s &&
./a.out < tests | diff -u -w - tests.good
Розбирання, включаючи байти машинного коду, які є фактичною відповіддю
0000000000000000 <parse_cxx14_int>:
0: 31 c0 xor %eax,%eax
2: 99 cltd
3: 8d 48 0a lea 0xa(%rax),%ecx
6: ac lods %ds:(%rsi),%al
7: 3c 30 cmp $0x30,%al
9: 75 1c jne 27 <parse_cxx14_int+0x27>
b: ac lods %ds:(%rsi),%al
c: b1 08 mov $0x8,%cl
e: 3c 42 cmp $0x42,%al
10: 72 15 jb 27 <parse_cxx14_int+0x27>
12: 24 12 and $0x12,%al
14: 91 xchg %eax,%ecx
15: eb 0f jmp 26 <parse_cxx14_int+0x26>
17: 2c 10 sub $0x10,%al
19: 72 0b jb 26 <parse_cxx14_int+0x26>
1b: 3c 0a cmp $0xa,%al
1d: 72 02 jb 21 <parse_cxx14_int+0x21>
1f: 04 d9 add $0xd9,%al
21: 0f af d1 imul %ecx,%edx
24: 01 c2 add %eax,%edx
26: ac lods %ds:(%rsi),%al
27: 24 df and $0xdf,%al
29: 75 ec jne 17 <parse_cxx14_int+0x17>
2b: c3 retq
Інші зміни у версії Даніеля включають в себе збереження sub $16, %alвнутрішньої цифри, використовуючи більше, subа неtest як частину виявлення роздільників та цифр проти буквених символів.
На відміну від Даніеля, кожен персонаж нижче '0'розглядається як роздільник, а не просто '\''. (За винятком ' ': and $~32, %al/ jnzв обох наших циклах трактується простір як термінатор, що, можливо, зручно для тестування з цілим числом на початку рядка.)
Кожна операція, яка змінюється %alвсередині циклу, має прапори, що споживають гілки, встановлені результатом, і кожна гілка переходить (або провалюється) у інше місце.
