Як я можу відповісти на запит мінібуфера від elisp?

Іноді я опиняюсь як використовую інтерактивні функції всередині функції, яку я пишу для власного використання. Якщо функція вимагає певної інформації (наприклад, "Вихідний файл: ~ /"), чи існує загальний спосіб додавання тексту до мінібуфера, а потім натисніть клавішу Enter, щоб користувачеві не довелося цього робити?

Наприклад, припустимо, що я хочу запускати org-latex-export-to-pdfфункцію, але я не хочу, щоб користувач вказував ім'я файлу. Біг (org-latex-export-to-pdf)перемістить крапку в мінібуфер, але, (insert "filename.tex")здається, щось подібне на наступному рядку не здається.

Цікава проблема. Схоже, редактор запускається post-command-hookкожного разу, коли він вводить новий командний цикл, тобто a recursive-edit. Але ми можемо почати з того minibuffer-setup-hook, що виконує функцію після входу в мінібуфер. Хоча це дозволяє вставляти вхід, занадто рано виходити з мінібуфера, оскільки улов ще не налаштовано.

(defmacro with-minibuffer-input (form &rest inputs)
  (declare (indent 1))
  `(minibuffer-with-setup-hook
       (lambda ()
         (minibuffer-input-provider ',inputs))
     ,form))

Ось це нам потрібно було загорнути «аргументи» у власний «командний цикл», який виконується кожного разу, коли ми вводимо a recursive-edit, і в цей момент він вискакує один аргумент і кидає один рівень вгору через exit-minibuffer.

;; -*- lexical-binding: t -*-
(defun minibuffer-input-provider (inputs)
  (let ((hook (make-symbol "hook")))
    (fset hook (lambda ()
                 (remove-hook 'post-command-hook hook)
                 (when inputs
                   (when (= 0 (minibuffer-depth))
                     (error "Too many inputs"))
                   (when (cdr inputs)
                     (add-hook 'post-command-hook hook))
                   (insert (pop inputs))
                   (exit-minibuffer))))
    (add-hook 'post-command-hook hook)))


(with-minibuffer-input (call-interactively 'find-file)
  "/")

(with-minibuffer-input (call-interactively 'occur)
  "\\(foo\\)\\(bar\\)" "\\1");;C-u C-x C-e

;;foobar

(with-minibuffer-input (call-interactively 'replace-string)
  "foo" "bar")

;; foo

Я написав макрос для цього під назвою with-simulated-input, який ви можете отримати тут . Це дозволяє надавати довільне введення, а також виконувати довільні форми lisp, щоб імітувати взаємодію користувачів.

Наприклад:

(with-simulated-input '("hello SPC" (insert "world") "RET")
  (read-string "Enter greeting: "))

повернеться "hello world", із "привіт", вставленим першим рядком, "світ", вставлений через код lisp, і нарешті "RET", щоб закінчити введення.

Поставляється з тестовим набором, який ви можете переглянути для більше прикладів використання.

Здається, що за допомогою run-with-timerз допомогою insertвийде робота.

(run-with-timer .2 nil 'insert "filename.tex")
(run-with-timer .3 nil 'execute-kbd-macro (kbd "RET"))
(org-latex-export-to-pdf)

Команда, insertрозміщена після цього, надто швидко з’являється. Він намагається вставити рядок до того, як є місце для його вставки.