"Поп" вікно в кадр

Часто мені вікна автоматично розбиваються, поки я довільно вирішую, що поточний кадр не має достатньої кількості нерухомості для всіх. Коли це відбувається, я вручну видаляю вікно, створюю кадр та перемикаюся на це видалене вікно. Як я можу написати функцію elisp, яка це робить?

Я намагався:

(defun pop-window-into-frame ()
  (interactive)
  (delete-window)
  (make-frame-command)
  (switch-to-prev-buffer))

Але чомусь це не робить те, що я думаю, що повинно.

Спробуйте це замість цього:

(defun my-turn-current-window-into-frame ()
  (interactive)
  (let ((buffer (current-buffer)))
    (unless (one-window-p)
      (delete-window))
    (display-buffer-pop-up-frame buffer nil)))

;; Inspired from `mouse-tear-off-window'.
(defun tear-off-window ()
  "Create a new frame displaying buffer of selected window.
    If window is not the only one in frame, then delete it.
    Otherwise, this command effectively clones the frame and window."
  (interactive)
  (let ((owin  (selected-window))
        (buf   (window-buffer))
        (fr    (make-frame)))
    (select-frame fr)
    (switch-to-buffer buf)
    (save-window-excursion 
      (select-window owin)
      (unless (one-window-p) (delete-window owin)))))

Ця команда, а також наступна, яка нічого не робить, якщо вибране вікно одне у своєму кадрі, є в бібліотеці frame-cmds.el.

(defun tear-off-window-if-not-alone ()
  "Move selected window to a new frame, unless it is alone in its frame.
If it is alone, do nothing.  Otherwise, delete it and create a new
frame showing the same buffer."
  (interactive)
  (if (one-window-p 'NOMINI)
      (message "Sole window in frame")
    (tear-off-window)))