171 байт 1
Wooohoooo! Минуло пів дня, але було весело ...
Отже, ось воно. Я думаю, що він відповідає специфікаціям (обертання вказівника комірок, відлуння символів на вході, читання char за допомогою char, відлуння вхідних символів, ...), і, здається, насправді працює (ну, я не пробував багато програм , але, враховуючи простоту мови, я вважаю, що покриття не так вже й погано.
Обмеження
Одне важливе: якщо у вашій програмі brainfuck є інші символи, ніж 8 інструкцій для brainfuck, або якщо []вони недостатньо збалансовані, вона зірветься на вас, mouhahahaha!
Також програма brainfuck не може перевищувати 512 байт (сектор). Але це здається невідповідним, оскільки ви говорите, що "виконуваний файл Brainfuck розташований у другому секторі диска" .
Остання деталь: я не явно ініціалізував комірки до нуля. Qemu, здається, робить це для мене, і я покладаюся на це, але я не знаю, чи справжній BIOS на реальному комп'ютері це зробив би (ініціалізація все-таки займе ще кілька байт).
Кодекс
(на основі вашого шаблону, і, до речі, спасибі за це, я ніколи б не намагався без нього):
[BITS 16]
[ORG 0x7C00]
%define cellcount 30000 ; you can't actually increase this value much beyond this point...
; first sector:
boot:
; initialize segment registers
xor ax, ax
mov ss, ax
mov ds, ax
mov es, ax
jmp 0x0000:$+5
; initialize stack
mov sp, 0x7bfe
; load brainfuck code into 0x8000
; no error checking is used
mov ah, 2 ; read
mov al, 1 ; one sector
mov ch, 0 ; cylinder & 0xff
mov cl, 2 ; sector | ((cylinder >> 2) & 0xc0)
mov dh, 0 ; head
; dl is already the drive number
mov bx, 0x8000 ; read buffer (es:bx)
int 0x13 ; read sectors
; initialize SI (instruction pointer)
mov si, bx ; 0x8000
; initialize DI (data pointer)
mov bh, 0x82
mov di, bx ; 0x8200
decode:
lodsb ; fetch brainfuck instruction character
.theend:
test al, al ; endless loop on 0x00
jz .theend
and ax, 0x0013 ; otherwise, bit shuffling to get opcode id
shl ax, 4
shl al, 2
shr ax, 1
add ax, getchar ; and compute instruction implementation address
jmp ax
align 32, db 0
getchar:
xor ah, ah
int 0x16
cmp al, 13
jne .normal
mov al, 10 ; "enter" key translated to newline
.normal:
mov byte [di], al
push di
jmp echochar
align 32, db 0
decrementdata:
dec byte [di]
jmp decode
align 32, db 0
putchar:
push di
mov al, byte [di]
echochar:
mov ah, 0x0E
xor bx, bx
cmp al, 10 ; newline needs additional carriage return
jne .normal
mov al, 13
int 0x10
mov al, 10
.normal:
int 0x10
pop di
jmp decode
align 32, db 0
incrementdata:
inc byte [di]
jmp decode
align 32, db 0
decrementptr:
dec di
cmp di, 0x8200 ; pointer wraparound check (really, was that necessary?)
jge decode
add di, cellcount
jmp decode
align 32, db 0
jumpback:
pop si
jmp jumpforward
align 32, db 0
incrementptr:
inc di
cmp di, 0x8200+cellcount ; pointer wraparound check
jl decode
sub di, cellcount
jmp decode
align 32, db 0
jumpforward:
cmp byte [di], 0
jz .skip
push si
jmp decode
.skip:
xor bx, bx ; bx contains the count of [ ] imbrication
.loop:
lodsb
cmp al, '['
je .inc
cmp al, ']'
jne .loop
test bx, bx
jz decode
dec bx
jmp .loop
.inc:
inc bx
jmp .loop
; fill sector
times (0x1FE)-($-$$) db 0
; boot signature
db 0x55, 0xAA
; second sector contains the actual brainfuck program
; currently: "Hello world" followed by a stdin->stdout cat loop
db '++++++++[>++++[>++>+++>+++>+<<<<-]>+>+>->>+[<]<-]>>.>---.+++++++..+++.>>.<-.<.+++.------.--------.>>+.>++.,[.,]'
times 0x400-($-$$) db 0
Використовувані трюки
Гаразд, я трохи обдурив. Оскільки ви сказали, що "будучи завантажувачем, розмір програми рахується в ненульових байтах у складеному коді" , я зробив код меншим, дозволяючи "дірки" між реалізацією восьми оппонентів мозкових епізодів. Таким чином, мені не потрібна велика послідовність тестів, таблиця стрибків або що-небудь інше: я просто переходжу до мозкового епізоду "ідентифікатор коду" (від 0 до 8), помножений на 32, щоб виконати інструкцію "епізодично" (варто зазначити, що це означає, що виконання інструкцій не може займати більше 32 байт).
Більше того, щоб отримати цей "ідентифікатор коду" від персонажа програми, що залякує мозг, я помітив, що потрібно було трохи перетасувати. Дійсно, якщо ми просто розглянемо біти 0, 1 і 4 символу опкоду, ми отримаємо 8 унікальних комбінацій:
X XX
00101100 0x2C , Accept one byte of input, storing its value in the byte at the pointer.
00101101 0x2D - Decrement (decrease by one) the byte at the pointer.
00101110 0x2E . Output the value of the byte at the pointer.
00101011 0x2B + Increment (increase by one) the byte at the pointer.
00111100 0x3C < Decrement the pointer (to point to the next cell to the left).
01011101 0x5D ] Jump back after the corresp [ if data at pointer is nonzero.
00111110 0x3E > Increment the pointer (to point to the next cell to the right).
01011011 0x5B [ Jump forward after the corresp ] if data at pointer is zero.
І, пощастило, насправді є один опкод, для реалізації якого потрібно більше 32 байтів, але це останній (стрибок вперед [). Оскільки після цього місця більше, все добре.
Інший трюк: я не знаю, як працює типовий перекладач мозкових епідемій, але, щоб зробити речі набагато меншими, я насправді не реалізував ]як "Стрибок назад після відповідних, [якщо дані вказівника не мають нуля" . Натомість я завжди повертаюся до відповідної [, і, звідси, повторно застосовую типову [реалізацію (яка, зрештою, після необхідності ]знову йде вперед ). З цього [приводу кожного разу, коли я сприяю , я поміщаю поточний "покажчик інструкцій" на стек перед виконанням внутрішніх інструкцій, і коли я стикаюся з], Я повертаю назад вказівник інструкції. Приблизно так, ніби це був дзвінок до функції. Тому теоретично ви могли б переповнити стек, зробивши багато безлічі вбудованих циклів, але не з існуючим 512-байтовим обмеженням коду, що є мозком.
1. Включаючи нульові байти, що входили до самого коду, але не ті, що були частиною прокладки
Input must be redЯ впевнений, що більшість завантажувачів не підтримують колір.