Як змінити частини спеціальної теми?

Я використовую одну із заздалегідь визначених користувацьких тем, які поставляються в комплекті з Spacemacs (zenburn).

Як я можу змінити конкретні частини теми, наприклад просто змінити колір шрифту, який використовується для коментарів?

Я віддаю перевагу використанню custom-theme-set-facesдля визначення нового способу відображення конкретного обличчя, наприклад,

(custom-theme-set-faces
 'zenburn
 '(font-lock-comment-face ((t (:foreground "#DFAF8F"))))
 '(font-lock-comment-delimiter-face ((t (:foreground "#DFAF8F")))))

Для конкретного випадку zenburnтема сама визначає різні кольори та макрос, у яких вони пов'язані із іменами змінних, тож ви можете записати вищезгадане як:

(zenburn-with-color-variables
  (custom-theme-set-faces
   'zenburn
   `(font-lock-comment-face ((t (:foreground ,zenburn-orange))))
   `(font-lock-comment-delimiter-face ((t (:foreground ,zenburn-orange))))))

В Spacemacs встановіть шар theming, див. Https://github.com/syl20bnr/spacemacs/tree/master/layers/%2Bthemes/theming

Наприклад, у мене є наступний пропущений в dotspacemacs/user-initз моїх .spacemacsрегулювати колір фону і LINENUMBER кольору gruvbox і соляризацію-світлу тема:

  (setq theming-modifications '(
    ;; requires the theming layer
    (gruvbox
       (default :background "#1D2021" :foreground "#fdf4c1")
       (linum :background "#000000" :foreground "#878787")
       (fringe  :background "#000000")
       (linum-relative-current-face :inherit (shadow default) :background "#3C3836" :foreground "#ff0000")
       (font-lock-comment-face :slant italic)
    )
    (solarized-light
     (linum :background "#DBCDA7" :foreground "#40371F")
       (fringe :background "#DBCDA7")
       (font-lock-comment-face :slant italic)
       )
))

Я додав пораду до функції завантаження теми, щоб змінити певні обличчя - таким чином ви можете продовжувати використовувати тему завантаження як звичайну для вибору теми, і вона застосовуватиме зміни автоматично.

(defadvice load-theme (after theme-set-overrides activate)
  "Set override faces for different custom themes."
  (dolist (theme-settings theme-overrides)
    (let ((theme (car theme-settings))
          (faces (cadr theme-settings)))
      (if (member theme custom-enabled-themes)
          (dolist (face faces)
            (custom-theme-set-faces theme face))))))

(defcustom theme-overrides nil
  "Association list of override faces to set for different custom themes.")

(defun alist-set (alist-symbol key value)
  "Set VALUE of a KEY in ALIST-SYMBOL."
  (set alist-symbol
        (cons (list key value) (assq-delete-all key (eval alist-symbol)))))

; override some settings of the ample-flat theme
(alist-set 'theme-overrides 'ample-flat '(
                                          (default ((t (:background "gray12" :foreground "#bdbdb3"))))
                                          (mode-line ((t (:background "cornsilk4" :foreground "#222" :inherit 'variable-pitch))))
                                          (outline-2 ((t (:inherit font-lock-keyword-face)))) ; blueish
                                          (outline-3 ((t (:inherit font-lock-comment-face)))) ; brownish
                                          (outline-4 ((t (:inherit font-lock-string-face)))) ; orangeish
                                          (org-table ((t (:inherit fixed-pitch :height 0.7 :foreground "#887"))))
                                          (org-formula ((t (:inherit org-table :foreground nil))))
                                          ))

Це працює, і було б непогано мати частину інтерфейсу, але, мабуть, найпростіше просто зробити функцію для кожної теми, яку ви використовуєте, і викликати користувальницькі теми-набори-обличчя після завантаження -

(defun ample-flat ()
  (interactive)
  (mapc #'disable-theme custom-enabled-themes) ; clear any existing themes
  (load-theme 'ample-flat t)
  (custom-theme-set-faces 'ample-flat 
                          '(default ((t (:background "gray12" :foreground "#bdbdb3"))))
                          '(mode-line ((t (:background "cornsilk4" :foreground "#222" :inherit 'variable-pitch))))
                          '(outline-2 ((t (:inherit font-lock-keyword-face)))) ; blueish
                          '(outline-3 ((t (:inherit font-lock-comment-face)))) ; brownish
                          '(outline-4 ((t (:inherit font-lock-string-face)))) ; orangeish
                          '(org-table ((t (:inherit fixed-pitch :height 0.7 :foreground "#887"))))
                          '(org-formula ((t (:inherit org-table :foreground nil))))
                          ))

(ample-flat)

Приклад того, що я зробив для редагування spacemacs-dark, видаливши пару шрифтів, які мені не подобаються:

  ;; on dotspacemacs/user-config:

  ;; configure spacemacs-dark theme, specifically removing bolds
  (let
      ((func "#d75fd7")
       (keyword "#4f97d7")
       (type "#ce537a"))

    (custom-theme-set-faces
     'spacemacs-dark
     `(font-lock-function-name-face ((t (:foreground ,func :inherit normal))))
     `(font-lock-keyword-face ((t (:foreground ,keyword :inherit normal))))
     `(font-lock-type-face ((t (:foreground ,type :inherit normal))))
     )
    )

Вам може бути простіше просто використовувати SPC SPC custom-theme-visit-theme, знаходити gruvbox, вносити зміни до них, а потім просто розміщувати (load-file "~/.emacs.d/gruvbox-theme.el")у своїй dotspacemacs/user-configфункції.