Виділення змінних оболонок в лапках

In vim, наступний документ призведе до того, що $PWDрядки 2 та 3 будуть пофарбовані двома різними способами:

#/bin/sh
echo "Current Directory: $PWD"
echo 'Current Directory: $PWD'

Перший екземпляр $PWDбуде в іншому кольорі від решти рядка, в якому він знаходиться. Це дає чітку візуальну вказівку на те, що змінна буде розширена, а не розглядається як буквальний текст. На відміну від цього, другий екземпляр $PWDкольору буде кольоровим так само, як і решта рядка, оскільки одиничні лапки спричиняють, що це трактується як буквальний текст.

Чи існують якісь режими emacs, які забезпечують такий тип "обізнаності про цитування оболонок"?

У наведеному нижче коді використовується правило блокування шрифту з функцією замість регулярного виразу, функція пошуку подій, $VARале лише тоді, коли вони знаходяться всередині дворядкового рядка. Функція (syntax-ppss)використовується для визначення цього.

Правило блокування шрифту використовує prependпрапор, щоб додати себе до існуючого виділення рядка. (Зверніть увагу, що tдля цього використовується багато пакунків . На жаль, це замінює всі аспекти існуючого підсвічування. Наприклад, використання prependзбереже кольоровий колір фону (якщо такий є) під час заміни кольору переднього плану.)

(defun sh-script-extra-font-lock-is-in-double-quoted-string ()
  "Non-nil if point in inside a double-quoted string."
  (let ((state (syntax-ppss)))
    (eq (nth 3 state) ?\")))

(defun sh-script-extra-font-lock-match-var-in-double-quoted-string (limit)
  "Search for variables in double-quoted strings."
  (let (res)
    (while
        (and (setq res
                   (re-search-forward
                    "\\$\\({#?\\)?\\([[:alpha:]_][[:alnum:]_]*\\|[-#?@!]\\)"
                    limit t))
             (not (sh-script-extra-font-lock-is-in-double-quoted-string))))
    res))

(defvar sh-script-extra-font-lock-keywords
  '((sh-script-extra-font-lock-match-var-in-double-quoted-string
     (2 font-lock-variable-name-face prepend))))

(defun sh-script-extra-font-lock-activate ()
  (interactive)
  (font-lock-add-keywords nil sh-script-extra-font-lock-keywords)
  (if (fboundp 'font-lock-flush)
      (font-lock-flush)
    (when font-lock-mode
      (with-no-warnings
        (font-lock-fontify-buffer)))))

Ви можете зателефонувати використовувати це, додавши останню функцію у відповідний гачок, наприклад:

(add-hook 'sh-mode-hook 'sh-script-extra-font-lock-activate)

Я вдосконалив відповідь @ Lindydancer такими способами:

• Накреслив sh-script-extra-font-lock-is-in-double-quoted-stringфункцію, оскільки вона була використана лише один раз
• Уникнення змінної працює.
• Виділено числові змінні ( $10, $1тощо).

Перерва на код

(defun sh-script-extra-font-lock-match-var-in-double-quoted-string (limit)
  "Search for variables in double-quoted strings."
  (let (res)
    (while
        (and (setq res (progn (if (eq (get-byte) ?$) (backward-char))
                              (re-search-forward
                               "[^\\]\\$\\({#?\\)?\\([[:alpha:]_][[:alnum:]_]*\\|[-#?@!]\\|[[:digit:]]+\\)"
                               limit t)))
             (not (eq (nth 3 (syntax-ppss)) ?\")))) res))

(defvar sh-script-extra-font-lock-keywords
  '((sh-script-extra-font-lock-match-var-in-double-quoted-string
     (2 font-lock-variable-name-face prepend))))

(defun sh-script-extra-font-lock-activate ()
  (interactive)
  (font-lock-add-keywords nil sh-script-extra-font-lock-keywords)
  (if (fboundp 'font-lock-flush)
      (font-lock-flush)
    (when font-lock-mode (with-no-warnings (font-lock-fontify-buffer)))))