Спосіб приховати роздільники блоку SRC

13

чи є спосіб зберегти лише вихідний код у вихідному коді, тобто зробити # + BEGIN_SRC та # + END_SRC невидимими? Це косметично, але робить речі зрозумілішими, коли доводиться мати справу з великою кількістю коротких фрагментів коду. Для прикладу:

(defun org-xor (a b)
          "Exclusive or."
          (if a (not b) b))

замість :

  #+BEGIN_SRC emacs-lisp
       (defun org-xor (a b)
          "Exclusive or."
          (if a (not b) b))
  #+END_SRC

org-mode

— loukios
джерело

Мій коментар під питанням у цій напівпов'язаній темі показує, як програмно приховати заголовки / колонтитули вихідного блоку. emacs.stackexchange.com/q/26163/2287 - тобто,

(save-excursion (goto-char (point-max)) (while (re-search-backward "#\\+BEGIN_SRC\\|#\\+END_SRC" nil t) (let ((ov (make-overlay (line-beginning-position) (1+ (line-end-position))))) (overlay-put ov 'invisible t))))

щоб приховати все, використовуйте (remove-overlays). Подальшу роботу потрібно провести для окремих записів і видалити лише вибрані накладки (замість усіх накладок), але це загальна ідея.

— законник

Дякую, це цікаво ... Я пограю з цим.

— loukios

5

Обличчя для всіх ліній, що починаються з #+, називається org-meta-line.

Ви можете налаштувати це обличчя менше, темніше тощо, щоб зробити його менш помітним.

— Хуанчо
джерело

Справді. Як приклад, я створив це за допомогою (set-face-attribute 'org-meta-line nil :height 0.8 :slant 'normal). Я вважаю, що це допомагає трохи.

— Харальд Ханш-Ольсен

Дякую за вашу відповідь, це допомагає. Я змінив висоту btw, але це не має ніякого ефекту ...

— loukios

Дивіться цю документацію Emacs Lisp про параметри, які ви можете призначити org-meta-line gnu.org/software/emacs/manual/html_node/elisp/…

— salotz

4

Я використовую наступний фрагмент коду, який проходить певний шлях. Це не ідеально. Можливо, це стане правильним minor-modeякогось дня. ( джерело ).

(with-eval-after-load 'org
  (defvar-local rasmus/org-at-src-begin -1
    "Variable that holds whether last position was a ")

  (defvar rasmus/ob-header-symbol ?☰
    "Symbol used for babel headers")

  (defun rasmus/org-prettify-src--update ()
    (let ((case-fold-search t)
          (re "^[ \t]*#\\+begin_src[ \t]+[^ \f\t\n\r\v]+[ \t]*")
          found)
      (save-excursion
        (goto-char (point-min))
        (while (re-search-forward re nil t)
          (goto-char (match-end 0))
          (let ((args (org-trim
                       (buffer-substring-no-properties (point)
                                                       (line-end-position)))))
            (when (org-string-nw-p args)
              (let ((new-cell (cons args rasmus/ob-header-symbol)))
                (cl-pushnew new-cell prettify-symbols-alist :test #'equal)
                (cl-pushnew new-cell found :test #'equal)))))
        (setq prettify-symbols-alist
              (cl-set-difference prettify-symbols-alist
                                 (cl-set-difference
                                  (cl-remove-if-not
                                   (lambda (elm)
                                     (eq (cdr elm) rasmus/ob-header-symbol))
                                   prettify-symbols-alist)
                                  found :test #'equal)))
        ;; Clean up old font-lock-keywords.
        (font-lock-remove-keywords nil prettify-symbols--keywords)
        (setq prettify-symbols--keywords (prettify-symbols--make-keywords))
        (font-lock-add-keywords nil prettify-symbols--keywords)
        (while (re-search-forward re nil t)
          (font-lock-flush (line-beginning-position) (line-end-position))))))

  (defun rasmus/org-prettify-src ()
    "Hide src options via `prettify-symbols-mode'.

  `prettify-symbols-mode' is used because it has uncollpasing. It's
  may not be efficient."
    (let* ((case-fold-search t)
           (at-src-block (save-excursion
                           (beginning-of-line)
                           (looking-at "^[ \t]*#\\+begin_src[ \t]+[^ \f\t\n\r\v]+[ \t]*"))))
      ;; Test if we moved out of a block.
      (when (or (and rasmus/org-at-src-begin
                     (not at-src-block))
                ;; File was just opened.
                (eq rasmus/org-at-src-begin -1))
        (rasmus/org-prettify-src--update))
      ;; Remove composition if at line; doesn't work properly.
      ;; (when at-src-block
      ;;   (with-silent-modifications
      ;;     (remove-text-properties (match-end 0)
      ;;                             (1+ (line-end-position))
      ;;                             '(composition))))
      (setq rasmus/org-at-src-begin at-src-block)))

  (defun rasmus/org-prettify-symbols ()
    (mapc (apply-partially 'add-to-list 'prettify-symbols-alist)
          (cl-reduce 'append
                     (mapcar (lambda (x) (list x (cons (upcase (car x)) (cdr x))))
                             `(("#+begin_src" . ?✎) ;; ➤ 🖝 ➟ ➤ ✎
                               ("#+end_src"   . ?□) ;; ⏹
                               ("#+header:" . ,rasmus/ob-header-symbol)
                               ("#+begin_quote" . ?»)
                               ("#+end_quote" . ?«)))))
    (turn-on-prettify-symbols-mode)
    (add-hook 'post-command-hook 'rasmus/org-prettify-src t t))
  (add-hook 'org-mode-hook #'rasmus/org-prettify-symbols))

— расмус
джерело