зробити `delete-duplicate-lines` ігнорувати порожні рядки та певні слова

Я редагую текст в org-режимі, кілька рядків повторюються, оскільки вони містять різні файли з однієї теми.

Я хочу використовувати delete-duplicate-linesдля видалення повторних рядків, однак команда також видаляє порожні рядки, що я не хочу (інакше у мене не було б абзаців!). Я хочу проігнорувати певні слова, які існують окремо в рядках, наприклад, "Резюме" , це багато разів повторюється в тексті, але я хочу зберегти його, оскільки це потрібно.

text-editing

— шакра
джерело

Ігнорування порожніх рядків

Ви можете сказати delete-duplicate-linesігнорувати порожні рядки, зателефонувавши через

C-u C-u C-u M-x delete-duplicate-lines RET

Якщо ви не хочете, щоб C-uпід час дзвінка натискати на стільки разів delete-duplicate-lines, ви можете згорнути його у власну команду та прив’язати цю команду до ключової послідовності на ваш вибір:

(defun delete-duplicate-lines-keep-blanks ()
  (interactive)
  (delete-duplicate-lines (region-beginning) (region-end) nil nil t))

(global-set-key (kbd "C-c d") 'delete-duplicate-lines-keep-blanks)

Ігнорування ліній, що відповідають regexp

Що стосується другої частини вашого питання, я не думаю, що ви можете досягти того, що хочете, використовуючи вбудовану версію delete-duplicate-lines. Однак ви можете використовувати модифіковану версію команди (яка також зберігає порожні рядки за замовчуванням):

(defun delete-duplicate-lines
    (beg end keep &optional reverse adjacent keep-blanks interactive)
  (interactive
   (progn
     (barf-if-buffer-read-only)
     (list (region-beginning) (region-end)
           (read-string "Keep lines matching regexp: ") ; Prompt for regexp to keep
           (equal current-prefix-arg '(4))
           (equal current-prefix-arg '(16))
           t                                            ; Keep blanks by default
           t)))
  (let ((lines (unless adjacent (make-hash-table :test 'equal)))
        line prev-line
        (count 0)
        (beg (copy-marker beg))
        (end (copy-marker end)))
    (save-excursion
      (goto-char (if reverse end beg))
      (if (and reverse (bolp)) (forward-char -1))
      (while (if reverse
             (and (> (point) beg) (not (bobp)))
               (and (< (point) end) (not (eobp))))
        (setq line (buffer-substring-no-properties
                (line-beginning-position) (line-end-position)))
        (if (or (and keep-blanks (string= "" line))
                (string-match keep line))               ; Ignore line if it
                                                        ; matches regexp to keep
            (forward-line 1)
          (if (if adjacent (equal line prev-line) (gethash line lines))
              (progn
                (delete-region (progn (forward-line 0) (point))
                               (progn (forward-line 1) (point)))
                (if reverse (forward-line -1))
                (setq count (1+ count)))
            (if adjacent (setq prev-line line) (puthash line t lines))
            (forward-line (if reverse -1 1))))))
    (set-marker beg nil)
    (set-marker end nil)
    (when interactive
      (message "Deleted %d %sduplicate line%s%s"
               count
               (if adjacent "adjacent " "")
               (if (= count 1) "" "s")
               (if reverse " backward" "")))
    count))

Ця версія програми delete-duplicate-linesзапропонує вам зробити регулярний вираз і збереже всі рядки, що відповідають регулярному. Наприклад, щоб зберегти всі рядки, що складаються зі слова, яке Resumeви виконували б:

M-x delete-duplicate-lines RET ^Resume$ RET

— itjeyd
джерело