Здійснення резервного копіювання всіх баз даних у SQL Server

У мене є сервер БД Microsoft SQL Server 2005. На сервері БД я маю близько 250 баз даних користувачів. Мені потрібно зробити резервну копію всіх цих баз даних. Оскільки резервне копіювання вручну займає багато часу, я шукаю сценарій Batch або сценарій DB, який автоматично забере резервне копіювання всіх 250 баз даних. Чи будь-хто, будь ласка, допоможе в цьому?

Примітка. Спершу створіть папку на D:диску. (наприклад D:\User_DataBackup\)

Крок 1: Створіть процедуру, подану нижче.

Create PROCEDURE [dbo].[UserDataBaseBackUp]
AS

BEGIN
SET NOCOUNT ON;

DECLARE @name VARCHAR(50) -- database name
DECLARE @path VARCHAR(256) -- path for backup files
DECLARE @fileName VARCHAR(256) -- filename for backup
DECLARE @fileDate VARCHAR(20) -- used for file name
SET @path = 'D:\User_DataBackup\' -- as same as your created folder' 
SELECT @fileDate = CONVERT(VARCHAR(20),GETDATE(),104)
DECLARE db_cursor CURSOR FOR
  SELECT name
  FROM MASTER.dbo.sysdatabases
  WHERE name NOT IN ('master','model','msdb','tempdb','ReportServer','ReportServerTempDB')
OPEN db_cursor
FETCH NEXT FROM db_cursor INTO @name
WHILE @@FETCH_STATUS = 0
BEGIN
  SET @fileName = @path + @name + '_' + @fileDate + '.BAK'
  BACKUP DATABASE @name TO DISK = @fileName
  FETCH NEXT FROM db_cursor INTO @name
END
CLOSE db_cursor
DEALLOCATE db_cursor
END

Крок 2: Виконайте вищевказану процедуру.

 EXEC [UserDataBaseBackUp]

Ви також можете запланувати цю процедуру. Ця процедура перевірена, сподіваємось, це допоможе.

Розробіть план технічного обслуговування

SQL Server має цю дивовижну функцію, де він створить сценарій та завдання для вас

• Крок 1:
  Клацніть правою кнопкою миші Maintenance PlanпідManagement

  

• Крок 2:
  Назвіть свій план

  

• Крок 3:
  Виберіть завдання резервного копіювання бази даних

  

• Крок 4:
  Налаштуйте завдання, виберіть Бази даних, Місце папки, Тип резервного копіювання (повне, диференціальне, журнал транзакцій) і т.д.

  

• Крок 5:
  Налаштуйте графік роботи

  

Я рекомендую скласти окремий план для системних баз даних та ваших баз даних користувачів, щоб уникнути будь-яких проблем

Допоміжні посилання:

• Налаштування плану обслуговування для резервного копіювання баз даних
• Резервне копіювання завдань бази даних (план обслуговування)

Я знаю на факт, що підтримка безлічі баз даних із SSMS може бути трохи заплутаною, але це прямо вперед.

Я можу порекомендувати більш ефективний спосіб - використання сценарію технічного обслуговування Ola Hallengren . Це дуже круто і дуже ефективно. І ви можете зробити набагато більше, ніж просто створити резервну копію всіх баз даних, ви можете виконати всі види процедур обслуговування.

Наприклад, ви можете створити резервну копію всіх баз даних, стиснути їх і зашифрувати за допомогою обраного вами сертифікату, скориставшись такою командою (і всі вони необов’язкові. Шифрування та стискання не працюватимуть на SQL Server 2005, але я думаю, що це буде показати гнучкість і силу сценарію Оли):

EXECUTE dbo.DatabaseBackup @Databases = 'USER_DATABASES',
@Directory = 'C:\Backup',
@BackupType = 'FULL',
@Compress = 'Y',
@Encrypt = 'Y',
@EncryptionAlgorithm = 'AES_256',
@ServerCertificate = 'MyCertificate'

Працюючи над відповіддю від JP, я додав параметр для передачі каталогу призначення (і, можливо, додати більше варіантів):

