VBScript - Використання обробки помилок

Я хочу використовувати VBScript для лову помилок та їх реєстрації (тобто при помилці "щось записати"), а потім відновити наступний рядок сценарію.

Наприклад,

Про помилку Поновити далі
'Виконайте крок 1
'Виконайте крок 2
'Виконайте крок 3

Коли на кроці 1 виникає помилка, я хочу, щоб ця помилка реєструвалась (або виконувала з нею інші користувацькі функції), а потім відновлювалась на кроці 2. Чи можливо це? і як я можу це реалізувати?

EDIT: Чи можу я зробити щось подібне?

Про помилку Відновити myErrCatch
'Виконайте крок 1
'Виконайте крок 2
'Виконайте крок 3

myErrCatch:
'помилка журналу
Поновити далі

VBScript не має поняття кидати або ловити винятки, але час виконання забезпечує глобальний об'єкт Err, що містить результати останньої виконаної операції. Ви повинні чітко перевірити, чи властивість Err.Number не дорівнює нулю після кожної операції.

On Error Resume Next

DoStep1

If Err.Number <> 0 Then
  WScript.Echo "Error in DoStep1: " & Err.Description
  Err.Clear
End If

DoStep2

If Err.Number <> 0 Then
  WScript.Echo "Error in DoStop2:" & Err.Description
  Err.Clear
End If

'If you no longer want to continue following an error after that block's completed,
'call this.
On Error Goto 0

Синтаксис "On Error Goto [label]" підтримується Visual Basic та Visual Basic for Applications (VBA), але VBScript не підтримує цю мовну функцію, тому вам доведеться використовувати On Error Resume Next, як описано вище.

Зверніть увагу, що On Error Resume Nextце не глобально. Ви можете помістити свою небезпечну частину коду, наприклад, у функцію, яка буде негайно перервана у разі виникнення помилки, і викликати цю функцію з додатка, що містить OERNоператор прецеденту .

ErrCatch()

Sub ErrCatch()
    Dim Res, CurrentStep

    On Error Resume Next

    Res = UnSafeCode(20, CurrentStep)
    MsgBox "ErrStep " & CurrentStep & vbCrLf & Err.Description

End Sub

Function UnSafeCode(Arg, ErrStep)

    ErrStep = 1
    UnSafeCode = 1 / (Arg - 10)

    ErrStep = 2
    UnSafeCode = 1 / (Arg - 20)

    ErrStep = 3
    UnSafeCode = 1 / (Arg - 30)

    ErrStep = 0
End Function

Ви можете перегрупувати виклики функцій ваших кроків у фасадну функцію:

sub facade()
    call step1()
    call step2()
    call step3()
    call step4()
    call step5()
end sub

Тоді нехай ваша обробка помилок буде у верхній функції, яка викликає фасад:

sub main()
    On error resume next

    call facade()

    If Err.Number <> 0 Then
        ' MsgBox or whatever. You may want to display or log your error there
        msgbox Err.Description
        Err.Clear
    End If

    On Error Goto 0
end sub

Тепер, припустимо, step3()виникає помилка. Так як facade()не обробляють помилки (немає ні On error resume next в facade()), то помилка буде повернута main()і step4()та step5()нічого очікувати виконано.

Тепер обробка помилок перероблена в 1 блоці коду

Я надзвичайно новачок у VBScript, тому це може не вважатися найкращою практикою, або може бути причина, що це не слід робити таким чином, я ще не знаю, але це рішення, яке я придумав, щоб обрізати зменшити кількість коду реєстрації помилок у моєму основному блоці коду.

Dim oConn, connStr
Set oConn = Server.CreateObject("ADODB.Connection")
connStr = "Provider=SQLOLEDB;Server=XX;UID=XX;PWD=XX;Databse=XX"

ON ERROR RESUME NEXT

oConn.Open connStr
If err.Number <> 0 Then : showError() : End If


Sub ShowError()

    'You could write the error details to the console...
    errDetail = "<script>" & _
    "console.log('Description: " & err.Description & "');" & _
    "console.log('Error number: " & err.Number & "');" & _
    "console.log('Error source: " & err.Source & "');" & _
    "</script>"

    Response.Write(errDetail)       

    '...you could display the error info directly in the page...
    Response.Write("Error Description: " & err.Description)
    Response.Write("Error Source: " & err.Source)
    Response.Write("Error Number: " & err.Number)

    '...or you could execute additional code when an error is thrown...
    'Insert error handling code here

    err.clear
End Sub