Чи можна додати шаблони, крім # + BEGIN_ # + END

9

Я помітив, що org-structure-template-alist змінився (я використовую org-mode версії 9.2) для автоматичного розширення #+BEGIN_<some block tag> #+END_<some block tag>. Цікаво, чи можна додати шаблони різного типу. Наприклад, :PROPERTIES:<some properties>:END:шаблон.

Чи це можливо, або я повинен звернутися до іншого пакету, наприклад, yasnippets?

org-mode

— П’єрБ
джерело

9

ОНОВЛЕННЯ:

Не помічав, що Org Mode 9.2 змінив механізм розширення шаблону, де org-structure-template-alistлише для блоків, визначених "#+BEGIN_"і "#+END_". І такий вхід ("p" ":PROPERTIES:?:END:")більше не приймається.

Як було зазначено у вищенаведеному посиланні, інший "складний" шаблон може бути визначений функцією tempo-define-template, і org-tempo повинен бути завантажений ( (require 'org-tempo)). На насправді записи про org-structure-template-alist перетворюються в org-tempo-tagsчерез tempo-define-templateпо org-tempo, і по org-tempo-tagsзамовчуванням:

(("<i" . tempo-template-org-index)
 ("<A" . tempo-template-org-ascii)
 ("<H" . tempo-template-org-html)
 ("<L" . tempo-template-org-latex)
 ("<v" . tempo-template-org-verse)
 ("<s" . tempo-template-org-src)
 ("<q" . tempo-template-org-quote)
 ("<l" . tempo-template-org-export-latex)
 ("<h" . tempo-template-org-export-html)
 ("<E" . tempo-template-org-export)
 ("<e" . tempo-template-org-example)
 ("<C" . tempo-template-org-comment)
 ("<c" . tempo-template-org-center)
 ("<a" . tempo-template-org-export-ascii)
 ("<I" . tempo-template-org-include))

Для вашого випадку ви можете визначити шаблон:

(tempo-define-template "my-property"
               '(":PROPERTIES:" p ":END:" >)
               "<p"
               "Insert a property tempate")

Нижче відповідь працює лише для версії Org режиму до 9.2

Так, ви можете додати запис до нього так:

(add-to-list 'org-structure-template-alist '("p" ":PROPERTIES:?:END:"))

Тоді в org файл ви вводите <pі TAB, він розшириться до властивості і залишить крапку в позиції ?.

І ви можете знайти більш детальну інформацію в документації змінної, ввівши C-h v org-structure-template-alist RET.

— whatacold
джерело

Дуже корисна відповідь, дякую. Btw, Чи >символ на tempo-define-templateдруку? Якщо ні .... Яка роль його у визначенні?

— Докс

1

Рада, що це допомагає :) Не помилка друку, це означає, що лінія буде відступною, tempo-define-templateвбудована розгортка, детальну інформацію див. У документі .

— whatacold

2

Шкода, з якою вони вносять несумісні зміни в налаштування org-mode, дійсно шкода.

У наведеному нижче коді наведено старі шаблони структури org-mode до версії 9.2. Ця функція org-complete-expand-structure-templateявляє собою чисту копію версії 9.1 і org-try-structure-completionє дещо зміненою версією версії 9.1. (Я там додав перевірку типу.)

Після встановлення цього коду ви можете просто знову використовувати старий шаблон
(add-to-list 'org-structure-template-alist '("p" ":PROPERTIES:?:END:"))
.

(defvar org-structure-template-alist)

(defun org+-avoid-old-structure-templates (fun &rest args)
  "Call FUN with ARGS with modified `org-structure-template-alist'.
Use a copy of `org-structure-template-alist' with all
old structure templates removed."
  (let ((org-structure-template-alist
     (cl-remove-if
      (lambda (template)
        (null (stringp (cdr template))))
      org-structure-template-alist)))
    (apply fun args)))

(eval-after-load "org"
  '(when (version<= "9.2" (org-version))
     (defun org-try-structure-completion ()
       "Try to complete a structure template before point.
This looks for strings like \"<e\" on an otherwise empty line and
expands them."
       (let ((l (buffer-substring (point-at-bol) (point)))
         a)
     (when (and (looking-at "[ \t]*$")
            (string-match "^[ \t]*<\\([a-zA-Z]+\\)$" l)
            (setq a (assoc (match-string 1 l) org-structure-template-alist))
            (null (stringp (cdr a))))
       (org-complete-expand-structure-template (+ -1 (point-at-bol)
                              (match-beginning 1)) a)
       t)))

     (defun org-complete-expand-structure-template (start cell)
       "Expand a structure template."
       (let ((rpl (nth 1 cell))
         (ind ""))
     (delete-region start (point))
     (when (string-match "\\`[ \t]*#\\+" rpl)
       (cond
        ((bolp))
        ((not (string-match "\\S-" (buffer-substring (point-at-bol) (point))))
         (setq ind (buffer-substring (point-at-bol) (point))))
        (t (newline))))
     (setq start (point))
     (when (string-match "%file" rpl)
       (setq rpl (replace-match
              (concat
               "\""
               (save-match-data
             (abbreviate-file-name (read-file-name "Include file: ")))
               "\"")
              t t rpl)))
     (setq rpl (mapconcat 'identity (split-string rpl "\n")
                  (concat "\n" ind)))
     (insert rpl)
     (when (re-search-backward "\\?" start t) (delete-char 1))))

     (advice-add 'org-tempo-add-templates :around #'org+-avoid-old-structure-templates)

     (add-hook 'org-tab-after-check-for-cycling-hook #'org-try-structure-completion)

     (require 'org-tempo)
     ))

— Тобіас
джерело

Чи можна додати шаблони, крім # + BEGIN_ # + END_, до org-structure-template-alist?