Create PROCEDURE [dbo].[UserDataBaseBackUp] (
  @OutputDir varchar(255)
) AS
BEGIN
    SET NOCOUNT ON;

    DECLARE @name VARCHAR(50) -- database name
    DECLARE @path VARCHAR(256) -- path for backup files
    DECLARE @fileName VARCHAR(256) -- filename for backup
    DECLARE @fileDate VARCHAR(20) -- used for file name
    SET @path = @OutputDir
    SELECT @fileDate = CONVERT(VARCHAR(20),GETDATE(),104)
    PRINT 'Starting Backups'
    DECLARE db_cursor CURSOR FOR
        SELECT name FROM MASTER.dbo.sysdatabases
            WHERE name NOT IN ('master','model','msdb','tempdb','ReportServer','ReportServerTempDB')
        OPEN db_cursor
            FETCH NEXT FROM db_cursor INTO @name
            WHILE @@FETCH_STATUS = 0 BEGIN
                SET @fileName = @path + @name + '_' + @fileDate + '.BAK'
                    PRINT 'Starting Backup For ' + @name
                    BACKUP DATABASE @name TO DISK = @fileName WITH FORMAT
                FETCH NEXT FROM db_cursor INTO @name
            END
        CLOSE db_cursor
    DEALLOCATE db_cursor
    PRINT 'Backups Finished'
END
GO

Так то:

EXEC UserDataBaseBackUp @OutputDir = 'F:\Backups\SQL Databases\'

Ви можете використовувати SELECT Statement або CURSOR так:

DECLARE @PathForBackUp VARCHAR(255)
SET @PathForBackUp = 'F:\Backup\User DB\'

SELECT 'BACKUP DATABASE [' + name + '] TO  DISK = N''' + @PathForBackUp + '' + name + '.bak''
WITH NOFORMAT, NOINIT,  NAME = N''' + name + '_FullBackUp'', SKIP, NOREWIND, NOUNLOAD, COMPRESSION,  STATS = 5'
FROM sys.databases
WHERE database_id > 4

АБО

DECLARE @DBName VARCHAR(255)  
DECLARE @PathForBackUp VARCHAR(255) 
DECLARE @FileName VARCHAR(255)  
DECLARE @DateFile VARCHAR(255)
DECLARE @SQL NVARCHAR(2048) 
SET @PathForBackUp = 'F:\Backup\User DB\'  
SET @DateFile = REPLACE(REPLACE(CONVERT(VARCHAR(20),GETDATE(),120) ,' ','T'), ':','') 

DECLARE BACKUPING CURSOR FOR   
SELECT name  
FROM master.dbo.sysdatabases WHERE dbid > 4 

OPEN BACKUPING    
FETCH NEXT FROM BACKUPING INTO @DBName    
WHILE @@FETCH_STATUS = 0    

BEGIN    
        SET @FileName = @PathForBackUp + @DBName + '_' + @DateFile + '.BAK'  
    SET @SQL = 'BACKUP DATABASE '+@DBName+ ' TO DISK = '''+@FileName+''' WITH COMPRESSION ' 
    PRINT @SQL 
    EXECUTE sp_executesql @sql   
    FETCH NEXT FROM BACKUPING INTO @DBName  

END    

CLOSE BACKUPING    
DEALLOCATE BACKUPING 

Ви також можете використовувати PowerShell, як показано у розділі Використовувати PowerShell для резервного копіювання всіх баз даних користувачів Buck Woody:

# Performs a Full backup followed by a transaction log backup on all user databases

[System.Reflection.Assembly]::LoadWithPartialName("Microsoft.SqlServer.SMO")  | out-null
$s = new-object ('Microsoft.SqlServer.Management.Smo.Server') 'BWOODY1\SQL2K8'
$bkdir = $s.Settings.BackupDirectory
$dbs = $s.Databases
$dbs | foreach-object {
    $db = $_

    if ($db.IsSystemObject -eq $False -and $db.IsMirroringEnabled -eq $False) {
        $dbname = $db.Name
        $dt = get-date -format yyyyMMddHHmmss
        $dbbk = new-object ('Microsoft.SqlServer.Management.Smo.Backup')
        $dbbk.Action = 'Database'
        $dbbk.BackupSetDescription = "Full backup of " + $dbname
        $dbbk.BackupSetName = $dbname + " Backup"
        $dbbk.Database = $dbname
        $dbbk.MediaDescription = "Disk"
        $dbbk.Devices.AddDevice($bkdir + "\" + $dbname + "_db_" + $dt + ".bak", 'File')
        $dbbk.SqlBackup($s)
        if ($db.DatabaseOptions.RecoveryModel -ne 'Simple') {
            $dt = get-date -format yyyyMMddHHmmss
            $dbtrn = new-object ('Microsoft.SqlServer.Management.Smo.Backup')
            $dbtrn.Action = 'Log'
            $dbtrn.BackupSetDescription = "Trans Log backup of " + $dbname
            $dbtrn.BackupSetName = $dbname + " Backup"
            $dbtrn.Database = $dbname
            $dbtrn.MediaDescription = "Disk"
            $dbtrn.Devices.AddDevice($bkdir + "\" + $dbname + "_tlog_" + $dt + ".trn", 'File')
            $dbtrn.SqlBackup($s)
            }
        }     
    }