UltiSnips і YouCompleteMe

У мене на macvim встановлені пучки ultisnips та youcompleteme. Проблема полягає в тому, що ultisnips не працює, оскільки вкладка пов'язана ycm. Я спробував поставити let g:UltiSnipsExpandTrigger = "<s-tab>"так, щоб я міг спровокувати завершення фрагмента за допомогою вкладки shift, але це не працює з незрозумілої причини. Я міг би використовувати кришки як тригер, але поки що я не знайшов способу це зробити.

Хтось із вас використовує ці два додатки разом? Що я можу зробити, щоб змусити роботу "shift-tab"? Чи можете ви порекомендувати ще одну клавішу для запуску фрагментів?

Інший варіант - використання плагіна SuperTab:

" if you use Vundle, load plugins:
Bundle 'ervandew/supertab'
Bundle 'Valloric/YouCompleteMe'
Bundle 'SirVer/ultisnips'

" make YCM compatible with UltiSnips (using supertab)
let g:ycm_key_list_select_completion = ['<C-n>', '<Down>']
let g:ycm_key_list_previous_completion = ['<C-p>', '<Up>']
let g:SuperTabDefaultCompletionType = '<C-n>'

" better key bindings for UltiSnipsExpandTrigger
let g:UltiSnipsExpandTrigger = "<tab>"
let g:UltiSnipsJumpForwardTrigger = "<tab>"
let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"

Тут YouCompleteMe пов'язаний з іншою комбінацією Ctrln, але потім ця комбінація прив’язана до вкладки через SuperTab. UltiSnips і SuperTab грають добре разом, тож ви можете просто прив’язати UltiSnips безпосередньо до вкладки, і все вийде.

Спробуйте цю пропозицію на сторінці відстежувача випусків YouCompleteMe. У вашому .vimrc:

let g:UltiSnipsExpandTrigger="<c-j>"

Хоча цей параметр зробить розширення спільної частини фрагмента відображенням за замовчуванням для стрибків вперед у фрагменті , воно імітує поведінку TextMates, як згадується у довідкових тегах UltiSnips.

Оскільки я зіставив свій ключ Caps Lock в Ctrl, це зіставлення працює досить плавно.

скопіюйте такий код у свій vimrc та насолоджуйтесь. Ця функція буде вирішувати всі проблеми між YCM та UltiSnips.

function! g:UltiSnips_Complete()
    call UltiSnips#ExpandSnippet()
    if g:ulti_expand_res == 0
        if pumvisible()
            return "\<C-n>"
        else
            call UltiSnips#JumpForwards()
            if g:ulti_jump_forwards_res == 0
               return "\<TAB>"
            endif
        endif
    endif
    return ""
endfunction

au BufEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
let g:UltiSnipsJumpForwardTrigger="<tab>"
let g:UltiSnipsListSnippets="<c-e>"
" this mapping Enter key to <C-y> to chose the current highlight item 
" and close the selection list, same as other IDEs.
" CONFLICT with some plugins like tpope/Endwise
inoremap <expr> <CR> pumvisible() ? "\<C-y>" : "\<C-g>u\<CR>"

я маю це у своєму vimrc

"" YouCompleteMe
let g:ycm_key_list_previous_completion=['<Up>']

"" Ultisnips
let g:UltiSnipsExpandTrigger="<c-tab>"
let g:UltiSnipsListSnippets="<c-s-tab>"

ось що я зробив під час своєї першої спроби, але я неправильно написав UltiSnips з Ultisnips .. о, добре, випрацював у підсумку!

Я особисто вирішив не використовувати <tab>з YouCompleteMe, а орієнтуватися в ньому вручну.

Тому я додав це до свого .vimrc:

let g:ycm_key_list_select_completion=[]
let g:ycm_key_list_previous_completion=[]

який просто відключає tabключ для YCM. Замість цього ви використовуєте клавіші руху (стрілки або CTRL-N/ CTRL-P) та вибираєте запис CR. UltiSnips працює за замовчуванням з tab.

Тільки збираючи відповіді Майкласлека, Джої Лю і разом із рішеннями, які я знайшов у цій темі випуску та vimrc цього хлопця , у мене зараз це вирішило майже всі проблеми.

function! g:UltiSnips_Complete()
  call UltiSnips#ExpandSnippet()
  if g:ulti_expand_res == 0
    if pumvisible()
      return "\<C-n>"
    else
      call UltiSnips#JumpForwards()
      if g:ulti_jump_forwards_res == 0
        return "\<TAB>"
      endif
    endif
  endif
  return ""
endfunction

function! g:UltiSnips_Reverse()
  call UltiSnips#JumpBackwards()
  if g:ulti_jump_backwards_res == 0
    return "\<C-P>"
  endif

  return ""
