Чи може XSLT вставити поточну дату?

Програма, яку ми використовуємо в моєму офісі, експортує звіти, перекладаючи файл XML, який він експортує разом із файлом XSLT, у XHTML. Я переписую XSLT, щоб змінити форматування та додати більше інформації з вихідного файлу XML.

Я хотів би включити дату створення файлу до остаточного звіту. Але поточна дата / час не включені в оригінальний файл XML, і я не маю контролю над тим, як створюється файл XML. Здається, в XSLT не існує жодної функції дати, яка повертає поточну дату.

Хтось уявляє, як я можу включити поточну дату під час моєї трансформації XSLT?

XSLT 2

Функції дати доступні в оригіналі, такі як:

<xsl:value-of  select="current-dateTime()"/>

Існує також current-date()і current-time().

XSLT 1

Скористайтеся пакетом розширень дати та часу EXSLT.

1. Завантажте пакет дати та часу з GitHub .
2. Витягніть date.xslдо місця розташування ваших файлів XSL.
3. Встановіть заголовок таблиці стилів.
4. Імпорт date.xsl.

Наприклад:

<xsl:stylesheet version="1.0" 
    xmlns:date="http://exslt.org/dates-and-times" 
    extension-element-prefixes="date"
    ...>

    <xsl:import href="date.xsl" />

    <xsl:template match="//root">
       <xsl:value-of select="date:date-time()"/>
    </xsl:template>
</xsl:stylesheet>

Для синтаксичного аналізатора MSXML спробуйте наступне:

<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:msxsl="urn:schemas-microsoft-com:xslt"
                xmlns:my="urn:sample" extension-element-prefixes="msxml">

    <msxsl:script language="JScript" implements-prefix="my">
       function today()
       {
          return new Date(); 
       } 
    </msxsl:script> 
    <xsl:template match="/">

        Today = <xsl:value-of select="my:today()"/>

    </xsl:template> 
</xsl:stylesheet>

Також прочитайте Сценарії таблиць стилів XSLT за допомогою msxsl: script та Розширення XSLT за допомогою JScript, C # та Visual Basic .NET

Чи маєте Ви контроль над перетворенням? Якщо так, ви можете передати поточну дату в XSL і використовувати $ current-date зсередини вашого XSL. Нижче наведено, як ви оголошуєте вхідний параметр, але, знаючи, як ви виконуєте перетворення, я не можу сказати вам, як передавати значення.

<xsl:param name="current-date" />

Наприклад, із сценарію bash використовуйте:

xsltproc --stringparam current-date `date +%Y-%m-%d` -o output.html path-to.xsl path-to.xml

Тоді в xsl ви можете використовувати:

<xsl:value-of select="$current-date"/>

...
    xmlns:msxsl="urn:schemas-microsoft-com:xslt"
    xmlns:local="urn:local" extension-element-prefixes="msxsl">

    <msxsl:script language="CSharp" implements-prefix="local">
        public string dateTimeNow()
        {       
          return DateTime.Now.ToString("yyyy-MM-ddTHH:mm:ssZ"); 
        } 
    </msxsl:script>  
...
    <xsl:value-of select="local:dateTimeNow()"/>

Пізня відповідь, але моє рішення працює в Eclipse XSLT. На момент написання статті Eclipse використовує XSLT 1. Ви можете встановити движок XSLT 2, як Saxon. Або ви можете скористатися наведеним нижче рішенням XSLT 1, щоб вставити поточну дату та час.

<xsl:value-of select="java:util.Date.new()"/>

Це викличе клас даних Java для виведення дати. Це не буде працювати, якщо ви також не введете в <xsl:stylesheet>тег таке визначення "java:" .

<xsl:stylesheet [...snip...]
         xmlns:java="java"
         [...snip...]>

Сподіваюся, це комусь допомагає. Цю просту відповідь мені було важко знайти.

format-date(current-date(), '[M01]/[D01]/[Y0001]') = 09/19/2013
format-time(current-time(), '[H01]:[m01] [z]') = 09:26 GMT+10
format-dateTime(current-dateTime(), '[h1]:[m01] [P] on [MNn] [D].') = 9:26 a.m. on September 19.

посилання: Форматування дат та часу за допомогою XSLT 2.0 та XPath