Як я можу негайно вийти з ediff, не вводячи "y"

Коли я кидаю едіфф, qмене запитують, чи дійсно я хочу кинути. Я вважаю за краще це негайно кинути. У налаштуваннях немає нічого очевидного . Існує рішення тут , який , здається , на роботу, переглядаючи qключ, але я не впевнений в деталях , як працює функція. Який найпростіший спосіб змусити кинути насправді означати кинути?

Ви можете порадити, ediff-quitщоб він динамічно відновлювався y-or-n-pдо функції, яка повертається t.

(defun disable-y-or-n-p (orig-fun &rest args)
  (cl-letf (((symbol-function 'y-or-n-p) (lambda (prompt) t)))
    (apply orig-fun args)))

(advice-add 'ediff-quit :around #'disable-y-or-n-p)

Це більш надійно щодо змін, що перебувають вгору, ніж перевизначення ediff-quit.

На жаль, я думаю, що вам доведеться або відновлювати q, або коригувати джерело ediff-quit. Як видно в джерелі ediff-quitпідказки завжди буває.

(defun ediff-quit (reverse-default-keep-variants)
  "Finish an Ediff session and exit Ediff.
Unselects the selected difference, if any, restores the read-only and modified
flags of the compared file buffers, kills Ediff buffers for this session
\(but not buffers A, B, C\).

If `ediff-keep-variants' is nil, the user will be asked whether the buffers
containing the variants should be removed \(if they haven't been modified\).
If it is t, they will be preserved unconditionally.  A prefix argument,
temporarily reverses the meaning of this variable."
  (interactive "P")
  (ediff-barf-if-not-control-buffer)
  (let ((ctl-buf (current-buffer))
    (ctl-frm (selected-frame))
    (minibuffer-auto-raise t))
    (if (y-or-n-p (format "Quit this Ediff session%s? "
              (if (ediff-buffer-live-p ediff-meta-buffer)
                  " & show containing session group" "")))
    (progn
      (message "")
      (set-buffer ctl-buf)
      (ediff-really-quit reverse-default-keep-variants))
      (select-frame ctl-frm)
      (raise-frame ctl-frm)
      (message ""))))

Я б запропонував переосмислитись ediff-quitу вашому .emacsі надіслати патч до джерела, додавши змінну налаштування.

Пам’ятайте, що джерело реалізації в emacs завжди знаходиться за декілька натискань клавіш. Припускаючи, що джерела elisp встановлені, введіть C-h f, введіть ім'я функції та перейдіть за посиланням на те, де воно визначено.

Я використовую наступне відновлення q в едіфф. Якщо будь-який з буферів модифікований, він запитує, чи потрібно їх зберегти, тоді він просто закривається. Якщо жодні буфери не змінені, він просто закриється.

(add-hook 'ediff-startup-hook
          (lambda ()
            (local-set-key (kbd"q") 'my-ediff-quit)))

(defun my-ediff-quit ()
  "If any of the ediff buffers have been modified, ask if changes
should be saved. Then quit ediff normally, without asking for
confirmation"
  (interactive)
  (ediff-barf-if-not-control-buffer)
  (let* ((buf-a ediff-buffer-A)
         (buf-b ediff-buffer-B)
         (buf-c ediff-buffer-C)
         (ctl-buf (current-buffer))
         (modified (remove-if-not 'buffer-modified-p
                                  (list buf-a buf-b buf-c))))
    (let ((save (if modified (yes-or-no-p "Save changes?")nil)))
      (loop for buf in modified do
            (progn
              (set-buffer buf)
              (if save
                  (save-buffer)
                (set-buffer-modified-p nil))))
      (set-buffer ctl-buf)
      (ediff-really-quit nil))))