Структура петлі всередині gnuplot?

Чи є спосіб ітеративного отримання даних з декількох файлів та побудови їх на одному графіку в gnuplot. Припустимо, у мене є такі файли, як data1.txt, data2.txt ...... data1000.txt; кожна з яких має однакову кількість стовпців. Тепер я міг написати щось на зразок-

plot "data1.txt" using 1:2 title "Flow 1", \
     "data2.txt" using 1:2 title "Flow 2", \
      .
      .
      .
     "data1000.txt"  using 1:2 title "Flow 6"

Але це було б справді незручно. Мені було цікаво, чи є спосіб прокрутити сюжетну частину в gnuplot.

Напевно є (у gnuplot 4.4+):

plot for [i=1:1000] 'data'.i.'.txt' using 1:2 title 'Flow '.i

Змінна iможе бути інтерпретована як змінна або рядок, тому ви можете зробити щось подібне

plot for [i=1:1000] 'data'.i.'.txt' using 1:($2+i) title 'Flow '.i

якщо ви хочете, щоб лінії були зміщені один від одного.

help iterationДля отримання додаткової інформації введіть у командному рядку gnuplot.

Також обов’язково перегляньте відповідь @ DarioP щодо do forсинтаксису; що дає вам щось ближче до традиційного forциклу.

Погляньте також на do { ... }команду, починаючи з gnuplot 4.6, оскільки вона дуже потужна:

do for [t=0:50] {
  outfile = sprintf('animation/bessel%03.0f.png',t)
  set output outfile
  splot u*sin(v),u*cos(v),bessel(u,t/50.0) w pm3d ls 1
}

http://www.gnuplotting.org/gnuplot-4-6-do/

У мене є сценарій all.p

set ...
...
list=system('ls -1B *.dat')
plot for [file in list] file w l u 1:2 t file

Тут два останні рядки є буквальними, а не евристичними. Тоді я біжу

$ gnuplot -p all.p

Змініть *.datтип файлу, який у вас є, або додайте типи файлів.

Наступний крок: Додайте до ~ / .bashrc цей рядок

alias p='gnuplot -p ~/./all.p'

і помістіть файл у all.pсвій домашній каталог і вуаля. Ви можете побудувати всі файли в будь-якому каталозі, набравши p і enter.

EDIT Я змінив команду, оскільки вона не спрацювала. Раніше він містив list(i)=word(system(ls -1B *.dat),i).

Використовуйте наступне, якщо у вас є дискретні стовпці, щоб побудувати графік у графіку

do for [indx in "2 3 7 8"] {
  column = indx + 0
  plot ifile using 1:column ;  
}

Я хотів використовувати узагальнюючі символи для побудови декількох файлів, часто розміщених у різних каталогах, працюючи з будь-якого каталогу. Рішенням, яке я знайшов, було створення наступної функції в~/.bashrc

plo () {
local arg="w l"
local str="set term wxt size 900,500 title 'wild plotting'
set format y '%g'
set logs
plot"
while [ $# -gt 0 ]
        do str="$str '$1' $arg,"
        shift
done
echo "$str" | gnuplot -persist
}

і використовуйте його, наприклад, як plo *.dat ../../dir2/*.out, для побудови всіх .datфайлів у поточному каталозі та всіх .outфайлів у каталозі, який, як виявляється, знаходиться на рівні вище і викликається dir2.

Ось альтернативна команда:

gnuplot -p -e 'plot for [file in system("find . -name \\*.txt -depth 1")] file using 1:2 title file with lines'