endfunction


if !exists("g:UltiSnipsJumpForwardTrigger")
  let g:UltiSnipsJumpForwardTrigger = "<tab>"
endif

if !exists("g:UltiSnipsJumpBackwardTrigger")
  let g:UltiSnipsJumpBackwardTrigger="<s-tab>"
endif

au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger     . " <C-R>=g:UltiSnips_Complete()<cr>"
au InsertEnter * exec "inoremap <silent> " .     g:UltiSnipsJumpBackwardTrigger . " <C-R>=g:UltiSnips_Reverse()<cr>"

Хоча я знаю, що цей пост трохи старий, я маю власну функцію, яка трохи оптимізованіша, ніж та, яку наведено вище:

function! g:UltiSnips_Complete()
  call UltiSnips#ExpandSnippetOrJump()
  if g:ulti_expand_or_jump_res == 0
    if pumvisible()
      return "\<C-N>"
    else
      return "\<TAB>"
    endif
  endif

  return ""
endfunction

Звичайно, якщо ви просто збережете налаштування, які надав Джоу Лю, а потім просто скористаєтесь цією функцією, все буде працювати чудово!

EDIT: Також я використовую іншу функцію для збільшення функцій зворотного кроку між YouCompleteMe та UltiSnips. Я покажу, що я маю на увазі:

function! g:UltiSnips_Reverse()                                                                                               
  call UltiSnips#JumpBackwards()                                                                                              
  if g:ulti_jump_backwards_res == 0        
    return "\<C-P>"                                                                                                           
  endif                                                                                                                       

  return ""                                                                                                                   
endfunction

Потім просто покладіть це у свій .vimrc:

au BufEnter * exec "inoremap <silent> " . g:UltiSnipsJumpBackwardTrigger . " <C-R>=g:UltiSnips_Reverse()<cr>"

Як і let g:UltiSnipsJumpBackwardTrigger="<s-tab>"і ваш набір!

Я обоє використовую разом. За замовчуванням прив'язок YouCompleteMe <Tab>і <Down>вибрати наступний пункт завершення , а також <S-Tab>і <Up>для вибору попереднього пункту завершення. Ви можете змінити прив'язки YouCompleteMe за допомогою параметрів g: ycm_key_list_select_completion та g: ycm_key_list_previous_completion . Зауважте, що назви цих параметрів нещодавно були змінені, коли параметр був змінений з однієї рядка до списку рядків.

Я встановив плагін UltiSnips після плагіна YouCompleteMe, тому я подумав, що вони суперечать один одному, але насправді мені щось більше заважає:

set paste

Переконайтесь, що вилучите його, .vimrcякщо він присутній.

Хоча багато відповідей справно спрацьовують у цій публікації, я просто хочу сказати, що проблема викликана зіткненням ключів між YCM та UltiSnip, тоді як YCM підтримує фрагменти UltiSnip за замовчуванням, він запускає тригер UltiSnip розширення за замовчуванням <tab>як ключ завершення вибору, так Не буде розширено фрагменти UltiSnip <tab>. Надайте їм різні прив'язки ключів, це вирішить проблему, я особисто використовую <c-nі <c-p>для YCM, і використовую за замовчуванням <tab>UltiSnip. Більш детальну інформацію можна отримати з help youcompletemedoc in vim.

На основі відповіді Зігфрід я використовую таке, що видається більш природним:

let g:ycm_key_list_select_completion = ['<C-j>']
let g:ycm_key_list_previous_completion = ['<C-k>']

let g:UltiSnipsExpandTrigger = "<C-l>"
let g:UltiSnipsJumpForwardTrigger = "<C-j>"
let g:UltiSnipsJumpBackwardTrigger = "<C-k>"

Я також використовую c-hjklприв'язки десь в іншому місці (перехід з панелі на іншу), але це було б лише у звичайному режимі, тому проблем немає.

Я використовую ;для розширення UltiSnips, це так чудово для мене

let g:UltiSnipsExpandTrigger = ";"

Я використовую kj. Це те, що є в моєму.vimrc :

let g:UltisnipsExpandTrigger="kj".

Рідко трапляється, що я натрапляю на слово, яке є kjв ньому. У такому випадку я просто зачекаю пару секунд після введення тексту kта цього типу j.

Як зазначають інші, відображення Cj на ultisnips чудово працює.
let g:UltiSnipsExpandTrigger="<c-j>"

Тепер, якщо піти трохи далі і встановити xcape і використовувати
xcape -e "Shift_L=Control_R|J"

Ви даєте можливість використовувати лише клавішу shift для utlitsnips.