Покладіть всі резервні копії в одну папку резервного копіювання

Як я можу налаштувати Emacs так, щоб усі резервні копії були розміщені в одній папці резервного копіювання? напр/MyEmacsBackups

Перевірте backup-directory-alist, що дозволяє встановлювати місця резервного копіювання за допомогою файлу regexp. Щоб все перейшло в один каталог, спробуйте щось на кшталт:

(setq backup-directory-alist '(("." . "~/MyEmacsBackups")))

Для справді параноїдальних (як я), є також резервне копіювання кожного збереження , яке (як випливає з назви) створює резервну копію ваших файлів кожного разу, коли вони зберігаються у зручному місці. Це забезпечує додатковий рівень захисту від традиційного контролю версій, наприклад, для тих випадків, коли ви випадково очищаєте робочий каталог, не перевіряючи щось.

Далі короткий код від мого .emacs. Він не тільки створює резервні копії у певному каталозі, але й автоматично зберігає, і робить те ж саме для файлів, що не мають змоги, щоб вони не ставились у віддалену систему.

;; Put backup files neatly away                                                 
(let ((backup-dir "~/tmp/emacs/backups")
      (auto-saves-dir "~/tmp/emacs/auto-saves/"))
  (dolist (dir (list backup-dir auto-saves-dir))
    (when (not (file-directory-p dir))
      (make-directory dir t)))
  (setq backup-directory-alist `(("." . ,backup-dir))
        auto-save-file-name-transforms `((".*" ,auto-saves-dir t))
        auto-save-list-file-prefix (concat auto-saves-dir ".saves-")
        tramp-backup-directory-alist `((".*" . ,backup-dir))
        tramp-auto-save-directory auto-saves-dir))

(setq backup-by-copying t    ; Don't delink hardlinks                           
      delete-old-versions t  ; Clean up the backups                             
      version-control t      ; Use version numbers on backups,                  
      kept-new-versions 5    ; keep some new versions                           
      kept-old-versions 2)   ; and some old ones, too                           

;; put all backup files into ~/MyEmacsBackups
(setq backup-directory-alist '(("." . "~/MyEmacsBackups")))
(setq backup-by-copying t)

Помістіть це у свій файл init. Змініть шлях до обраного каталогу резервного копіювання.

;;backup directory
(setq backup-directory-alist '(("" . "~/.emacs.d/emacs_backup")))