Як послідовність.nextval може бути нульовою в Oracle?

У мене така послідовність Oracle визначена так:

CREATE SEQUENCE  "DALLAS"."X_SEQ"  
    MINVALUE 0 
    MAXVALUE 999999999999999999999999999 
    INCREMENT BY 1 START WITH 0 NOCACHE  NOORDER  NOCYCLE ;

Він використовується в збереженій процедурі для вставки запису:

PROCEDURE Insert_Record
                (p_name    IN  VARCHAR2,                
                 p_userid  IN  INTEGER,
                 cur_out   OUT TYPES_PKG.RefCursor)
    IS
        v_id NUMBER := 0;
    BEGIN
        -- Get id value from sequence
        SELECT x_seq.nextval
          INTO v_id
          FROM dual;

        -- Line below is X_PKG line 40
        INSERT INTO X
            (the_id,            
             name,                        
             update_userid)
          VALUES
            (v_id,
             p_name,                        
             p_userid);

        -- Return new id
        OPEN cur_out FOR
            SELECT v_id the_id
              FROM dual;
    END;

Інколи ця процедура повертає помилку при виконанні з коду програми.

ORA-01400: cannot insert NULL into ("DALLAS"."X"."THE_ID") 
ORA-06512: at "DALLAS.X_PKG", line 40 
ORA-06512: at line 1

Деталі, які можуть бути або не бути актуальними:

• Випуск бази даних Oracle 11g Enterprise Edition 11.2.0.1.0 - 64-бітне виробництво
• Процедура виконується за допомогою Microsoft.Practices.EnterpriseLibrary - Data.Oracle.OracleDatabase.ExecuteReader (команда DbCommand)
• Додаток не завершує виклик у явній транзакції.
• Вставка виходить з перервами - менше 1%

За яких обставин може x_seq.nextvalбути недійсним?

Я впевнений, що це в кінцевому підсумку стане артефактом вашого коду чи драйвером .net, який ви використовуєте. Я створив для вас швидку демонстрацію за допомогою чистого SQL - PL / SQL і ніколи не отримую втрачене значення послідовності. Між іншим, курсор ref, який ви використовуєте, ймовірно, не потрібний і, ймовірно, впливає на продуктивність і читабельність коду - моя демонстрація включає в себе процедуру insert_record2, яка стабільно виконує на 10% швидше - приблизно на 26 секунд на моєму ноутбуці проти 36 для версії курсору ref. Я, принаймні, теж думаю, що це легше зрозуміти. Ви, очевидно, можете запустити модифіковану версію проти тестової бази даних разом із тригером аудиту.

/* 
demo for dbse 
assumes a user with create table, create sequence, create procedure pivs and quota. 

*/

drop table dbse13142 purge;

create table dbse13142(
    the_id number not null
,   name   varchar2(20)
,   userid number)
;

drop sequence x_seq;
CREATE SEQUENCE  X_SEQ NOCACHE  NOORDER  NOCYCLE ;

create or replace PROCEDURE Insert_Record
                (p_name    IN  VARCHAR2,                
                 p_userid  IN  INTEGER,
                 cur_out   OUT sys_refcursor)
    IS
        v_id NUMBER := 0;
    BEGIN
        -- Get id value from sequence
        SELECT x_seq.nextval
          INTO v_id
          FROM dual;

        -- Line below is X_PKG line 40
        INSERT INTO dbse13142
            (the_id,            
             name,                        
             userid)
          VALUES
            (v_id,
             p_name,                        
             p_userid);

        -- Return new id
        OPEN cur_out FOR
            SELECT v_id the_id
              FROM dual;
    END;
/


create or replace PROCEDURE Insert_Record2
                (p_name    IN  VARCHAR2,                
                 p_userid  IN  INTEGER,
                 p_theid   OUT dbse13142.the_id%type)
    IS
    BEGIN
        -- Get id value from sequence
        SELECT x_seq.nextval
          INTO p_theid
          FROM dual;

        -- Line below is X_PKG line 40
        INSERT INTO dbse13142
            (the_id,            
             name,                        
             userid)
          VALUES
            (p_theid,
             p_name,                        
             p_userid);
    END;
/

set timing on

declare
   c sys_refcursor;
begin   
for i in 1..100000 loop
   insert_record('User '||i,i,c);
   close c;
end loop;
commit;
end;
/

select count(*) from dbse13142;
truncate table dbse13142;

declare
  x number;
begin   
for i in 1..100000 loop
   insert_record2('User '||i,i,x);
end loop;
commit;
end;
/

select count(*) from dbse13142;
truncate table dbse13142;

Спробуйте зробити тестовий випадок. Складіть макетну таблицю і вставте 100 000 записів, використовуючи свою послідовність із бази даних. Б'юсь об заклад, у вас не буде проблем. Далі спробуйте вставити те саме з вашої програми.

Чи можуть це бути викликані іншими проблемами, такими як невідповідність клієнта Oracle?

Ще одне рішення, яке вирішило б проблему, але не було проблемою - додати тригер на стіл.
Перед вставкою в таблицю на Dallas.X ЯК: the_id є нульовим ТАКІ ВИБІР x_seq.nextval INTO: the_id ВІД подвійний; КІНЦЯ ЯКЩО;

У мене поки що немає коментарів, щоб коментувати коментарі, тому записуйте це як відповідь: Оскільки ви використовуєте версію Oracle> = 11.1, яка дозволяє послідовності в виразах PL / SQL замість SQL, спробуйте це:

   v_id := x_seq.nextval;

Замість цього:

 -- Get id value from sequence
    SELECT x_seq.nextval
      INTO v_id
      FROM dual;

Або, хоча я почув сумніви / підводні камені під час використання ".currval", можливо, опустіть окреме призначення v_id і використовуйте лише цей код ?:

 -- Line below is X_PKG line 40
        INSERT INTO X
            (the_id,            
             name,                        
             update_userid)
          VALUES
            (x_seq.nextval,
             p_name,                        
             p_userid);

        -- Return new id
        OPEN cur_out FOR
            SELECT x_seq.currval the_id
              FROM dual;

Вибачте, зараз не маю під рукою екземпляр 11 г, щоб спробувати це.