Як я можу отримати фактичний розмір даних для рядка в таблиці SQL Server?

33

Я знайшов цей скрипт sql-server-2005-достигаючий-table-row-size-limit, який, здається, повертає розмір рядка за визначеними довжинами типу даних. Мені потрібен сценарій, який би дав мені всі рядки таблиці, що їх максимальний розмір даних перевищує рекомендований 8024 (що б MS не рекомендував)

sql-server

— Ентоні
джерело

2

Ви можете спробувати використовувати msdn.microsoft.com/en-us/library/ms188917%28v=sql.105%29.aspx - SELECT * FROM sys.dm_db_index_physical_stats(DB_ID(N'Database_Name'), OBJECT_ID(N'Table_Name'), NULL, NULL, 'DETAILED')і шукати що - небудь , де alloc_unit_type_descцеROW_OVERFLOW_DATA

MS SQL-сервер дозволяє зберігати лише 8060 байт максимуму даних у рядку. Отже, розмір рядка завжди буде <= 8060. Він ніколи цього не перетне.

— AnandPhadke

2

@AnandPhadke Це не зовсім правильно: msdn.microsoft.com/en-us/library/ms186981%28SQL.90%29.aspx

— Хайме

44

Спробуйте цей сценарій:

declare @table nvarchar(128)
declare @idcol nvarchar(128)
declare @sql nvarchar(max)

--initialize those two values
set @table = 'YourTable'
set @idcol = 'some id to recognize the row'

set @sql = 'select ' + @idcol +' , (0'

select @sql = @sql + ' + isnull(datalength(' + name + '), 1)' 
        from  sys.columns 
        where object_id = object_id(@table)
        and   is_computed = 0
set @sql = @sql + ') as rowsize from ' + @table + ' order by rowsize desc'

PRINT @sql

exec (@sql)

Рядки будуть упорядковані за розміром, тому ви можете перевірити зверху вниз.

— Хайме
джерело

так, це не стосується varchar Я згоден. Тут вище ваш запит не охоплює всіх стовпців таблиці

— AnandPhadke

@AnandPhadke Які стовпці не охоплює? Спасибі

— Хайме

Навіщо додати один байт для нульового стовпця? Це не нульові байти? Або він зберігається внутрішньо як # 0?

— Пол

2

@Paul, це нульові байти для стовпців змінної довжини (varchar, nvarchar ...), але це фактична довжина типу даних для стовпців із фіксованою довжиною (int, smallint ...), тому 1 є своєрідною оцінкою. NULL - це цілий Всесвіт :) (є також маска растрової карти NULL, яка використовується для позначення значень NULL, яка займає деякий простір). stackoverflow.com/questions/4546273/…

— Хайме

@Paul він буде зберігатися як нульовий байт, якщо SQL Server використовує будь-яке стиснення даних.

— д.попов

7

Мені сподобалось вище від Хайме. Я додав кілька квадратних дужок для обробки дивних назв стовпців.

    declare @table nvarchar(128)
    declare @idcol nvarchar(128)
    declare @sql nvarchar(max)

    --initialize those two values
    set @table = 'YourTable'
    set @idcol = 'some id to recognize the row'

    set @sql = 'select ' + @idcol +' , (0'

    select @sql = @sql + ' + isnull(datalength([' + name + ']), 1)' 
            from sys.columns where object_id = object_id(@table)
    set @sql = @sql + ') as rowsize from ' + @table + ' order by rowsize         desc'

    PRINT @sql

    exec (@sql)

— Speedcat
джерело

3

І мені сподобалось вище від Speedcat, і розширюю його до списку всіх таблиць із кількістю рядків і загальним байтом.

declare @table nvarchar(128)
declare @sql nvarchar(max)
set @sql = ''
DECLARE tableCursor CURSOR FOR  
SELECT name from sys.tables

open tableCursor
fetch next from tableCursor into @table

CREATE TABLE #TempTable( Tablename nvarchar(max), Bytes int, RowCnt int)

WHILE @@FETCH_STATUS = 0  
begin
    set @sql = 'insert into #TempTable (Tablename, Bytes, RowCnt) '
    set @sql = @sql + 'select '''+@table+''' "Table", sum(t.rowsize) "Bytes", count(*) "RowCnt" from (select (0'

    select @sql = @sql + ' + isnull(datalength([' + name + ']), 1) ' 
        from sys.columns where object_id = object_id(@table)
    set @sql = @sql + ') as rowsize from ' + @table + ' ) t '
    exec (@sql)
    FETCH NEXT FROM tableCursor INTO @table  
end

PRINT @sql

CLOSE tableCursor   
DEALLOCATE tableCursor

select * from #TempTable
select sum(bytes) "Sum" from #TempTable

DROP TABLE #TempTable

— Ромул
джерело

0

спробуйте це:

;WITH CTE as(select *,LEN(ISNULL(col1,''))+LEN(ISNULL(col2,'')) as row_len from yourtable)
select * from CTE where row_len > 8060

— АнандПхадке
джерело