Розглядаючи наявні чотири відповіді ( два на Super User та два на це питання), я бачу такі питання:
- Ті , що в SuperUser від Стефана та Пен Бая (рухаються по рядку, дивлячись на поточний відступ), не реалізують збереження поточного положення стовпця та переміщення до батьківського,
- Відповідь Дан ( з використанням повторного пошуку вперед , щоб знайти наступний рядок з тим же відступом) скаче по лініях з меншим відступом: він не знає , коли немає поруч рідний брата, і , отже , може рухатися до чого - то , що не є спорідненим але дитина іншого батька ... можливо, наступний "двоюрідний брат".
- Відповідь на Жиль ( з використанням контуру-режим) не зберігається позицію стовпця і вона не працює з рядками з нульовим відступом ( «верхнього рівня» лінії). Крім того, дивлячись на його код
outline.el, він також в основному йде по outline-next-visible-headingодному рядку в будь-якому випадку (використовуючи ) в нашому випадку, оскільки (майже) всі рядки будуть відповідати контуру регулярним виразом і вважатись "заголовком".
Отже, складаючи деякі ідеї кожного, у мене є наступне: рухатися вперед по черзі, пропускаючи порожні та більш відрізні рядки. Якщо ви з рівним відступом, то це наступний брат. Основна ідея виглядає так:
(defun indentation-get-next-sibling-line ()
"The line number of the next sibling, or nil if there isn't any."
(let ((wanted-indentation (current-indentation)))
(save-excursion
(while (and (zerop (forward-line)) ; forward-line returns 0 on success
(or (eolp) ; Skip past blank lines and more-indented lines
(> (current-indentation) wanted-indentation))))
;; Now we can't go further. Which case is it?
(if (and (not (eobp)) (= (current-indentation) wanted-indentation))
(line-number-at-pos)
nil))))
(defun indentation-forward-to-next-sibling ()
(interactive)
(let ((saved-column (current-column)))
(forward-line (- (indentation-get-next-sibling-line) (line-number-at-pos)))
(move-to-column saved-column)))
Відповідно узагальнений (вперед / назад / вгору / вниз), що я зараз використовую, виглядає наступним чином:
(defun indentation-get-next-good-line (direction skip good)
"Moving in direction `direction', and skipping over blank lines and lines that
satisfy relation `skip' between their indentation and the original indentation,
finds the first line whose indentation satisfies predicate `good'."
(let ((starting-indentation (current-indentation))
(lines-moved direction))
(save-excursion
(while (and (zerop (forward-line direction))
(or (eolp) ; Skip past blank lines and other skip lines
(funcall skip (current-indentation) starting-indentation)))
(setq lines-moved (+ lines-moved direction)))
;; Now we can't go further. Which case is it?
(if (and
(not (eobp))
(not (bobp))
(funcall good (current-indentation) starting-indentation))
lines-moved
nil))))
(defun indentation-get-next-sibling-line ()
"The line number of the next sibling, if any."
(indentation-get-next-good-line 1 '> '=))
(defun indentation-get-previous-sibling-line ()
"The line number of the previous sibling, if any"
(indentation-get-next-good-line -1 '> '=))
(defun indentation-get-parent-line ()
"The line number of the parent, if any."
(indentation-get-next-good-line -1 '>= '<))
(defun indentation-get-child-line ()
"The line number of the first child, if any."
(indentation-get-next-good-line +1 'ignore '>))
(defun indentation-move-to-line (func preserve-column name)
"Move the number of lines given by func. If not possible, use `name' to say so."
(let ((saved-column (current-column))
(lines-to-move-by (funcall func)))
(if lines-to-move-by
(progn
(forward-line lines-to-move-by)
(move-to-column (if preserve-column
saved-column
(current-indentation))))
(message "No %s to move to." name))))
(defun indentation-forward-to-next-sibling ()
"Move to the next sibling if any, retaining column position."
(interactive "@")
(indentation-move-to-line 'indentation-get-next-sibling-line t "next sibling"))
(defun indentation-backward-to-previous-sibling ()
"Move to the previous sibling if any, retaining column position."
(interactive "@")
(indentation-move-to-line 'indentation-get-previous-sibling-line t "previous sibling"))
(defun indentation-up-to-parent ()
"Move to the parent line if any."
(interactive "@")
(indentation-move-to-line 'indentation-get-parent-line nil "parent"))
(defun indentation-down-to-child ()
"Move to the first child line if any."
(interactive "@")
(indentation-move-to-line 'indentation-get-child-line nil "child"))
Є ще кілька бажаних функціональних можливостей, і перегляд outline.elі повторне доповнення деяких з них може допомогти, але я зараз задоволений цим для своїх цілей.
set-selective-displayнаближаєтесь ви до того, що вам потрібно?