Emacs - обмежена порада

Я хотів би тимчасово змінити функцію в фрагменті коду.

Візьмемо, наприклад, таке:

(defun nadvice/load-quiet (args)
  (cl-destructuring-bind
      (file &optional noerror nomessage nosuffix must-suffix)
      args
    (list file noerror t nosuffix must-suffix)))

(defun nadvice/idle-require-quiet (old-fun &rest args)
    (advice-add 'load :filter-args #'nadvice/load-quiet)
    (apply old-fun args)
    (advice-remove #'load #'nadvice/load-quiet))

(advice-add 'idle-require-load-next :around #'nadvice/idle-require-quiet)

Що не працює:

• Це. Було б набагато чіткіше, якби я міг уникнути вручну ввімкнення та відключення порад і довіритися однопоточному характеру Emacs, щоб піклуватися про речі.
• cl-letfне дозволить мені посилатися на оригінальну функцію, тому я не можу реалізувати речі, які :filter-argsзазвичай роблять.
• cl-flet не може змінювати функції інших функцій.
• nofletце зовнішній пакет, який я хотів би уникнути. (Також робить набагато більше, ніж мені потрібно)

Хіба ви не можете використовувати (cl-)letf, посилаючись на оригінальну функцію самостійно?

Щось на зразок цього:

;; Original function
(defun my-fun (arg)
  (message "my-fun (%s)" arg))


;; Standard call
(my-fun "arg") ;; => my-fun (arg)


;; Temporary overriding (more or less like an around advice)
(let ((orig-fun (symbol-function 'my-fun)))
  (letf (((symbol-function 'my-fun)
          (lambda (arg)
            ;; filter arguments
            (funcall orig-fun (concat "modified-" arg)))))
    (my-fun "arg")))
;; => my-fun (modified-arg)


;; The overriding was only temporary
(my-fun "arg") ;; => my-fun (arg)

Ви також можете обернути це в макрос, якщо плануєте його повторно використовувати:

(defmacro with-advice (args &rest body)
  (declare (indent 1))
  (let ((fun-name (car args))
        (advice   (cadr args))
        (orig-sym (make-symbol "orig")))
    `(cl-letf* ((,orig-sym  (symbol-function ',fun-name))
                ((symbol-function ',fun-name)
                 (lambda (&rest args)
                   (apply ,advice ,orig-sym args))))
       ,@body)))

Приклад вище можна потім переписати таким чином:

(defun my-fun (arg)
  (message "my-fun (%s)" arg))


(my-fun "my-arg")

(with-advice (my-fun
              (lambda (orig-fun arg)
                (funcall orig-fun (concat "modified-" arg))))
  (my-fun "my-arg"))

(my-fun "my-arg")