Як правильно вирівняти область та / або лінію?

Ми можемо центрувати текст за допомогою M-x center-regionта M-o M-s. Чи є щось подібне для правильного вирівнювання?

Приклад раніше:

Item 0: value                                                       |
Item 100: value                                                     |
Item 30: value                                                      |

після:

                                                       Item 0: value|
                                                     Item 100: value|
                                                      Item 30: value|
                                                       fill-column  ^

Який найпростіший спосіб вирівняти текст праворуч?

Відповідно до вузла вручну на Заповнення , кілька функцій заливки приймають необов'язковий аргумент JUSTIFY, який ви можете використовувати. Так, наприклад, для заповнення абзацу з правильним обґрунтуванням ви можете скористатися (fill-paragraph 'right).

Ви також можете використовувати (justify-current-line 'right)для одного рядка.

Якщо ви плануєте багато використовувати ці параметри, ви можете обернути їх у такі функції, як наведені нижче, а потім прив’язати ці функції до клавіш на ваш вибір:

(defun right-justify-current-line ()
  "Right-justify this line."
  (interactive)
  (justify-current-line 'right))

(defun right-fill-paragraph ()
  "Fill paragraph with right justification."
  (interactive)
  (fill-paragraph 'right))

Ось функція, яку ви можете застосувати як заміну fill-paragraph. За допомогою різних префіксів можна визначити, яке виправдання використовувати для абзацу, який ви заповнюєте:

(defun fill-paragraph-dwim (&optional arg)
  "Fills the paragraph as normal with no prefix. With C-u,
right-justify.  With C-u C-u, center-justify.  With C-u C-u C-u,
full-justify."
  (interactive "p")
  (fill-paragraph (cond ((= arg 4)  'right)
                        ((= arg 16) 'center)
                        ((= arg 64) 'full))))

Якщо ви не хочете заповнювати, коли ви center-regionвирівнюєте право , ви можете скористатись такою функцією, яка зашифрована безпосередньо з функції, за допомогою однорядкової зміни, щоб зробити її замість вирівнювання правою:

(defun right-region (from to)
  "Right-justify each nonblank line starting in the region."
  (interactive "r")
  (if (> from to)
      (let ((tem to))
    (setq to from from tem)))
  (save-excursion
    (save-restriction
      (narrow-to-region from to)
      (goto-char from)
      (while (not (eobp))
    (or (save-excursion (skip-chars-forward " \t") (eolp))
        ;; (center-line))              ; this was the original code
        (justify-current-line 'right)) ; this is the new code
    (forward-line 1)))))