mu4e - кілька облікових записів

Я використовую mu4eелектронну пошту в Emacs, і він наразі налаштований лише для одного облікового запису пошти, і я встановив ключ для перегляду різних вхідних. Цікаво, як використовувати mu4e для управління кількома обліковими записами електронної пошти?

Я використовую mu4e з двома обліковими записами. У кожного облікового запису є свій майлдір:

~/Mail
|
+---- work
|
`---- private

Посібник містить прикладну функцію для вибору облікового запису:

(defun my-mu4e-set-account ()
  "Set the account for composing a message."
  (let* ((account
          (if mu4e-compose-parent-message
              (let ((maildir (mu4e-message-field mu4e-compose-parent-message :maildir)))
                (string-match "/\\(.*?\\)/" maildir)
                (match-string 1 maildir))
            (completing-read (format "Compose with account: (%s) "
                                     (mapconcat #'(lambda (var) (car var))
                                                my-mu4e-account-alist "/"))
                             (mapcar #'(lambda (var) (car var)) my-mu4e-account-alist)
                             nil t nil nil (caar my-mu4e-account-alist))))
         (account-vars (cdr (assoc account my-mu4e-account-alist))))
    (if account-vars
        (mapc #'(lambda (var)
                  (set (car var) (cadr var)))
              account-vars)
      (error "No email account found"))))

;; ask for account when composing mail
(add-hook 'mu4e-compose-pre-hook 'my-mu4e-set-account)

Для цього вам також знадобляться my-mu4e-account-alist:

(defvar my-mu4e-account-alist
  '(("private"
     (user-mail-address  "private@domain.net")
     (user-full-name     "My Name")
     (mu4e-sent-folder   "/private/Sent Items")
     (mu4e-drafts-folder "/private/Drafts")
     (mu4e-trash-folder  "/private/Deleted Items")
     (mu4e-refile-folder "/private/Archive"))
    ("work"
     (user-mail-address  "work@domain.net")
     (mu4e-sent-folder   "/work/Sent Items")
     (mu4e-drafts-folder "/work/Drafts")
     (mu4e-trash-folder  "/work/Deleted Items")
     (mu4e-refile-folder "/work/Archives"))))

(setq mu4e-user-mail-address-list
      (mapcar (lambda (account) (cadr (assq 'user-mail-address account)))
              my-mu4e-account-alist))

Ви можете просто переключатися між папками пошти за допомогою j, якщо всі ваші поштові файли є підкаталогами mu4e-maildir.

Я на насправді використовувати більш складну функцію mu4e-trash-folderі , mu4e-refile-folderщоб уникнути переміщення листи від одного MAILDIR до іншого, але вищевказана інформація повинна бути достатньою , щоб використовувати кілька облікових записів.

Я використовую два різні облікові записи, які хочу якомога менше змішати.

offlineimap налаштовано з двома обліковими записами, один доставляє пошту в ~/.maildir-workінший ~/.maildir-home.

Моя конфігурація mu4e використовує новий контекстний механізм:

(setq mu4e-contexts
      `( ,(make-mu4e-context
           :name "home"
           :match-func (lambda (_) (string-equal "home" (mu4e-context-name mu4e~context-current)))
           :enter-func '()
           :leave-func (lambda () (mu4e-clear-caches))
           :vars '((mu4e-maildir . "~/.maildir-home")
                   (mu4e-mu-home . "~/.mu-home")
                   (mu4e-get-mail-command . "offlineimap -a Home")
                    ...))
         ,(make-mu4e-context
           :name "work"
           :match-func (lambda (_) (string-equal "work" (mu4e-context-name mu4e~context-current)))
           :enter-func '()
           :leave-func (lambda () (mu4e-clear-caches))
           :vars '((mu4e-maildir . "~/.maildir-work")
                   (mu4e-mu-home . "~/.mu-work")
                   (mu4e-get-mail-command . "offlineimap -a Work")
                   ...))))

Я використовую налаштування, дуже схоже на Magnus ', і просто хотів додати, що (mu4e-quit)існує, і він прекрасно працює для очищення облікових записів без перезавантаження. Фактичний механізм:

(defun mail-gmail ()
  (interactive)
  (setenv "MAILDIR" "/Users/foo/Maildir/gmail")
  (setenv "MU_HOME" "/Users/foo/.mu/gmail")
  (setq mu4e-maildir "/Users/foo/Maildir/gmail")
  (setq user-mail-address "...")
  (mu4e-quit))