У Perl, як я стисло перевіряю, чи визначена змінна $ і містить рядок не нульової довжини?

На даний момент я використовую наступний Perl, щоб перевірити, чи визначена змінна та містить текст. definedСпочатку потрібно перевірити, щоб уникнути попередження „неініціалізоване значення“:

if (defined $name && length $name > 0) {
    # do something with $name
}

Чи є кращий (імовірно, більш стислий) спосіб написати це?

Ви часто бачите перевірку на визначеність, тому вам не доведеться мати справу з попередженням про використання значення undef (а в Perl 5.10 воно повідомляє вам про змінну, що порушує):

 Use of uninitialized value $name in ...

Отже, щоб обійти це попередження, люди придумують всілякі коди, і цей код починає виглядати як важлива частина рішення, а не як жувальна гумка та клейка стрічка. Іноді краще показати, що ви робите, явно вимкнувши попередження, якого ви намагаєтеся уникати:

 {
 no warnings 'uninitialized';

 if( length $name ) {
      ...
      }
 }

В інших випадках використовуйте якесь нульове значення замість даних. За допомогою оператора визначеного або Perl 5.10 ви можете вказати lengthявний порожній рядок (визначений і повернути нульову довжину) замість змінної, яка ініціюватиме попередження:

 use 5.010;

 if( length( $name // '' ) ) {
      ...
      }

У Perl 5.12 це трохи простіше, оскільки lengthдля невизначеного значення також повертається undefined . Це може здатися трохи глупотою, але це радує математика, яким я, можливо, хотів би стати. Це не видає попередження, тому це питання існує.

use 5.012;
use warnings;

my $name;

if( length $name ) { # no warning
    ...
    }

Як вказує mobrule, замість невеликої економії ви можете використовувати наступне:

if (defined $name && $name ne '') {
    # do something with $name
}

Ви можете скинути визначений чек і отримати щось ще коротше, наприклад:

if ($name ne '') {
    # do something with $name
}

Але у випадку, коли $nameце не визначено, хоча логічний потік буде працювати так, як передбачалося, якщо ви використовуєте warnings(і вам слід це зробити), ви отримаєте таке застереження:

Використання неініціалізованого значення у рядку ne

Отже, якщо є шанс, який $nameможе бути не визначений, вам дійсно потрібно перевірити визначеність насамперед, щоб уникнути цього попередження. Як зазначає Сінан Унюр, ви можете використовувати Scalar :: MoreUtils, щоб отримати код, який робить саме це (перевіряє визначеність, а потім перевіряє нульову довжину), прямо за допомогою empty()методу:

use Scalar::MoreUtils qw(empty);
if(not empty($name)) {
    # do something with $name 
}

По-перше, оскільки lengthзавжди повертає невід’ємне число,

if ( length $name )

і

if ( length $name > 0 )

еквівалентні.

Якщо у вас все в порядку із заміною невизначеного значення порожнім рядком, ви можете використовувати //=оператор Perl 5.10, який призначає RHS LHS, якщо не визначено LHS:

#!/usr/bin/perl

use feature qw( say );
use strict; use warnings;

my $name;

say 'nonempty' if length($name //= '');
say "'$name'";

Зверніть увагу на відсутність попереджень про неініціалізовану змінну, оскільки $nameїй присвоюється порожній рядок, якщо вона невизначена.

Однак, якщо ви не хочете залежати від встановленої версії 5.10, використовуйте функції, надані Scalar :: MoreUtils . Наприклад, вищезазначене можна записати як:

#!/usr/bin/perl

use strict; use warnings;

use Scalar::MoreUtils qw( define );

my $name;

print "nonempty\n" if length($name = define $name);
print "'$name'\n";

Якщо ви не хочете клаббер $name, використовуйте default.

У випадках, коли мені байдуже, чи є змінна undefрівною '', я зазвичай підсумовую це як:

$name = "" unless defined $name;
if($name ne '') {
  # do something with $name
}

Можна сказати

 $name ne ""

замість

 length $name > 0

Не завжди можна робити повторювані речі простим та елегантним способом.

Просто робіть те, що завжди робите, коли у вас є загальний код, який тиражується у багатьох проектах:

Шукайте CPAN, можливо, хтось уже має код для вас. Для цього випуску я знайшов Scalar :: MoreUtils .

Якщо ви не знайдете на CPAN чогось, що вам подобається, створіть модуль і помістіть код у підпрограму:

package My::String::Util;
use strict;
use warnings;
our @ISA = qw( Exporter );
our @EXPORT = ();
our @EXPORT_OK = qw( is_nonempty);

use Carp  qw(croak);

sub is_nonempty ($) {
    croak "is_nonempty() requires an argument" 
        unless @_ == 1;

    no warnings 'uninitialized';

    return( defined $_[0] and length $_[0] != 0 );
}

1;

=head1 BOILERPLATE POD

blah blah blah

=head3 is_nonempty

Returns true if the argument is defined and has non-zero length.    

More boilerplate POD.

=cut

Тоді у своєму коді назвіть це:

use My::String::Util qw( is_nonempty );

if ( is_nonempty $name ) {
    # do something with $name
}

Або , якщо ви заперечуєте прототипи і не заперечують проти додаткових дужок, пропустити прототип в модулі, і назвати його як: is_nonempty($name).

Відмінна бібліотека Type :: Tiny забезпечує структуру, за допомогою якої можна вбудувати перевірку типу у ваш код Perl. Тут я показую лише найтоншу верхівку айсберга і використовую Type :: Tiny найбільш спрощеним та ручним способом.

Обов’язково перегляньте посібник Type :: Tiny :: для отримання додаткової інформації.

use Types::Common::String qw< NonEmptyStr >;

if ( NonEmptyStr->check($name) ) {
    # Do something here.
}

NonEmptyStr->($name);  # Throw an exception if validation fails

Як на рахунок

if (length ($name || '')) {
  # do something with $name
}

Це не зовсім еквівалентно вашій оригінальній версії, оскільки воно також поверне false, якщо $nameце числове значення 0 або рядок '0', але буде поводитися однаково у всіх інших випадках.

У perl 5.10 (або пізнішої версії) відповідним підходом буде використання замість цього визначеного або оператора:

use feature ':5.10';
if (length ($name // '')) {
  # do something with $name
}

Це вирішить, на основі чого визначати довжину, залежно від того $name, визначено, а не чи відповідає дійсності, тому 0 / '0'буде правильно обробляти ці випадки, але для цього потрібна остання версія perl, ніж доступна багатьом людям.

if ($ name)
{
    #since undef та '' обидва оцінюють як false 
    # це має працювати лише тоді, коли рядок визначений і не порожній ...
    # якщо ви не очікуєте щось на зразок $ name = "0", що є хибним.
    # зауважте, що $ name = "00" не є хибним
}