Як змусити повторну оцінку дефавару?

Припустимо, у мене буфер Emacs lisp, який містить:

(defvar foo 1)

Якщо я дзвоню eval-last-sexpабо eval-buffer, fooприв'язується до 1. Якщо я потім редагую цей буфер:

(defvar foo 2)

eval-last-sexpі eval-bufferне виконувати повторно цей рядок, так fooце ще 1.

Це особливо складно, коли таких заяв декілька, і я повинен відстежувати, які рядки не піддаються повторній оцінці.

Я переглянув лише перезапуск Emacs, а потім (require 'foo), але тоді я повинен бути обережним, щоб не завантажувати старіші файли .elc.

Як я можу бути абсолютно впевнено впевненим, що змінні та функції, визначені в поточному файлі, перебувають у тому ж стані, що і знову завантаження коду в новому екземплярі Emacs?

Як пояснено в інших відповідях, оцінювання defvarформи за допомогою eval-last-sexpне скидає значення за замовчуванням.

Замість цього, ви можете використовувати eval-defun(зобов'язані C-M-xв emacs-lisp-modeза замовчуванням), який реалізує поведінку , яке ви хочете в якості особливого винятку:

Якщо поточне замикання насправді є викликом defvarабо defcustom, оцінюючи його таким чином, скидає змінну, використовуючи її початкове значення вираження, навіть якщо змінна вже має якесь інше значення. (Зазвичай defvarі defcustomне змінюйте значення, якщо воно вже є.)

Якщо вам потрібно оцінити повний вміст буфера, ви можете написати функцію, яка переходить по черзі форми верхнього рівня і закликає eval-defunкожен. Щось подібне повинно працювати:

(defun my/eval-buffer ()
  "Execute the current buffer as Lisp code.
Top-level forms are evaluated with `eval-defun' so that `defvar'
and `defcustom' forms reset their default values."
  (interactive)
  (save-excursion
    (goto-char (point-min))
    (while (not (eobp))
      (forward-sexp)
      (eval-defun nil))))

Як говорять інші відповіді, це лише спосіб дефарвації, але ви можете обійти це, зрештою, це майже все.

Ви можете тимчасово переосмислити, як працює defvar, якщо хочете, і за цей час перезавантажте пакунки, які хочете скинути.

Я написав макрос, де під час оцінювання тіла значення девальваторів завжди будуть переоцінені.

(defmacro my-fake-defvar (name value &rest _)
  "defvar impersonator that forces reeval."
  `(progn (setq ,name ,value)
          ',name))

(defmacro with-forced-defvar-eval (&rest body)
  "While evaluating, any defvars encountered are reevaluated"
  (declare (indent defun))
  (let ((dv-sym (make-symbol "old-defvar")))
    `(let ((,dv-sym (symbol-function 'defvar)))
       (unwind-protect
           (progn
             (fset 'defvar (symbol-function 'my-fake-defvar))
             ,@body)
         (fset 'defvar ,dv-sym)))))

Приклад використання:

file_a.el

(defvar my-var 10)

file_b.el

(with-forced-defvar-eval
  (load-file "file_a.el")
  (assert (= my-var 10))
  (setq my-var 11)
  (assert (= my-var 11)
  (load-file "file_a.el")
  (assert (= my-var 10))

Примітка. Це слід використовувати лише з метою переоцінки дефвараторів, оскільки воно просто ігнорує docstrings при переоцінці. Ви можете змінити макрос, щоб він підтримував переоцінку, яка застосовує доктрини, але це я залишаю вам.

У вашому випадку ви могли б зробити

(with-forced-defvar-eval (require 'some-package))

Але знайте, що роблять ті, хто пише elisp, очікуючи, що defvar працюватиме, як зазначено, можливо, вони використовують defvar для визначення та setq в якійсь функції init, щоб вказати значення, тож ви можете в кінцевому підсумку змінити nil'ing, яких ви не маєте наміру, але це, мабуть, рідко.

Альтернативна реалізація

Використовуючи це, ви можете просто переосмислити defvar у глобальному масштабі та контролювати, чи буде він встановлювати значення символу аргументу INIT-VALUE, навіть якщо символ визначається зміною значення нового defvar-always-reeval-valuesсимволу.

;; save the original defvar definition
(fset 'original-defvar (symbol-function 'defvar))

(defvar defvar-always-reeval-values nil
  "When non-nil, defvar will reevaluate the init-val arg even if the symbol is defined.")

(defmacro my-new-defvar (name &optional init-value docstring)
  "Like defvar, but when `defvar-always-reeval-values' is non-nil, it will set the symbol's value to INIT-VALUE even if the symbol is defined."
  `(progn
     (when defvar-always-reeval-values (makunbound ',name))
     (original-defvar ,name ,init-value ,docstring)))

;; globally redefine defvar to the new form
(fset 'defvar (symbol-function 'my-new-defvar))

defvarПроводиться оцінка та робити саме те , що ви вказали. Однак defvarвстановлює лише початкове значення:

Необов'язковий аргумент INITVALUE оцінюється та використовується для встановлення SYMBOL, лише якщо значення SYMBOL недійсне.

Отже, щоб досягти того, що ви хочете, вам потрібно буде відв'язати змінну перед повторною оцінкою, наприклад

(makunbound 'foo)

або використовувати setqдля встановлення значення, наприклад

(defvar foo nil "My foo variable.")
(setq foo 1)

Якщо тут вам не потрібно вказувати docstring, ви можете пропустити defvarцілком.

Якщо ви дійсно хочете використовувати defvarта автоматично від’єднувати це, вам потрібно буде написати функцію для пошуку defvarвикликів у поточному буфері (або регіоні, або останньому sexp тощо); дзвінок makunboundдля кожного; а потім зробіть фактичну оцінку.

Наступний макрос був створений шляхом відстеження eval-defunйого підтримуючих функцій та модифікації його таким чином, що більше не потрібно оцінювати область певного буфера. Мені потрібна допомога в пов'язаному потоці Перетворення виразу в рядок , і на допомогу прийшов @Tobias - навчив мене перетворювати недосконалу функцію в макрос. Я не думаю, що нам потрібно eval-sexp-add-defvarsпередувати elisp--eval-defun-1, але якщо хтось вважає, що це важливо, будь ласка, дайте мені знати.

;;; EXAMPLE:
;;;   (defvar-reevaluate
;;;     (defvar undo-auto--this-command-amalgamating "hello-world"
;;;     "My new doc-string."))

(defmacro defvar-reevaluate (input)
"Force reevaluation of defvar."
  (let* ((string (prin1-to-string input))
        (form (read string))
        (form (elisp--eval-defun-1 (macroexpand form))))
    form))

Проблема не в тому, що лінія не піддається повторній оцінці. Проблема полягає в тому, що defvarвизначається змінна та її значення за замовчуванням . Якщо змінна вже існує, то зміна її значення за замовчуванням не змінює поточне значення. На жаль, я думаю, вам потрібно буде запустити setqдля кожної змінної, значення якої потрібно оновити.

Це може бути зайвим, але ви можете оновити такий файл, якби ви могли легко оновити fooйого нове значення за замовчуванням.

(defvar foo 2)
(setq foo 2)

але для цього потрібно зберегти значення за замовчуванням у двох місцях коду. Ви також можете це зробити:

(makunbound 'foo)
(defvar foo 2)

але якщо є шанс, який fooдекларується в іншому місці, у вас можуть виникнути деякі побічні ефекти.