Як написати прозору обгортку функції «прохідна»?

Що я маю на увазі під "прозорою" обгорткою функції пропуску "- це функція, назвемо її wrapper, яка повертає результат від передачі всіх його аргументів на якусь іншу функцію, назвемо її wrappee.

Як це робиться в Emacs Lisp?

NB: Ідеальна wrapperфункція є агностичною щодо wrappeeпідпису функції; тобто він нічого не знає про кількість, позиції, імена тощо wrappeeаргументів 's; він просто передає всі свої аргументи wrappee, так само, як ніби wrappeeвін був спочатку названий. (Однак не потрібно возитися зі стеком викликів, щоб замінити дзвінок на wrapperдзвінок wrappee.)

Я розмістив часткову відповідь на своє запитання:

(defun wrapper (&rest args) (apply 'wrappee args))

Це працює лише тоді, коли wrappeeвін не є інтерактивним. Мабуть, те, як інтерактивні функції отримують свої аргументи, являє собою інший "канал" від того, що охоплюється (&rest args)закликом. Тому мені все-таки потрібно wrappeeоднаково -агностичний аналог (&rest args)підпису для випадку, коли wrappeeце інтерактивна функція.

(Це питання мотивоване проблемою, описаною в цьому попередньому запитанні .)

У разі, якщо потрібне додаткове роз'яснення того, про що я прошу, нижче наведено кілька прикладів, що показують еквіваленти Python та JavaScript того, що я хочу.

У Python наведено кілька стандартних способів реалізації такої обгортки:

def wrapper(*args, **kwargs):
    return wrappee(*args, **kwargs)

# or

wrapper = lambda *args, **kwargs: wrappee(*args, **kwargs)

(Тут *argsрозшифровується "всі позиційні аргументи" і **kwargsозначає "всі аргументи ключового слова".)

Еквівалент JavaScript буде приблизно таким:

function wrapper () { return wrappee.apply(this, arguments); }

// or

wrapper = function () { return wrappee.apply(this, arguments); }

Для запису я не погоджуюся, що це питання є дублікатом того, як застосувати mapcar до функції з кількома аргументами . Мені не вдається пояснити, чому, оскільки два питання мені так очевидно виглядають по-різному. Це як би попросити "пояснити, чому яблуко не слід вважати рівнозначним апельсину". Просте запитання настільки божевільне, що можна сумніватися, що коли-небудь можна було б відповісти, що задовольнить людину, яка його запитує.

Звичайно, можливо включення interactiveспецифікації. Ми маємо справу тут із Еліспом ! (Lisp - це мова, на якій найважливіші конструкції - це списки. Форми, що викликаються - це лише списки. Отже, ви можете їх сконструювати за своїм смаком.)

Застосування: Ви хочете додати деякі функції деяким функціям автоматично. Розширеним функціям слід давати нові імена, щоб defadviceце не було застосовано.

Спочатку версія, яка цілком відповідає вашим цілям. Ми встановлюємо функціональну комірку ( fset) символу wrapperз усією необхідною інформацією wrappeeта додаємо наші додаткові матеріали.

Він працює для обох wrappeeвизначень. Перша версія wrappee- інтерактивна, друга - ні.

(defun wrappee (num str)
  "Nontrivial wrappee."
  (interactive "nNumber:\nsString:")
  (message "The number is %d.\nThe string is \"%s\"." num str))

(defun wrappee (num str)
  "Noninteractive wrappee."
  (message "The number is %d.\nThe string is \"%s\"." num str))

(fset 'wrapper (list 'lambda
             '(&rest args)
             (concat (documentation 'wrappee t) "\n Wrapper does something more.")
             (interactive-form 'wrappee)
             '(prog1 (apply 'wrappee args)
            (message "Wrapper does something more."))))

Але зручніше визначити макрос, який будує розширені функції. Тим самим ми можемо навіть потім вказати назви функцій. (Добре для автоматизованої версії.)

Після виконання коду нижче ви можете зателефонувати в wrapper-interactiveінтерактивному та wrapper-non-interactiveнеінтерактивному режимі.

(defmacro make-wrapper (wrappee wrapper)
  "Create a WRAPPER (a symbol) for WRAPPEE (also a symbol)."
  (let ((arglist (make-symbol "arglist")))
  `(defun ,wrapper (&rest ,arglist)
     ,(concat (documentation wrappee) "\n But I do something more.")
     ,(interactive-form wrappee)
     (prog1 (apply (quote ,wrappee) ,arglist)
       (message "Wrapper %S does something more." (quote ,wrapper))))))

(defun wrappee-interactive (num str)
  "That is the doc string of wrappee-interactive."
  (interactive "nNumber:\nsString:")
  (message "The number is %d.\nThe string is \"%s\"." num str))

(defun wrappee-non-interactive (format &rest arglist)
  "That is the doc string of wrappee-non-interactive."
  (apply 'message format arglist))

(make-wrapper wrappee-interactive wrapper-interactive)
(make-wrapper wrappee-non-interactive wrapper-non-interactive)
;; test of the non-interactive part:
(wrapper-non-interactive "Number: %d, String: %s" 1 "test")

Зауважте, до цього часу я ще не знайшов способу передати форми декларування, але це також повинно бути можливим.

Мені довелося вирішити дуже подібну проблему nadvice.el, тому ось рішення (яке використовує частину коду від nadvice.el):

(defun wrapper (&rest args)
  (interactive (advice-eval-interactive-spec
                (cadr (interactive-form #'wrappee))))
  (apply #'wrappee args))

У порівнянні з іншими рішеннями, розміщеними до цих пір, це має перевагу правильно працювати, якщо wrappeeвін переосмислюється іншою інтерактивною специфікацією (тобто не продовжує використовувати стару специфікацію).

Звичайно, якщо ви хочете, щоб ваша обгортка була справді прозорою, ви можете зробити це простіше:

(defalias 'wrapper #'wrappee)

редагувати: Відповідь Тобіаса приємніша за це, оскільки вона отримує точну інтерактивну форму та докстринг оберненої функції.

Поєднуючи відповіді Аарона Гарріса і кіо, ви можете використовувати щось на кшталт:

(defmacro my-make-wrapper (fn &optional name)
  "Return a wrapper function for FN defined as symbol NAME."
  `(defalias ',(or (eval name)
                   (intern (concat "my-" (symbol-name (eval fn)) "-wrapper")))
     (lambda (&rest args)
       ,(format "Generic wrapper for %s."
                (if (symbolp (eval fn))
                    (concat "`" (symbol-name (eval fn)) "'")
                  fn))
       (interactive)
       (if (called-interactively-p 'any)
           (call-interactively ,fn)
         (apply ,fn args)))))

Використання:

(my-make-wrapper 'find-file 'wrapper-func)

Зателефонуйте:

(wrapper-func "~/.emacs.d/init.el")

M-x wrapper-func