Функція таблиці SQL з оцінкою для розділення стовпця на коми

Я написав функцію "Таблицька оцінка" в Microsoft SQL Server 2008, щоб взяти стовпчик з обмеженими комами в базі даних, щоб виплюнути окремі рядки для кожного значення.

Наприклад: "один, два, три, чотири" поверне нову таблицю з лише одним стовпцем, що містить такі значення:

one
two
three
four

Чи виглядає цей код схильним до вас, хлопці? Коли я тестую це

SELECT * FROM utvf_Split('one,two,three,four',',') 

він просто працює вічно і ніколи нічого не повертає. Це стає дуже огидно, тим більше, що на сервері MSSQL немає вбудованих розділених функцій (ЧОМУ ЧОМУ чому ?!), а всі подібні функції, які я знайшов в Інтернеті, є абсолютним сміттям або просто не мають значення для того, що я намагаюся робити. .

Ось функція:

USE *myDBname*
GO
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
ALTER FUNCTION [dbo].[utvf_SPlit] (@String VARCHAR(MAX), @delimiter CHAR)

RETURNS @SplitValues TABLE
(
    Asset_ID VARCHAR(MAX) NOT NULL
)

AS
BEGIN
            DECLARE @FoundIndex INT
            DECLARE @ReturnValue VARCHAR(MAX)

            SET @FoundIndex = CHARINDEX(@delimiter, @String)

            WHILE (@FoundIndex <> 0)
            BEGIN
                  DECLARE @NextFoundIndex INT
                  SET @NextFoundIndex = CHARINDEX(@delimiter, @String, @FoundIndex+1)
                  SET @ReturnValue = SUBSTRING(@String, @FoundIndex,@NextFoundIndex-@FoundIndex)
                  SET @FoundIndex = CHARINDEX(@delimiter, @String)
                  INSERT @SplitValues (Asset_ID) VALUES (@ReturnValue)
            END

            RETURN
END

Повторно працював це ...

DECLARE @FoundIndex INT
DECLARE @ReturnValue VARCHAR(MAX)

SET @FoundIndex = CHARINDEX(@delimiter, @String)

WHILE (@FoundIndex <> 0)
BEGIN
      SET @ReturnValue = SUBSTRING(@String, 0, @FoundIndex)
      INSERT @SplitValues (Asset_ID) VALUES (@ReturnValue)
      SET @String = SUBSTRING(@String, @FoundIndex + 1, len(@String) - @FoundIndex)
      SET @FoundIndex = CHARINDEX(@delimiter, @String)
END

INSERT @SplitValues (Asset_ID) VALUES (@String)

RETURN

Я б не робив цього з циклом; Є набагато кращі альтернативи. До сих пір кращий, коли є для поділу, є CLR, і підхід Адама Machanic є найшвидшим я перевірив .

Наступний найкращий підхід IMHO, якщо ви не можете реалізувати CLR, - це таблиця цифр:

SET NOCOUNT ON;

DECLARE @UpperLimit INT = 1000000;

WITH n AS
(
    SELECT
        x = ROW_NUMBER() OVER (ORDER BY s1.[object_id])
    FROM       sys.all_objects AS s1
    CROSS JOIN sys.all_objects AS s2
    CROSS JOIN sys.all_objects AS s3
)
SELECT Number = x
  INTO dbo.Numbers
  FROM n
  WHERE x BETWEEN 1 AND @UpperLimit
  OPTION (MAXDOP 1); -- protecting from Paul White's observation

GO
CREATE UNIQUE CLUSTERED INDEX n ON dbo.Numbers(Number) 
    --WITH (DATA_COMPRESSION = PAGE);
GO

... що дозволяє виконувати цю функцію:

CREATE FUNCTION dbo.SplitStrings_Numbers
(
   @List       NVARCHAR(MAX),
   @Delimiter  NVARCHAR(255)
)
RETURNS TABLE
WITH SCHEMABINDING
AS
   RETURN
   (
       SELECT Item = SUBSTRING(@List, Number, 
         CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)
       FROM dbo.Numbers
       WHERE Number <= CONVERT(INT, LEN(@List))
         AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
   );
GO

Я вважаю, що все це буде працювати краще, ніж функція, яку ви маєте, коли ви працюєте, тим більше, що вони вбудовані замість мульти-оператора. Я не досліджував, чому ваша робота не працює, тому що я не думаю, що варто, щоб ця функція працювала.

Але це все сказало ...

Оскільки ви використовуєте SQL Server 2008, чи є причина, що вам потрібно розділити в першу чергу? Я б скоріше використовував для цього TVP:

CREATE TYPE dbo.strings AS TABLE
(
  string NVARCHAR(4000)
);

Тепер ви можете прийняти це як параметр для збережених процедур і використовувати вміст так, як ви б використовували TVF:

CREATE PROCEDURE dbo.foo
  @strings dbo.strings READONLY
AS
BEGIN
  SET NOCOUNT ON;

  SELECT Asset_ID = string FROM @strings;
  -- SELECT Asset_ID FROM dbo.utvf_split(@other_param, ',');
