Крок 1. Створіть службу для отримання сповіщень та черги до неї:
use msdb;
go
create queue dbm_notifications_queue;
create service dbm_notification_service
on queue dbm_notifications_queue
([http://schemas.microsoft.com/SQL/Notifications/PostEventNotification]);
go
create event notification dbm_notifications
on server
for database_mirroring_state_change
to service N'dbm_notification_service', N'current database';
go
Зауважте, що я використовую msdb, це не випадковість. Оскільки сповіщення про події на серверному рівні надсилаються від msdbнього набагато краще, якщо ви також створите протилежну кінцеву точку розмови (ціль) msdb, що означає, що службу призначення та чергу також потрібно розгорнути msdb.
Крок 2: створіть процедуру обробки сповіщень про події:
use msdb;
go
create table dbm_notifications_errors (
incident_time datetime not null,
session_id int not null,
has_rolled_back bit not null,
[error_number] int not null,
[error_message] nvarchar(4000) not null,
[message_body] varbinary(max));
create clustered index cdx_dbm_notifications_errors
on dbm_notifications_errors (incident_time);
go
create table mirroring_alerts (
alert_time datetime not null,
start_time datetime not null,
processing_time datetime not null,
database_id smallint not null,
database_name sysname not null,
[state] tinyint not null,
[text_data] nvarchar(max),
event_data xml not null);
create clustered index cdx_mirroring_alerts
on mirroring_alerts (alert_time);
go
create procedure dbm_notifications_procedure
as
begin
declare @dh uniqueidentifier, @mt sysname, @raw_body varbinary(max), @xml_body xml;
begin transaction;
begin try;
receive top(1)
@dh = conversation_handle,
@mt = message_type_name,
@raw_body = message_body
from dbm_notifications_queue;
if N'http://schemas.microsoft.com/SQL/Notifications/EventNotification' = @mt
begin
set @xml_body = cast(@raw_body as xml);
-- shred the XML and process it accordingly
-- IMPORTANT! IMPORTANT!
-- DO NOT LOOK AT sys.database_mirroring
-- The view represents the **CURRENT** state
-- This message reffers to an **EVENT** that had occured
-- the current state may or may no be relevant for this **PAST** event
declare @alert_time datetime
, @start_time datetime
, @processing_time datetime = getutcdate()
, @database_id smallint
, @database_name sysname
, @state tinyint
, @text_data nvarchar(max);
set @alert_time = @xml_body.value (N'(//EVENT_INSTANCE/PostTime)[1]', 'DATETIME');
set @start_time = @xml_body.value (N'(//EVENT_INSTANCE/StartTime)[1]', 'DATETIME');
set @database_id = @xml_body.value (N'(//EVENT_INSTANCE/DatabaseID)[1]', 'SMALLINT');
set @database_name = @xml_body.value (N'(//EVENT_INSTANCE/DatabaseName)[1]', 'SYSNAME');
set @state = @xml_body.value (N'(//EVENT_INSTANCE/State)[1]', 'TINYINT');
set @text_data = @xml_body.value (N'(//EVENT_INSTANCE/TextData)[1]', 'NVARCHAR(MAX)');
insert into mirroring_alerts (
alert_time,
start_time,
processing_time,
database_id,
database_name,
[state],
text_data,
event_data)
values (
@alert_time,
@start_time,
@processing_time,
@database_id,
@database_name,
@state,
@text_data,
@xml_body);
end
else if N'http://schemas.microsoft.com/SQL/ServiceBroker/Error' = @mt
begin
set @xml_body = cast(@raw_body as xml);
DECLARE @error INT
, @description NVARCHAR(4000);
WITH XMLNAMESPACES ('http://schemas.microsoft.com/SQL/ServiceBroker/Error' AS ssb)
SELECT @error = CAST(@xml_body AS XML).value('(//ssb:Error/ssb:Code)[1]', 'INT'),
@description = CAST(@xml_body AS XML).value('(//ssb:Error/ssb:Description)[1]', 'NVARCHAR(4000)');
insert into dbm_notifications_errors(
incident_time,
session_id,
has_rolled_back,
[error_number],
[error_message],
[message_body])
values (
getutcdate(),
@@spid,
0,
@error,
@description,
@raw_body);
end conversation @dh;
end
else if N'http://schemas.microsoft.com/SQL/ServiceBroker/EndDialog' = @mt
begin
end conversation @dh;
end
commit;
end try
begin catch
declare @xact_state int = xact_state(),
@error_number int = error_number(),
@error_message nvarchar(4000) = error_message(),
@has_rolled_back bit = 0;
if @xact_state = -1
begin
-- Doomed transaction, it must rollback
rollback;
set @has_rolled_back = 1;
end
else if @xact_state = 0
begin
-- transaction was already rolled back (deadlock?)
set @has_rolled_back = 1;
end
insert into dbm_notifications_errors(
incident_time,
session_id,
has_rolled_back,
[error_number],
[error_message],
[message_body])
values (
getutcdate(),
@@spid,
@has_rolled_back,
@error_number,
@error_message,
@raw_body);
if (@has_rolled_back = 0)
begin
commit;
end
end catch
end
go
Процедура написання сервісного брокера - це не ваш пробіг-код. Необхідно дотримуватися певних стандартів і дуже легко від'їхати на територію затишшя. У цьому коді показано кілька передових практик:
- загортають маскування повідомлень та обробку в транзакції. Ніякого мозгу, очевидно.
- завжди перевіряйте тип отриманого повідомлення. Хороша процедура сервісного брокера повинна обробляти
Errorта EndDialogповідомляти належним чином, закінчуючи діалогове вікно з його боку. Чи не робити це призводить до витоку ручки ( sys.conversation_endpointsзростає)
- завжди перевіряйте, чи повідомлення було відхилено RECEIVE. Деякі зразки перевіряють @@ rowcount after
RECEIVE, що цілком нормально. Цей зразок коду покладається на перевірку імені повідомлення (жодне повідомлення не означає назву типу повідомлення NULL) та обробляє цей випадок неявно.
- створити таблицю помилок обробки. фоновий характер процедур, активованих SSB, ускладнює усунення помилок, якщо повідомлення просто зникають без сліду.
Крім того, цей код також містить деякий код належної практики щодо заданого завдання (моніторинг DBM):
- розмежуйте
post_time( коли було надіслано повідомлення? ), start_time( коли розпочалася дія, яка викликала повідомлення ) ?processing_time ( і коли повідомлення було оброблено? ). post_timeі start_time, ймовірно, буде однаковим або дуже близьким, але processing_timeможуть бути секунди, години, дні від них post_time. цікавий для аудиту зазвичай post_time.
- так
post_timeі processing_timeрізні, це повинно бути очевидно , що DBM моніторингу завдання в парному повідомленні активується процедура не має ніякого бізнесу , дивлячись на sys.database_mirroringпогляді . Цей вигляд покаже поточний стан на момент обробки, який може бути або не бути пов'язаним з подією. Якщо обробка відбувається через довгий час після публікації події (думаю, час простою технічного обслуговування), то проблема очевидна, але вона може впоратися і з «здоровою» обробкою, якщо DBM дуже швидко змінює стан і розміщує два (або більше) події в рядок (що трапляється часто): в цій ситуації обробка, як і в опублікованому вами коді, ревізує подію по мірі їх виникнення, але записує поточне, остаточне , стан. Читання такого аудиту згодом може бути дуже заплутаним.
- завжди перевіряйте оригінальну подію XML Таким чином, ви можете пізніше запитувати цей XML для будь-якої інформації, яка не була 'подрібнена', до стовпців таблиці аудиту.
Крок 3: приєднайте процедуру до черги:
alter queue dbm_notifications_queue
with activation (
status=on,
procedure_name = [dbm_notifications_procedure],
max_queue_readers = 1,
execute as owner);