Присвоєння однакового значення декільком змінним?

Іноді мені потрібно встановити одне значення для кількох змінних.

У Python я міг би зробити

f_loc1 = f_loc2 = "/foo/bar"

Але в Еліспі я пишу

(setq f_loc1 "/foo/bar" f_loc2 "/foo/bar")

Мені цікаво, чи є спосіб досягти цього, використовуючи "/foo/bar"лише один раз?

setq повертає значення, тож ви можете просто:

(setq f-loc1 (setq f-loc2 "/foo/bar"))

Якщо ви не хочете покладатися на це, тоді використовуйте:

(setq f-loc1 "/foo/bar" f-loc2 f-loc1)

Особисто я би уникав останнього і замість цього писав:

(setq f-loc1 "/foo/bar"
      f-loc2 f-loc1)

або навіть

(setq f-loc1 "/foo/bar")
(setq f-loc2 f-loc1)

І найперший підхід я застосував би лише у досить особливих обставинах, коли він насправді наголошує на намірі, або коли альтернативою буде використання другого підходу progn.

Ви можете перестати читати тут, якщо вищезгадане робить вас щасливим. Але я думаю, що це хороша можливість попередити вас та інших, щоб не зловживати макросами.

Нарешті, хоча спокушати писати макрос на кшталт setq-every"тому що це ліс і ми можемо", я настійно рекомендую не робити цього. Ви отримуєте дуже мало, роблячи це:

(setq-every value a b)
   vs
(setq a (setq b value))

Але в той же час ви набагато складніше читачам читати код і бути впевненим, що відбувається. setq-everyможе бути реалізовано різними способами, і інші користувачі (включаючи майбутнього, який ви) не можете знати, кого обрати автор, просто подивившись на код, який його використовує. [Я спочатку робив тут кілька прикладів, але їх хтось вважав саркастичними і шахрайством.]

Ви можете боротися з цим розумовим накладним покриттям кожного разу, коли дивитесь, setq-everyабо можете просто жити з одним додатковим персонажем. (Принаймні у випадку, коли вам потрібно встановити лише дві змінні, але я не можу згадати, що мені коли-небудь доводилося встановлювати більше двох змінних на одне і те ж значення одразу. Якщо ви повинні це зробити, то, мабуть, щось інше не так з кодом.)

З іншого боку, якщо ви дійсно збираєтесь використовувати цей макрос більше, ніж можливо, півдесятка разів, то додаткове опосередкування може бути варте того. Наприклад, я використовую макроси, як --when-letу dash.elбібліотеці. Це ускладнює тим, хто вперше стикається з цим у моєму коді, але подолання цієї складності в розумінні того варте, тому що він використовується більше, ніж лише в декілька разів, і, принаймні, на мою думку, робить код більш читабельним .

Можна стверджувати, що те саме стосується setq-every, але я думаю, що дуже малоймовірно, що саме цей макрос буде використовуватися більше ніж кілька разів. Хорошим правилом є те, що коли визначення макросу (включаючи doc-рядок) додає більше коду, ніж використання макросу видаляє, тоді макрос дуже ймовірно є надмірним (хоча зворотне не обов'язково відповідає дійсності).

Макрос робити те, що ви хочете

Як своєрідна вправа:

(defmacro setq-every (value &rest vars)
  "Set every variable from VARS to value VALUE."
  `(progn ,@(mapcar (lambda (x) (list 'setq x value)) vars)))

Тепер спробуйте:

(setq-every "/foo/bar" f-loc1 f-loc2)

Як це працює

Оскільки людям цікаво, як це працює (за коментарями), ось пояснення. Щоб дійсно навчитися писати макроси, виберіть хорошу загальну книгу Lisp (так, Common Lisp, ви зможете робити те саме в Emacs Lisp, але Common Lisp трохи потужніший і має кращі книги, IMHO).

Макроси працюють на необробленому коді. Макроси не оцінюють їх аргументи (на відміну від функцій). Отже, ми маємо тут неоцінену valueі колекцію vars, які для нашого макросу є просто символами.

prognгрупує кілька setqформ в одну. Ця річ:

(mapcar (lambda (x) (list 'setq x value)) vars)

Просто формує список setqформ, використовуючи приклад ОП, це буде:

((setq f-loc1 "/foo/bar") (setq f-loc2 "/foo/bar"))

Розумієте, форма знаходиться у формі зворотного котирування і має префікс комою ,. У внутрішній формі з котируванням все цитується як зазвичай, але , оцінка "включення" тимчасово, тому ціле mapcarоцінюється в час макророзширення.

Нарешті, @видаляється зовнішня дужка із списку з setqs, тому ми отримуємо:

(progn
  (setq f-loc1 "/foo/bar")
  (setq f-loc2 "/foo/bar"))

Макроси можуть довільно перетворювати ваш вихідний код, чи не це здорово?

Застереження

Ось невеликий застереження, перший аргумент буде оцінено кілька разів, оскільки цей макрос по суті розширюється до наступного:

(progn
  (setq f-loc1 "/foo/bar")
  (setq f-loc2 "/foo/bar"))

Розумієте, якщо у вас є змінна чи рядкова тут, це нормально, але якщо ви пишете щось подібне:

(setq-every (my-function-with-side-effects) f-loc1 f-loc2)

Тоді ваша функція буде називатися не один раз. Це може бути небажаним. Ось як це виправити за допомогою once-only(доступний у пакеті MMT ):

(defmacro setq-every (value &rest vars)
  "Set every variable from VARS to value VALUE.

VALUE is only evaluated once."
  (mmt-once-only (value)
    `(progn ,@(mapcar (lambda (x) (list 'setq x value)) vars))))

І проблеми вже немає.

Оскільки ви можете використовувати та маніпулювати символами у lisp, ви можете просто перевести цикл на список символів та використовувати set.

(dolist (var '(foo bar baz)) (set var 10))

(mapc (lambda (var) (set var 10)) '(foo bar baz))

(loop for var in '(foo bar baz) do (set var 11))

(--each '(foo bar baz) (set it 10))