Як отримати вихідні дані для порядку денного органу без перегляду порядку денного?

Питання: Як я можу org-modeповернути вихідні дані для перегляду порядку денного, не створюючи власне перегляд порядку денного?

Я хотів би отримати до свого порядку денного довільний день. Однак я не хочу створювати порядок денний сам по собі. Натомість я хочу org-modeзібрати і сортувати всі елементи, які входили б у порядок денний на цей день, і повертати їх (в ідеалі в списку) для подальшої перевірки та маніпуляцій.

Я припускав, що org-agenda-listце саме місце почати. Однак ця функція є заплутаним звіром і, здається, переплітає процеси збирання, сортування та відображення. Я вважаю (сподіваюся?), Що я просто пропустив відповідну функцію десь, яка забезпечує функціонал, за яким я переслідую.

Нижче наводиться скорочений прикладом того , як для отримання даних , який йде в *Org Agenda*буфер , коли зазвичай з допомогою функції org-agenda-list, з org-agenda-entry-typesтакими , як :deadline, :scheduled, :timestamp, sexp, :deadline*, і :scheduled*. Діапазон дат - beginі end- повинен бути в григоріанському форматі списку - наприклад, '(6 1 2015). Налаштовувані обмежені параметри є org-agenda-prefix-formatі org-agenda-entry-types. Функція повертає результат у форматі списку.

(require 'calendar)
(require 'org)
(require 'org-agenda)
(require 'cl)

;; Portions of following code were extracted from:
;;   https://github.com/kiwanami/emacs-calfw written by Masashi Sakurai
;; Said code has been modified by @lawlist hereinbelow.
;;
(defun org-get-entries-fn (begin end)
"Return org schedule items between BEGIN and END.
USAGE:  (org-get-entries-fn '(6 1 2015) '(12 31 2020))"
  (unless
      (and
        (calendar-date-is-valid-p begin)
        (calendar-date-is-valid-p end))
    (let ((debug-on-quit nil))
      (signal 'quit '("One or both of your Gregorian dates are invalid."))))
  (let* (
      result
      (org-agenda-buffer nil) ;; prevent error from `org-compile-prefix-format'
      ;; The variable `org-agenda-only-exact-dates' is apparently not operational.
      (org-scheduled-past-days 0) ;; avoid duplicate entries for overdue items
      (org-agenda-prefix-format "• ")
      (org-agenda-entry-types '(:scheduled))
      (date-after
        (lambda (date num)
          "Return the date after NUM days from DATE."
          (calendar-gregorian-from-absolute
           (+ (calendar-absolute-from-gregorian date) num))))
      (enumerate-days
        (lambda (begin end)
          "Enumerate date objects between BEGIN and END."
          (when (> (calendar-absolute-from-gregorian begin)
                   (calendar-absolute-from-gregorian end))
            (error "Invalid period : %S - %S" begin end))
          (let ((d begin) ret (cont t))
            (while cont
              (push (copy-sequence d) ret)
              (setq cont (not (equal d end)))
              (setq d (funcall date-after d 1)))
            (nreverse ret)))) )
    (org-compile-prefix-format nil)
    (setq result
      (loop for date in (funcall enumerate-days begin end) append
        (loop for file in (org-agenda-files nil 'ifmode) append
          (progn
            (org-check-agenda-file file)
            (apply 'org-agenda-get-day-entries file date org-agenda-entry-types)))))
    result))