Як активувати C ++ 11 в CMake?

Коли я намагаюся запустити створений CMake makefile для компіляції своєї програми, я отримую помилку в цьому

діапазон на основі циклів не підтримується в режимі C ++ 98.

Я спробував додати add_definitions(-std=c++0x)до свого CMakeLists.txt, але це не допомогло.

Я також спробував це:

if(CMAKE_COMPILER_IS_GNUCXX)
    add_definitions(-std=gnu++0x)
endif()

Коли я це роблю g++ --version, я отримую:

g ++ (Ubuntu / Linaro 4.6.1-9ubuntu3) 4.6.1

Я також спробував SET(CMAKE_CXX_FLAGS "-std=c++0x"), що теж не працює.

Я не розумію, як я можу активувати функції C ++ 11 за допомогою CMake.

CMake 3.1 представив змінну CMAKE_CXX_STANDARD, яку ви можете використовувати. Якщо ви знаєте, що у вас завжди буде доступний CMake 3.1, ви можете просто записати це у свій файл CMakeLists.txt верхнього рівня або поставити його прямо до того, як буде визначено будь-яку нову ціль:

set (CMAKE_CXX_STANDARD 11)

Якщо вам потрібно підтримувати старіші версії CMake, ось макрос, який я придумав, який ви можете використовувати:

macro(use_cxx11)
  if (CMAKE_VERSION VERSION_LESS "3.1")
    if (CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
      set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=gnu++11")
    endif ()
  else ()
    set (CMAKE_CXX_STANDARD 11)
  endif ()
endmacro(use_cxx11)

Макрос підтримує GCC лише зараз, але слід розширити його на інші компілятори.

Тоді ви можете написати use_cxx11()вгорі будь-який файл CMakeLists.txt, який визначає ціль, яка використовує C ++ 11.

Випуск CMake № 15943 для кланг-користувачів, орієнтованих на macOS

Якщо ви використовуєте CMake та clang для націлювання на macOS, є помилка, яка може призвести до того, що CMAKE_CXX_STANDARDфункція просто не працює (не додайте жодних прапорів компілятора). Переконайтеся, що ви робите одну з таких дій:

• Використовуйте cmake_minimum_required, щоб вимагати CMake 3.0 або новішої версії, або

• Встановіть політику CMP0025 на NEW із наступним кодом у верхній частині файла CMakeLists.txt перед projectкомандою:

  # Fix behavior of CMAKE_CXX_STANDARD when targeting macOS.
  if (POLICY CMP0025)
    cmake_policy(SET CMP0025 NEW)
  endif ()

Команда CMake target_compile_features()використовується для визначення необхідної функції C ++ cxx_range_for. Потім CMake спонукає використовувати стандарт C ++.

cmake_minimum_required(VERSION 3.1.0 FATAL_ERROR)
project(foobar CXX)
add_executable(foobar main.cc)
target_compile_features(foobar PRIVATE cxx_range_for)

Не потрібно використовувати add_definitions(-std=c++11)або змінювати змінну CMake CMAKE_CXX_FLAGS, оскільки CMake переконається, що компілятор C ++ викликається відповідними прапорами командного рядка.

Можливо, ваша програма C ++ використовує інші функції, ніж C ++ cxx_range_for. Глобальна властивість CMake CMAKE_CXX_KNOWN_FEATURESмістить перелік функцій C ++, які ви можете вибрати.

Замість використання target_compile_features()ви також можете чітко вказати стандарт C ++, встановивши властивості CMake CXX_STANDARD та CXX_STANDARD_REQUIREDдля своєї цілі CMake.

Дивіться також мою більш детальну відповідь .

я використовую

include(CheckCXXCompilerFlag)
CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11)
CHECK_CXX_COMPILER_FLAG("-std=c++0x" COMPILER_SUPPORTS_CXX0X)
if(COMPILER_SUPPORTS_CXX11)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
elseif(COMPILER_SUPPORTS_CXX0X)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
else()
        message(STATUS "The compiler ${CMAKE_CXX_COMPILER} has no C++11 support. Please use a different C++ compiler.")
endif()

Але якщо ви хочете пограти з C++11, g++ 4.6.1досить старе. Спробуйте отримати більш нову g++версію.

Найпростіший спосіб встановити стандарт Cxx:

 set_property(TARGET tgt PROPERTY CXX_STANDARD 11)

