зробіть `попередній-буфер` і` наступний-буфер`, щоб ігнорувати деякі буфери

10

в Helm я ігнорую деякі буфери, які не відображаються при використанні C-x b, я шукаю спосіб скласти команди previous-bufferі next-bufferповодяться так само, ігноруючи деякі буфери.

buffers

— шакра
джерело

8

Ось два способи:

Якщо ви подивитесь на визначення функції switch-to-next-buffer(у бібліотеці window.el), ви побачите, що вона фільтрує буфери за присудком (якщо такий є), що є значенням параметра фрейму buffer-predicate. Цю функцію використовує next-buffer.

Ви можете встановити цей параметр кадру на предикат, який фільтрує так, як вам потрібно.
Ви можете просто порадити функцію switch-to-next-bufferфільтрувати так, як вам потрібно. Ви по суті заміните його визначення майже тим самим визначенням, але додатково фільтруєте так, як вам потрібно.

Аналогічно для switch-to-previous-buffer.

— Малював
джерело

7

(defvar my-skippable-buffers '("*Messages*" "*scratch*" "*Help*")
  "Buffer names ignored by `my-next-buffer' and `my-previous-buffer'.")

(defun my-change-buffer (change-buffer)
  "Call CHANGE-BUFFER until current buffer is not in `my-skippable-buffers'."
  (let ((initial (current-buffer)))
    (funcall change-buffer)
    (let ((first-change (current-buffer)))
      (catch 'loop
        (while (member (buffer-name) my-skippable-buffers)
          (funcall change-buffer)
          (when (eq (current-buffer) first-change)
            (switch-to-buffer initial)
            (throw 'loop t)))))))

(defun my-next-buffer ()
  "Variant of `next-buffer' that skips `my-skippable-buffers'."
  (interactive)
  (my-change-buffer 'next-buffer))

(defun my-previous-buffer ()
  "Variant of `previous-buffer' that skips `my-skippable-buffers'."
  (interactive)
  (my-change-buffer 'previous-buffer))

(global-set-key [remap next-buffer] 'my-next-buffer)
(global-set-key [remap previous-buffer] 'my-previous-buffer)

— філи
джерело