Як перенести два аргументи функції в Python?

Як я можу поміняти два аргументи під час виклику функції Python?

Якщо я поставлю pointпробіл між цими двома аргументами:

self.assertEqual(json.loads(some.data), json_data)

а потім M-t( transpose-words) я отримую:

self.assertEqual(json.loads(some.json), data_data)

З іншого боку, з CMt ( transpose-sexps) я отримую:

self.assertEqual(json.loadsjson_data, (some.data))

Що я хочу:

self.assertEqual(json_data, json.loads(some.data))

Чи є команда, яка це зробить?

Це я теж давно хотів мати, і тут я знайшов певну мотивацію працювати над цим. Напевно, це не дуже надійно, але при першій спробі, здається, висвітлюються випадки, які я намагався:

(defun my/calculate-stops ()
  (save-excursion
    (let ((start
           (condition-case e
               (while t (backward-sexp))
             (error (point))))
          stops)
      (push start stops)
      (condition-case e
          (while t
            (forward-sexp)
            (when (looking-at "\\s-*,")
              (push (point) stops)))
        (error (push (point) stops)))
      (nreverse stops))))

(defun my/transpose-args ()
  (interactive)
  (when (looking-at "\\s-") (backward-sexp))
  (cl-loop with p = (point)
           with previous = nil
           for stop on (my/calculate-stops)
           for i upfrom 0
           when (<= p (car stop)) do
           (when previous
             (let* ((end (cadr stop))
                    (whole (buffer-substring previous end))
                    middle last)
               (delete-region previous end)
               (goto-char previous)
               (setf middle (if (> i 1) (- (car stop) previous)
                              (string-match "[^, \\t]" whole 
                                            (- (car stop) previous)))
                     last (if (> i 1) (substring whole 0 middle)
                            (concat (substring whole (- (car stop) previous) middle)
                                    (substring whole 0 (- (car stop) previous)))))
               (insert (substring whole middle) last)))
           (cl-return)
           end do (setf previous (car stop))))

Я використовую варіант, transpose-sexpsякий шукає випадок, який ви описуєте, і переміщує речі, розділені комами, або просто регулярно transpose-sexps. Він також залишає курсор на місці замість того, щоб тягнути його вперед, що дещо інакше, але мені особисто подобається.

(defun my-transpose-sexps ()
  "If point is after certain chars transpose chunks around that.
Otherwise transpose sexps."
  (interactive "*")
  (if (not (looking-back "[,]\\s-*" (point-at-bol)))
      (progn (transpose-sexps 1) (forward-sexp -1))
    (let ((beg (point)) end rhs lhs)
      (while (and (not (eobp))
                  (not (looking-at "\\s-*\\([,]\\|\\s)\\)")))
        (forward-sexp 1))
      (setq rhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (re-search-backward "[,]\\s-*" nil t)
      (setq beg (point))
      (while (and (not (bobp))
                  (not (looking-back "\\([,]\\|\\s(\\)\\s-*" (point-at-bol))))
        (forward-sexp -1))
      (setq lhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (insert rhs)
      (re-search-forward "[,]\\s-*" nil t)
      (save-excursion
        (insert lhs)))))

У режимах, які використовують SMIE, transpose-sexpслід правильно працювати в цьому випадку. Вони все одно не зможуть, коли символ інфіксації (він же "роздільник") не є ,(або a ;), а є словом (наприклад and).

Отже, моя думка полягає в тому, що команда для цього є, transpose-sexpі коли це працює не правильно, я вважаю це помилкою (але помилка, яка може бути важкою та / або потребує часу, щоб виправити і мати низький пріоритет, тому не ' т затримати дихання). Спосіб її виправити - це встановити forward-sexp-functionфункцію, яка буде знати, що "після того, як я побачу кому, я просто стрибаю весь аргумент".