Як шукати та замінювати у всьому буфері?

17

Пошук і заміна на, M-%і !, здійснюється з поточного положення до кінця буфера. Як я можу це зробити для всього буфера? Спасибі.

replace

— StackExchange для всіх
джерело

2

Я пропоную змінити назву на "пошук і заміна цілого буфера". В усьому світі також можна згадати цілі проекти.

— Малабарба,

1

Це одна область, де Vim / Evil важко перемогти::%s/foo/bar

— shosti

@shosti: Насправді, я думаю, ваш метод вимагає більше натискань клавіш. Just sayin ';-)

— nispio

14

Я не вважаю, що це підтримується, зберігаючи ваше початкове місце. (Я не бачу способу завернутися до початку буфера, коли пошук досягне кінця.)

Ваша найкраща ставка - M-<це перейти до початку буфера, а потім зробіть query-replace, коли ви закінчите, натисніть, C-uC-spaceC-uC-spaceщоб повернутися до початкової точки.

— Джордон Біондо
джерело

1

Це працює, коли transient-mark-modeвін увімкнено. Інакше C-SPC C-SPCтимчасово ввімкнітьtransient-mark-mode

— nispio

5

Не потрібно встановлювати позначку вручну за допомогою C-SPC. M- <(та багато інших команд, які потенційно "рухають точку довгим шляхом") робить це за вас.

— Матіас Даль

9

Ви можете додати наступну команду до файлу ініціалізації emacs та прив'язати її до клавіші на ваш вибір.

(defun replace-regexp-entire-buffer (pattern replacement)
  "Perform regular-expression replacement throughout buffer."
  (interactive
   (let ((args (query-replace-read-args "Replace" t)))
     (setcdr (cdr args) nil)    ; remove third value returned from query---args
     args))
  (save-excursion
    (goto-char (point-min))
    (while (re-search-forward pattern nil t)
      (replace-match replacement))))

— Сью Д. Німма
джерело

9

Ви можете виконати наступні дії:

C-x h- Виберіть весь буфер або M-< - Перейдіть до верхньої частини буфера
M-% - Ініціювати query-replace
! - Сила замінити всіх
C-u C-SPC C-u C-SPC - Поверніться до вихідної позиції

— Каушал Моді
джерело

На це слід привернути більше уваги.

— Індра

3

Ви можете додати це у свій init.elфайл, щоб оновити поведінку M-%заміни слова у всьому буфері за замовчуванням:

(defun my/query-replace (from-string to-string &optional delimited start end)
  "Replace some occurrences of FROM-STRING with TO-STRING.  As each match is
found, the user must type a character saying what to do with it. This is a
modified version of the standard `query-replace' function in `replace.el',
This modified version defaults to operating on the entire buffer instead of
working only from POINT to the end of the buffer. For more information, see
the documentation of `query-replace'"
  (interactive
   (let ((common
      (query-replace-read-args
       (concat "Query replace"
           (if current-prefix-arg " word" "")
           (if (and transient-mark-mode mark-active) " in region" ""))
       nil)))
     (list (nth 0 common) (nth 1 common) (nth 2 common)
       (if (and transient-mark-mode mark-active)
           (region-beginning)
         (buffer-end -1))
       (if (and transient-mark-mode mark-active)
           (region-end)
         (buffer-end 1)))))
  (perform-replace from-string to-string t nil delimited nil nil start end))
;; Replace the default key mapping
(define-key esc-map "%" 'my/query-replace)

І щоб отримати таку саму поведінку query-replace-regexp:

(defun my/query-replace-regexp (regexp to-string &optional delimited start end)
  "Replace some things after point matching REGEXP with TO-STRING.  As each
match is found, the user must type a character saying what to do with
it. This is a modified version of the standard `query-replace-regexp'
function in `replace.el', This modified version defaults to operating on the
entire buffer instead of working only from POINT to the end of the
buffer. For more information, see the documentation of `query-replace-regexp'"
  (interactive
   (let ((common
      (query-replace-read-args
       (concat "Query replace"
           (if current-prefix-arg " word" "")
           " regexp"
           (if (and transient-mark-mode mark-active) " in region" ""))
       t)))
     (list (nth 0 common) (nth 1 common) (nth 2 common)
       (if (and transient-mark-mode mark-active)
           (region-beginning)
         (buffer-end -1))
       (if (and transient-mark-mode mark-active)
           (region-end)
         (buffer-end 1)))))
  (perform-replace regexp to-string t t delimited nil nil start end))
;; Replace the default key mapping
(define-key esc-map [?\C-%] 'my/query-replace-regexp)

— ніспіо
джерело

Дуже корисний. Спасибі.

— NVaughan

2

Якщо ви використовуєте Icicles, ви можете шукати та замінювати весь буфер (або кілька буферів, файлів або цілей закладок).

І на відміну від query-replace(наприклад C-x h M-%):

Ви можете орієнтуватися в матчах у будь-якому порядку .
Заміна проводиться на вимогу: вам не потрібно відвідувати кожен матч і відповідати, замінювати його чи ні.

— Малював
джерело

0

Це рішення, яке я зараз використовую, воно починається з початку буфера і після заміни повернеться до старої точки.

(defun query-replace-from-top ()
  (interactive)
  (let ((orig-point (point)))
    (save-excursion
      (goto-char (point-min))
      (call-interactively 'query-replace))
    (message "Back to old point.")
    (goto-char orig-point)))
(bind-key* "M-%" 'query-replace-from-top)

— CodyChan
джерело