Детальнішу інформацію див. У документації CMake .

Як виявляється, SET(CMAKE_CXX_FLAGS "-std=c++0x")активує багато функцій C ++ 11. Причина не спрацювала в тому, що заява виглядала так:

set(CMAKE_CXX_FLAGS "-std=c++0x ${CMAKE_CXX_FLAGS} -g -ftest-coverage -fprofile-arcs")

Дотримуючись такого підходу, якось -std=c++0xпрапор був перезаписаний, і він не працював. Встановлення прапорців один за одним або використання методу списку працює.

list( APPEND CMAKE_CXX_FLAGS "-std=c++0x ${CMAKE_CXX_FLAGS} -g -ftest-coverage -fprofile-arcs")

Найпростіший спосіб:

add_compile_options(-std=c++11)

Для CMake 3.8 та новіших ви можете використовувати

target_compile_features(target PUBLIC cxx_std_11)

Це ще один спосіб увімкнути підтримку C ++ 11,

ADD_DEFINITIONS(
    -std=c++11 # Or -std=c++0x
    # Other flags
)

Я стикався з випадками, коли працює лише цей метод, а інші методи виходять з ладу. Можливо, це має щось спільне з останньою версією CMake.

У сучасних CMake (> = 3.1) найкращим способом встановлення глобальних вимог є:

set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

Це означає "Я хочу C ++ 11 для всіх цілей. Це не є обов'язковим. Я не хочу використовувати будь-які розширення GNU чи Microsoft". Що стосується C ++ 17, це все-таки найкращий спосіб IMHO.

Джерело: Увімкнення C ++ 11 і пізніше в CMake

Що для мене працює - це встановити наступний рядок у своєму CMakeLists.txt:

set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")

Встановлення цієї команди активує функції C ++ 11 для компілятора, і після виконання cmake ..команди ви повинні мати можливість використовувати range based for loopsу своєму коді та компілювати його без будь-яких помилок.

Я думаю, що цих двох рядків достатньо.

set(CMAKE_CXX_STANDARD 11)

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")

Якщо ви хочете завжди активувати останній стандарт C ++, ось моє розширення відповіді Девіда Грейсона , зважаючи на недавні доповнення (CMake 3.8 та CMake 3.11) значень 17 та 20 для CMAKE_CXX_STANDARD):

IF (CMAKE_VERSION VERSION_LESS "3.8")
    SET(CMAKE_CXX_STANDARD 14)
ELSEIF (CMAKE_VERSION VERSION_LESS "3.11")
    SET(CMAKE_CXX_STANDARD 17)
ELSE()
    SET(CMAKE_CXX_STANDARD 20)
ENDIF()

# Typically, you'll also want to turn off compiler-specific extensions:
SET(CMAKE_CXX_EXTENSIONS OFF)

(Використовуйте цей код замість set (CMAKE_CXX_STANDARD 11)пов'язаної відповіді.)

Сучасний cmake пропонує більш прості способи налаштування компіляторів для використання конкретної версії C ++. Єдине, що кому потрібно зробити, - це встановити відповідні цільові властивості. Серед властивостей, що підтримуються cmake , такі, які використовуються для визначення способу налаштування компіляторів для підтримки певної версії C ++, є наступними:

• CXX_STANDARDвстановлює стандарт C ++, функції якого вимагаються для створення цілі. Встановіть це як 11орієнтацію на C ++ 11.

• CXX_EXTENSIONS, булева інформація, яка визначає, чи потрібні розширення для компілятора. Встановлюючи це як Offвідключає підтримку будь-якого розширення, що стосується компілятора.

Щоб продемонструвати, ось мінімальний робочий приклад а CMakeLists.txt.

cmake_minimum_required(VERSION 3.1)

project(testproject LANGUAGES CXX )

set(testproject_SOURCES
    main.c++
    )

add_executable(testproject ${testproject_SOURCES})

set_target_properties(testproject
    PROPERTIES
    CXX_STANDARD 11
    CXX_EXTENSIONS off
    )

ОС X і Homebrew LLVM пов'язані:

Не забудьте зателефонувати cmake_minimum_required (VERSION 3.3) та project () після цього!

Або CMake буде вставлено project()неявно перед рядком 1, викликаючи проблеми з виявленням версії Clang і, можливо, іншими видами неполадок. Ось пов'язане питання .