Як змінити схему db на dbo

Я імпортував купу таблиць зі старого сервера sql (2000) до моєї бази даних 2008 року. Всі імпортовані таблиці починаються з моїм ім'ям, наприклад: jonathan.MovieData. У таблиці propertiesвін перераховується jonathanяк схема db. Коли я пишу збережені процедури, тепер я повинен включати jonathan.перед усіма назвами таблиць, що є заплутаним.

Як я можу змінити всі мої таблиці на dbo замість jonathan?

Поточний результат: jonathan.MovieData

Бажаний результат: dbo.MovieData

ALTER SCHEMA dbo TRANSFER jonathan.MovieData;

Дивіться ALTER SCHEMA .

Узагальнений синтаксис:

ALTER SCHEMA TargetSchema TRANSFER SourceSchema.TableName; 

Ви можете виконати наступне, що генерує набір операторів ALTER sCHEMA для всіх ваших табів:

SELECT 'ALTER SCHEMA dbo TRANSFER ' + TABLE_SCHEMA + '.' + TABLE_NAME 
FROM INFORMATION_SCHEMA.TABLES WHERE TABLE_SCHEMA = 'jonathan'

Потім потрібно скопіювати та запустити висловлювання в аналізатор запитів.

Ось старіший сценарій, який зробить це і для вас, я думаю, змінивши власника об'єкта. Я не пробував цього в 2008 році.

DECLARE @old sysname, @new sysname, @sql varchar(1000)

SELECT
  @old = 'jonathan'
  , @new = 'dbo'
  , @sql = '
  IF EXISTS (SELECT NULL FROM INFORMATION_SCHEMA.TABLES
  WHERE
      QUOTENAME(TABLE_SCHEMA)+''.''+QUOTENAME(TABLE_NAME) = ''?''
      AND TABLE_SCHEMA = ''' + @old + '''
  )
  EXECUTE sp_changeobjectowner ''?'', ''' + @new + ''''

EXECUTE sp_MSforeachtable @sql

Зрозумів з цього сайту .

Він також говорить про те, щоб зробити те ж саме для збережених програм, якщо вам потрібно.

USE MyDB;
GO
ALTER SCHEMA dbo TRANSFER jonathan.MovieData;
GO

Справка: ALTER SCHEMA

Перемістити таблицю зі схеми dbo в MySchema:

 ALTER SCHEMA MySchema TRANSFER dbo.MyTable

Перемістити таблицю з MySchema на схему dbo:

 ALTER SCHEMA dbo TRANSFER MySchema.MyTable

Я щойно опублікував це на подібне питання: На сервері sql 2005, як я можу змінити "схему" таблиці, не втрачаючи жодних даних?

Невелике поліпшення відмінного відповіді Саеіда в ...

Я додав exec для самостійного виконання цього коду, і я додав об'єднання вгорі, щоб я міг змінити схему обох таблиць ТА збережених процедур:

DECLARE cursore CURSOR FOR 


select specific_schema as 'schema', specific_name AS 'name'
FROM INFORMATION_SCHEMA.routines
WHERE specific_schema <> 'dbo' 

UNION ALL

SELECT TABLE_SCHEMA AS 'schema', TABLE_NAME AS 'name'
FROM INFORMATION_SCHEMA.TABLES 
WHERE TABLE_SCHEMA <> 'dbo' 



DECLARE @schema sysname, 
 @tab sysname, 
 @sql varchar(500) 


OPEN cursore     
FETCH NEXT FROM cursore INTO @schema, @tab 

WHILE @@FETCH_STATUS = 0     
BEGIN 
 SET @sql = 'ALTER SCHEMA dbo TRANSFER [' + @schema + '].[' + @tab +']'    
 PRINT @sql   
 exec (@sql)  
 FETCH NEXT FROM cursore INTO @schema, @tab     
END 

CLOSE cursore     
DEALLOCATE cursore

Мені теж довелося відновити dbdump, і я виявив, що схема не була dbo - я витратив години, намагаючись отримати студію управління Sql Server або передачу даних візуальної студії, щоб змінити схему призначення ... Я в кінцевому підсумку просто запустив це проти відновленої дамп на новому сервері, щоб отримати речі так, як я хотів.

Ви можете скласти схеми зміни кількох об'єктів бази даних, як описано в цій публікації:

Як змінити схему всіх таблиць, представлень та збережених процедур у MSSQL

Спосіб зробити це для індивідуальної речі:

змінити схему dbo передачі jonathan.MovieData

У мене була аналогічна проблема, але моя схема мала зворотну косу рису. У цьому випадку включіть дужки навколо схеми.

ALTER SCHEMA dbo TRANSFER [DOMAIN\jonathan].MovieData;

Відкрийте SQL Server як обліковий запис SA та натисніть на новий запит за поданими нижче запитами

потім натисніть на Execute, він відкаже всю схему, що належить, назад до облікового запису SA

alter authorization on schema::[db_datareader] to [dbo]
alter authorization on schema::[db_datareader] to [db_datareader]
alter authorization on schema::[db_datawriter] to [dbo]
alter authorization on schema::[db_datawriter] to [db_datawriter]
alter authorization on schema::[db_securityadmin] to [dbo]
alter authorization on schema::[db_securityadmin] to [db_securityadmin]
alter authorization on schema::[db_accessadmin] to [dbo]
alter authorization on schema::[db_accessadmin] to [db_accessadmin]
alter authorization on schema::[db_backupoperator] to [dbo]
alter authorization on schema::[db_backupoperator] to [db_backupoperator]
alter authorization on schema::[db_ddladmin] to [dbo]
alter authorization on schema::[db_ddladmin] to [db_ddladmin]
alter authorization on schema::[db_owner] to [dbo]
alter authorization on schema::[db_owner] to [db_owner]

ms-help: //MS.SQLCC.v9/MS.SQLSVR.v9.en/tsqlref9/html/0a760138-460e-410a-a3c1-d60af03bf2ed.htm

ALTER SCHEMA schema_name TRANSFER securable_name