Деякі приклади, як уникнути вибору
Використовуйте Dim'd змінні
Dim rng as Range
Setзмінна до необхідного діапазону. Існує багато способів звернутися до одноклітинного діапазону
Set rng = Range("A1")
Set rng = Cells(1,1)
Set rng = Range("NamedRange")
або багатоклітинний діапазон
Set rng = Range("A1:B10")
Set rng = Range("A1", "B10")
Set rng = Range(Cells(1,1), Cells(10,2))
Set rng = Range("AnotherNamedRange")
Set rng = Range("A1").Resize(10,2)
Ви можете використовувати ярлик до Evaluateметоду, але це менш ефективно і його, як правило, слід уникати у виробничому коді.
Set rng = [A1]
Set rng = [A1:B10]
Всі вищевказані приклади стосуються комірок на активному аркуші . Якщо ви конкретно не хочете працювати лише з активним аркушем, також краще розмітити Worksheetзмінну
Dim ws As Worksheet
Set ws = Worksheets("Sheet1")
Set rng = ws.Cells(1,1)
With ws
Set rng = .Range(.Cells(1,1), .Cells(2,10))
End With
Якщо ви дійсно хочете працювати з ActiveSheet, для ясності , що краще бути явним. Але будьте обережні, оскільки деякі Worksheetметоди змінюють активний аркуш.
Set rng = ActiveSheet.Range("A1")
Знову ж таки, це стосується активної робочої книги . Якщо ви конкретно не хочете працювати лише з ActiveWorkbookабо ThisWorkbook, краще також розмітити Workbookзмінну.
Dim wb As Workbook
Set wb = Application.Workbooks("Book1")
Set rng = wb.Worksheets("Sheet1").Range("A1")
Якщо ви дійсно хочете працювати з ActiveWorkbook, для ясності , що краще бути явним. Але будьте обережні, адже багато WorkBookметодів змінюють активну книгу.
Set rng = ActiveWorkbook.Worksheets("Sheet1").Range("A1")
Ви також можете використовувати ThisWorkbookоб’єкт для позначення книги, що містить запущений код.
Set rng = ThisWorkbook.Worksheets("Sheet1").Range("A1")
Поширений (поганий) фрагмент коду - це відкрити книгу, отримати деякі дані, а потім знову закрити
Це погано:
Sub foo()
Dim v as Variant
Workbooks("Book1.xlsx").Sheets(1).Range("A1").Clear
Workbooks.Open("C:\Path\To\SomeClosedBook.xlsx")
v = ActiveWorkbook.Sheets(1).Range("A1").Value
Workbooks("SomeAlreadyOpenBook.xlsx").Activate
ActiveWorkbook.Sheets("SomeSheet").Range("A1").Value = v
Workbooks(2).Activate
ActiveWorkbook.Close()
End Sub
І краще б:
Sub foo()
Dim v as Variant
Dim wb1 as Workbook
Dim wb2 as Workbook
Set wb1 = Workbooks("SomeAlreadyOpenBook.xlsx")
Set wb2 = Workbooks.Open("C:\Path\To\SomeClosedBook.xlsx")
v = wb2.Sheets("SomeSheet").Range("A1").Value
wb1.Sheets("SomeOtherSheet").Range("A1").Value = v
wb2.Close()
End Sub
Передайте діапазони вашим Subs і Functions як змінні діапазону
Sub ClearRange(r as Range)
r.ClearContents
'....
End Sub
Sub MyMacro()
Dim rng as Range
Set rng = ThisWorkbook.Worksheets("SomeSheet").Range("A1:B10")
ClearRange rng
End Sub
Ви також повинні застосовувати Методи (такі як Findі Copy) до змінних
Dim rng1 As Range
Dim rng2 As Range
Set rng1 = ThisWorkbook.Worksheets("SomeSheet").Range("A1:A10")
Set rng2 = ThisWorkbook.Worksheets("SomeSheet").Range("B1:B10")
rng1.Copy rng2
Якщо ви перебуваєте в циклі за діапазоном комірок, часто краще (швидше) скопіювати значення діапазону спочатку в масив варіантів і перетворити цикл на це
Dim dat As Variant
Dim rng As Range
Dim i As Long
Set rng = ThisWorkbook.Worksheets("SomeSheet").Range("A1:A10000")
dat = rng.Value ' dat is now array (1 to 10000, 1 to 1)
for i = LBound(dat, 1) to UBound(dat, 1)
dat(i,1) = dat(i,1) * 10 'or whatever operation you need to perform
next
rng.Value = dat ' put new values back on sheet
Це невеликий дегустатор того, що можливо.
Selectта / абоActiveSheetт. Д. І зовсім неминуче. Ось приклад, який я знайшов: stackoverflow.com/questions/22796286/…