Чи є ясніппет, який продукує коментар доксигену, що наростає?

10

Для наступної функції C ++:

bool importantStuff(double a, double b);

Він повинен вивести такий фрагмент, можливо, без тегів:

/**
 * <Insert description of importantStuff>
 *
 * @param a <Insert description of a>
 * @param b <Insert description of b>
 * @return <Insert description of the return value>
 */

Я оглянув мережу, але найближче до мене дійшов відповіді - це старе питання, де відповідь залежить від більше не підтримуваного режиму doxymacs.

yasnippet c++

— Рованіон
джерело

Я думаю, c-sharp-modeмає щось таке, що робить це.

— erikstokes

Ви хочете зробити це для нових функцій або існуючих?

— itsjeyd

Задаючи питання, я думав про те, що коментар доксигену генерується з підпису функції.

— Рованіон

4

Я використовую наступне, що являє собою розміщення стандартних доксимаків, заснованих на одній, і себотичних, заснованих на абобо абобо, як уже відповідь - для цього потрібні лише семантичні та ясніппети. Це попередньо заповнює кілька інших заповнювачів yasnippet з відповідною інформацією, а також порівняно з версією або-або.


# -*- mode: snippet -*-
# name: dox
# key: dox
# type: command
# --
(unless (and (fboundp 'semantic-current-tag)
             semantic-mode)
  (error "Semantic required to use dox snippet"))
(let ((tag (senator-next-tag)))
  (while (or (null tag)
             (not (semantic-tag-of-class-p tag 'function)))
    (setq tag (senator-next-tag)))
  (let* ((name (semantic-tag-name tag))
         (attrs (semantic-tag-attributes tag))
         (args (plist-get attrs :arguments))
         (return-name (plist-get attrs :type))
         (idx 1))
    (if (listp return-name)
      (setq return-name (car return-name)))
    (yas/expand-snippet
     (format
      "/**
* @brief ${1:%s}
*
%s
%s*/
"
      name
      (mapconcat
       (lambda (x)
         (format "* @param %s ${%d:Description of %s}"
                 (car x) (incf idx) (car x)))
       args
       "\n")
      (if (and return-name (not (string-equal "void" return-name)))
          (format " * @return ${%d:%s}\n" (incf idx) return-name)
        "")))))

— алексмура
джерело

Це рішення абсолютно працює, але потрібно чекати, коли семантичний режим перегляне весь необхідний код, є трохи громіздким. Я також мав emacs застрявати в нескінченних циклах, якщо замість цього я напишу dox <tab> перед змінною. Але все на цьому світі не може бути: D

— Рованіон

це повинно бути проголосовано вище за вищезазначене, оскільки воно багатше му-доксигену

— Алехандро Еріксон

3

Щойно додав цю функцію до функцій-args .

Ось код, якщо вас цікавить. Він використовує CEDET:

(defun moo-doxygen ()
  "Generate a doxygen yasnippet and expand it with `aya-expand'.
The point should be on the top-level function name."
  (interactive)
  (move-beginning-of-line nil)
  (let ((tag (semantic-current-tag)))
    (unless (semantic-tag-of-class-p tag 'function)
      (error "Expected function, got %S" tag))
    (let* ((name (semantic-tag-name tag))
           (attrs (semantic-tag-attributes tag))
           (args (plist-get attrs :arguments))
           (ord 1))
      (setq aya-current
            (format
             "/**
* $1
*
%s
* @return $%d
*/
"
             (mapconcat
              (lambda (x)
                (format "* @param %s $%d"
                        (car x) (incf ord)))
              args
              "\n")
             (incf ord)))
      (aya-expand))))

Вам також потрібен автоматичний яснеппет . Обидва пакети доступні в MELPA.

— або-або
джерело