Як шукати арабське слово в тексті без його діакритики / наголосів?

В арабській мові, як і в деяких інших мовах, є те, що називається діакритикою для посилення вимови. Не існує угоди про те, скільки діакритиків слід написати за одне слово. Деякі використовують мінімум (який я вважаю за краще) достатньо, щоб розмежувати вимову, тоді як деякі використовують їх зайво або просто в естетичних каліграфічних цілях. Таким чином, існує велика різниця щодо того, що і скільки діакритиків пов’язано з одним словом. Коли я роблю isearch-forward/backwardнатискання C-s/r, проблема виникає, коли я набираю його в міні-буфері пошуку без діакритики, воно не збігатиметься з тим самим словом у тексті, якби воно було діакритичним, тому завдання пошуку цього слова з його потенційною діакритикою стає завжди незадовільним.

Чи існує спосіб пошуку / повторного пошуку не знати діакритики? Я сподіваюся, що знайдеться відповідь, яку можна розширити на включення regexp C-M-s/rта grepпошук, який я досить часто використовую в кермовому снаряді, щоб шукати слово в багатофайлових проектах з латексу.

Оновлення
Було б добре побачити, що Emacs у всіх своїх пошукових функціях виконує крок відключення тексту (від акцентів / діакритики / ви його називаєте) перед тим, як відповідати кроку як поведінці за замовчуванням, яке може бути вимкнено префіксом на вимогу незалежно від того, яка мова є під рукою. Як правило, коли я шукаю щось, я не сподіваюся, що найкращий редактор (Emacs) зазнає невдачі в цьому дорученні лише через деяку діакритику або акценти, які рідко, якщо коли-небудь знадобляться для виконання мирських завдань з тексту.

Ось приблизний початок, заснований на списку поєднання символів у цій відповіді (а потім розширеному). (Позначивши це вікі спільноти - відредагуйте та вдосконаліть це!)

(defconst arabic-diacritics '(#x064b #x064c #x064d #x064e #x064f #x0650 #x0651 #x0652 #x0653 #x0654 #x0655 #x0670)
  "Unicode codepoints for Arabic combining characters.")
(defconst arabic-diacritics-regexp (regexp-opt (mapcar #'string arabic-diacritics)))

(defconst arabic-equivalents
  '(
    ;; "alef" is equivalent to "alef with hamza above" etc
    (#x0627 #x0623 #x0625 #x0622)))

;; (require 'cl-lib)    
;; (defun arabic-strip-diacritics (string)
;;   (cl-reduce (lambda (s c) (remove c s)) arabic-diacritics :initial-value string))

(defun arabic-search-without-diacritics (string)
  (interactive (list (read-string "Search for: " nil nil nil t)))
  (let ((regexp
         (apply #'concat
                (mapcar (lambda (c)
                          (let ((equivalents (assq c arabic-equivalents)))
                            (concat
                             (if equivalents
                                 (regexp-opt (mapcar #'string equivalents))
                               (regexp-quote (string c)))
                             arabic-diacritics-regexp "*")))
                        string))))
    (search-forward-regexp regexp)))

Отже, якщо буфер містить "الْحَمْدُ لِلَّهِ رَبِّ الْعَالَمِينَ", і я оцінюю (arabic-search-without-diacritics "الحمد لله رب العالمين"), він знаходить текст. Він також працює інтерактивно, як M-x arabic-search-without-diacritics.

Альтернативний підхід:

Ось повний приклад коду, який демонструє, як діакритичні та інші нерозмітні знаки ( Mnвластивість) можуть бути видалені з нормалізованих рядків у збігах regexp. Це працює з наведеними прикладами, і IMO - це правильний підхід.

(defun kill-marks (string)
  (concat (loop for c across string
                when (not (eq 'Mn (get-char-code-property c 'general-category)))
                collect c)))

(let* ((original1 "your Arabic string here")
      (normalized1 (ucs-normalize-NFKD-string original1))
      (original2 "your other Arabic string here")
      (normalized2 (ucs-normalize-NFKD-string original2)))
  (equal
   (replace-regexp-in-string "." 'kill-marks normalized1)
   (replace-regexp-in-string "." 'kill-marks normalized2)))