Режим демона: відкласти інтерактивні підказки при запуску?

(Зауважте, що, наголошуючи на протилежне, це питання не те саме, як запуститись у демон-режимі та придушити інтерактивні діалоги? Оскільки на це питання "відповів" подавець, усуваючи те, що спричиняло появу певного запиту.)

Мені хотілося б знати, чи існує загальний спосіб утриматися emacs --daemonвід вивішування вічно, чекаючи відповіді на підказку, відображену в мінібуфері, який ще не існує.

Підключитися до emacsclient не можна, щоб відповісти на ці підказки, оскільки сервер не запускається, поки Emacs не завершить послідовність запуску. (Це означає, що якщо у вас ALTERNATE_EDITOR встановлено в порожній рядок, завдяки чому emacsclientсервер не може знайти запуск нового демона, ви можете закінчити з декількома демонами Emacs, усі застрягли і чекаючи.) Я повинен killall emacsвирішити проблему перш ніж продовжувати.

Я можу грати з бездротовою моллю з кожною річчю, викликаючи підказку при запуску, коли я її ідентифікую (запускаючи Emacs в недемоновому режимі і бачачи, що він просить), але це не рішення, оскільки він не може зупинити наступний демон від зависання при запуску з нової причини.

Для прикладу: поширена причина, яку вона зависла, - це після перезавантаження системи або аварії Emacs, коли перший Emacs після перезавантаження хотів дізнатися, чи добре вкрасти замкові файли у неіснуючих Emacs. Я міг би це виправити, створюючи поради, щоб цей підказник завжди відповідав "так" без взаємодії. Але потім, один з файлів, який був відкритий на попередньому сеансі збереження, - це файл TRAMP, який вимагає sudo або SSH-пароля, тому демон демонстровно затримався в очікуванні на запит пароля. Тож я це виправляю, вручну редагуючи сесійний файл (з viабо emacs -q!), Щоб видалити файли, які порушують правопорушення, але це не перешкоджає наступному разу.

Отже, я можу припинити завантаження сеансу автоматично під час запуску і змінити його на команду, яку я повинен виконувати вручну з першого мого emacsclient. Але якщо він не завантажує сеанс у фоновому режимі, щоб він був готовий до моменту, коли я готовий його використовувати, вся мета демона втрачається!

Отже, що мені хотілося б:

• (Найкраще) Якимось способом відкласти підказки minibuffer, поки я не відкрию emacsclient, доки не завершую решту ініціалізації.
• (ОК) Якимось способом зробити всі підказки мінібуфера, які я вже не радив, інакше як описано вище, просто повертайтеся, noякщо не працює emacsclient. Я можу жити, коли мої буфери TRAMP помиляються до тих пір, поки це в основному працює.

Чи є спосіб досягти будь-якої з цих цілей?

Під час нашої дискусії з'ясувалося, що у вас немає жодного X-сервера, який працює на цьому, робить моє перше рішення непотрібним для вас.

Далі я представляю друге рішення, яке працює з текстовими термінальними кадрами.

Коли ваша ініціалізація вимагає введення користувачем через один, функції, рекомендовані в avoid-initial-terminalEmacs, чекають, поки ви відкриєте текстовий термінальний кадр. Підказка відображається в мінібуфері цього кадру, і ви можете дати свою інтерактивну відповідь.

Інформація, що стосується коду, подається як коментарі до коду. Є TODOмаркери з описами, які показують, куди потрібно вставити власну конфігурацію. Наразі там є тестові форми, які підтверджують код.

;; TODO: Do here configure the server if needed.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Startup the server:
;; Analysis of read_from_minibuffer in src/minibuf.c and daemon_type in src/emacs.c
;; shows that daemon-initialized must have run before read-passwd / read-string
;; works on frames. Before it only works on stdin & stdout.
(server-start) ;;< early start
(let ((after-init-time before-init-time))
  (daemon-initialized)) ;; Finalize the daemon, 

(advice-add 'daemon-initialized :override #'ignore)
;;< Ignore `daemon-initialized' after initialization. It may only run once!
;; Now the background emacs is no longer marked as daemon. It just runs the server.

(defun prevent-server-start (&rest _ignore)
  "Prevent starting a server one time after `server-start' has been advised with this."
  (advice-remove 'server-start #'prevent-server-start))