END

І ви можете передавати TVP безпосередньо з C # тощо як DataTable. Це майже напевно перевершить будь-яке з вищезазначених рішень, особливо якщо ви спеціально будуєте рядок, розділений комами у вашому додатку, щоб ваша збережена процедура могла викликати TVP, щоб розділити його знову. Більше інформації про телевізійні телеканали див. У чудовій статті Ерланда Соммарського .

Зовсім недавно я написав серію про розділення рядків:

• http://sqlperformance.com/2012/07/t-sql-queries/split-strings
• http://sqlperformance.com/2012/08/t-sql-queries/splitting-strings-follow-up
• http://sqlperformance.com/2012/08/t-sql-queries/splitting-strings-now-with-less-t-sql

І якщо ви використовуєте SQL Server 2016 або новішу версіюSTRING_SPLIT (або база даних Azure SQL), тут є нова функція , про яку я бгітував тут:

• Сюрпризи та припущення щодо ефективності: STRING_SPLIT ()
• STRING_SPLIT () у SQL Server 2016: Підготовка №1
• STRING_SPLIT () у SQL Server 2016: Слідування №2

SQL Server 2016 запровадив функцію STRING_SPLIT () . Він має два параметри - рядок, яку потрібно подрібнити, і роздільник. Вихід - один рядок на повернене значення.

Для наведеного прикладу

SELECT * FROM string_split('one,two,three,four', ',');

повернеться

value
------------------
one
two
three
four

Я використовую і люблю розбивач струн Джеффа Модена майже з моменту виходу.

Tally OH! Удосконалена функція SQL 8K “CSV Splitter”

CREATE FUNCTION [dbo].[DelimitedSplit8K]
--===== Define I/O parameters
        (@pString VARCHAR(8000), @pDelimiter CHAR(1))
--WARNING!!! DO NOT USE MAX DATA-TYPES HERE!  IT WILL KILL PERFORMANCE!
RETURNS TABLE WITH SCHEMABINDING AS
 RETURN
--===== "Inline" CTE Driven "Tally Table" produces values from 1 up to 10,000...
     -- enough to cover VARCHAR(8000)
  WITH E1(N) AS (
                 SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL
                 SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL
                 SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1 UNION ALL SELECT 1
                ),                          --10E+1 or 10 rows
       E2(N) AS (SELECT 1 FROM E1 a, E1 b), --10E+2 or 100 rows
       E4(N) AS (SELECT 1 FROM E2 a, E2 b), --10E+4 or 10,000 rows max
 cteTally(N) AS (--==== This provides the "base" CTE and limits the number of rows right up front
                     -- for both a performance gain and prevention of accidental "overruns"
                 SELECT TOP (ISNULL(DATALENGTH(@pString),0)) ROW_NUMBER() OVER (ORDER BY (SELECT NULL)) FROM E4
                ),
cteStart(N1) AS (--==== This returns N+1 (starting position of each "element" just once for each delimiter)
                 SELECT 1 UNION ALL
                 SELECT t.N+1 FROM cteTally t WHERE SUBSTRING(@pString,t.N,1) = @pDelimiter
                ),
cteLen(N1,L1) AS(--==== Return start and length (for use in substring)
                 SELECT s.N1,
                        ISNULL(NULLIF(CHARINDEX(@pDelimiter,@pString,s.N1),0)-s.N1,8000)
                   FROM cteStart s
                )
--===== Do the actual split. The ISNULL/NULLIF combo handles the length for the final element when no delimiter is found.
 SELECT ItemNumber = ROW_NUMBER() OVER(ORDER BY l.N1),
        Item       = SUBSTRING(@pString, l.N1, l.L1)
   FROM cteLen l
;

CREATE FUNCTION [dbo].[fnSplit]
(

    @sInputList VARCHAR(8000),         -- List of delimited items

    @sDelimiter VARCHAR(8000) = ','    -- delimiter that separates items

)
RETURNS @List TABLE (colData VARCHAR(8000))

BEGIN

DECLARE @sItem VARCHAR(8000)

    WHILE CHARINDEX(@sDelimiter,@sInputList,0) <> 0

    BEGIN

        SELECT @sItem=RTRIM(LTRIM(SUBSTRING(@sInputList,1,CHARINDEX
(@sDelimiter,@sInputList,0)-1))),

        @sInputList=RTRIM(LTRIM(SUBSTRING(@sInputList,CHARINDEX(@sDelimiter,@sInputList,0)
+LEN(@sDelimiter),LEN(@sInputList))))

        IF LEN(@sItem) > 0
            INSERT INTO @List SELECT @sItem
        END

        IF LEN(@sInputList) > 0
            INSERT INTO @List SELECT @sInputList -- Put the last item in
        RETURN
    END

--TEST

--Example 1: select * from fnSplit('1,22,333,444,,5555,666', ',')

--Example 2: select * from fnSplit('1##22#333##444','##')  --note second colData has embedded #

--Example 3: select * from fnSplit('1 22 333 444  5555 666', ' ')