(advice-add 'server-start :override #'prevent-server-start)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Prepare waiting for a real terminal frame when user input is required:

(defun avoid-initial-terminal (fun &rest args)
  "Wait until we are no longer on \"intial-terminal\".
Afterwards run `fun' with frame on the other terminal selected."
  (message "Avoiding initial terminal. Terminal: %S" (get-device-terminal nil))
  (while (string-equal
      (terminal-name (get-device-terminal nil))
      "initial_terminal")
    (sleep-for 1))
  ;; (message "Selected frame: %S; Running %S with %S." (selected-frame) fun args)
  (apply fun args))

(advice-add 'read-string :around #'avoid-initial-terminal)

(advice-add 'read-passwd :around #'avoid-initial-terminal)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; TODO: Your initialization that is not daemon related
;; and may require user input:

;; Currently this is just a test.
(read-passwd "Passwd: ")

(read-string "String: ")

(y-or-n-p "y-or-n query")

Тест: Emacs-версія: 26.1

1-й) Запуск emacs --daemonна консолі.

2) Запуск emacsclient --ttyна іншій консолі. Там вас запитують пароль і рядок. Після цього вам також потрібно буде відповісти на y-або-np запит.

Не зовсім те, про що ви просите, але, можливо, рішення вашої початкової проблеми:

Мені хотілося б дізнатися, чи існує загальний спосіб не допустити, щоб emacs -daemon вічно чекав, коли відповідь на підказку відображатиметься в мінібуфері, який ще не існує.

Якщо демон надає вам графічний кадр для відповідей на запитання, що виникають у його стартовій фазі, ви більше не зациклюєтесь.

Код нижче визначає загальну пораду, my-with-initial-frameяка відкриває кадр на першому доступному дисплеї (наприклад, :0.0).

Ця рада може бути легко доданий до запитуючи команди , таких як y-or-n-pабо read-passwd, як це показано нижче.

Просто відкриття кадру дає досить грубу можливість відповідати на запити в інтерфейсі користувача. Можна також скористатися діалоговим вікном для, y-or-n-pале для цього знадобляться спеціальні рішення для певних команд запитів. Я хотів цього уникнути.

Якщо ви спробуєте цей код у своєму файлі init, переконайтеся, що це перше.

(when (daemonp)

  (defun my-with-initial-frame (&rest _)
    "Ensure a frame on display :0.0 and ignore args."
    (let* ((display-list (x-display-list))
           (display-re (and display-list (regexp-opt display-list)))
           (term (and display-re (cl-some (lambda (term) (and (string-match display-re (terminal-name term)) term)) (terminal-list))))
           (frame (and term (cl-some (lambda (frame) (and (frame-live-p frame) frame)) (frames-on-display-list term)))))
      (select-frame (or frame (make-frame-on-display (getenv "DISPLAY"))))))

  (message "Advising querying functions with `my-with-initial-frame'.")
  (advice-add 'y-or-n-p :before #'my-with-initial-frame)
  (advice-add 'read-passwd :before #'my-with-initial-frame))

Тест:

Припущення:

Мати запущений xserver, до якого програми можуть підключатися через DISPLAYзмінну середовища.

Вхід при xterm:

emacs --daemon

emacsclient --eval '(y-or-n-p "A")'

Тут відкривається кадр із y-or-n-pзапитом запиту A (y or n). Дайте відповідь на цей запит і повторіть спробу:

emacsclient --eval '(y-or-n-p "B")'

Новий запит із запитом B (y or n)у тому ж кадрі. Закрийте цей кадр, наприклад, за допомогою C-x 5 0та повторіть спробу:

emacsclient --eval '(y-or-n-p "C")'

Відкриється новий кадр із запитом запиту C (y or n).

Те саме працює і для введення пароля.

Я думаю, що відкладати підказки в цілому буде складно, але змінити Emacs слід досить легко, щоб такі підказки негайно сигналізували про помилку.

Мало того, але якщо ви не можете відповісти на ці підказки без багато гімнастики, я думаю, що це кваліфікується як помилка, тому я рекомендую вам надіслати звіт про помилку.