T-SQL: Перегляд масиву відомих значень

Ось мій сценарій:

Скажімо, у мене є збережена процедура, в якій мені потрібно викликати іншу збережену процедуру за набором конкретних ідентифікаторів; чи є спосіб зробити це?

тобто замість того, щоб робити це:

exec p_MyInnerProcedure 4
exec p_MyInnerProcedure 7
exec p_MyInnerProcedure 12
exec p_MyInnerProcedure 22
exec p_MyInnerProcedure 19

Робимо щось подібне:

*magic where I specify my list contains 4,7,12,22,19*

DECLARE my_cursor CURSOR FAST_FORWARD FOR
*magic select*

OPEN my_cursor 
FETCH NEXT FROM my_cursor INTO @MyId
WHILE @@FETCH_STATUS = 0
BEGIN

exec p_MyInnerProcedure @MyId

FETCH NEXT FROM my_cursor INTO @MyId
END

Моя головна мета - це просто ремонтопридатність (легко видалити / додати ідентифікатори в міру зміни бізнесу), можливість перерахувати всі ідентифікатори в одному рядку ... Продуктивність не повинна бути такою великою проблемою

declare @ids table(idx int identity(1,1), id int)

insert into @ids (id)
    select 4 union
    select 7 union
    select 12 union
    select 22 union
    select 19

declare @i int
declare @cnt int

select @i = min(idx) - 1, @cnt = max(idx) from @ids

while @i < @cnt
begin
     select @i = @i + 1

     declare @id = select id from @ids where idx = @i

     exec p_MyInnerProcedure @id
end

У цьому сценарії я роблю створення табличної змінної для зберігання ідентифікаторів.

  Declare @Ids Table (id integer primary Key not null)
  Insert @Ids(id) values (4),(7),(12),(22),(19)

- (або викликати іншу табличну функцію для створення цієї таблиці)

Потім цикл на основі рядків у цій таблиці

  Declare @Id Integer
  While exists (Select * From @Ids)
    Begin
      Select @Id = Min(id) from @Ids
      exec p_MyInnerProcedure @Id 
      Delete from @Ids Where id = @Id
    End

або ...

  Declare @Id Integer = 0 -- assuming all Ids are > 0
  While exists (Select * From @Ids
                where id > @Id)
    Begin
      Select @Id = Min(id) 
      from @Ids Where id > @Id
      exec p_MyInnerProcedure @Id 
    End

Будь-який із наведених вище підходів набагато швидший, ніж курсор (оголошений щодо звичайних таблиць користувачів). Таблично змінні змінні мають погану репутацію, оскільки при неправильному використанні (для дуже широких таблиць з великою кількістю рядків) вони не ефективні. Але якщо ви використовуєте їх лише для зберігання значення ключа або цілого 4 байта, з індексом (як у цьому випадку) вони надзвичайно швидкі.

використовувати статичну змінну курсора та функцію розділення :

declare @comma_delimited_list varchar(4000)
set @comma_delimited_list = '4,7,12,22,19'

declare @cursor cursor
set @cursor = cursor static for 
  select convert(int, Value) as Id from dbo.Split(@comma_delimited_list) a

declare @id int
open @cursor
while 1=1 begin
  fetch next from @cursor into @id
  if @@fetch_status <> 0 break
  ....do something....
end
-- not strictly necessary w/ cursor variables since they will go out of scope like a normal var
close @cursor
deallocate @cursor

Курсори мають поганий результат, оскільки параметри за замовчуванням при оголошенні щодо таблиць користувачів можуть генерувати багато накладних витрат.

Але в цьому випадку накладні витрати є цілком мінімальними, менше, ніж будь-які інші методи тут. STATIC вказує SQL Server матеріалізувати результати в tempdb, а потім повторити це. Для таких невеликих списків це оптимальне рішення.

Ви можете спробувати, як показано нижче:

declare @list varchar(MAX), @i int
select @i=0, @list ='4,7,12,22,19,'

while( @i < LEN(@list))
begin
    declare @item varchar(MAX)
    SELECT  @item = SUBSTRING(@list,  @i,CHARINDEX(',',@list,@i)-@i)
    select @item

     --do your stuff here with @item 
     exec p_MyInnerProcedure @item 

    set @i = CHARINDEX(',',@list,@i)+1
    if(@i = 0) set @i = LEN(@list) 
end

Я зазвичай використовую наступний підхід

DECLARE @calls TABLE (
    id INT IDENTITY(1,1)
    ,parameter INT
    )

INSERT INTO @calls
select parameter from some_table where some_condition -- here you populate your parameters

declare @i int
declare @n int
declare @myId int
select @i = min(id), @n = max(id) from @calls
while @i <= @n
begin
    select 
        @myId = parameter
    from 
        @calls
    where id = @i

        EXECUTE p_MyInnerProcedure @myId
    set @i = @i+1
end

CREATE TABLE #ListOfIDs (IDValue INT)

DECLARE @IDs VARCHAR(50), @ID VARCHAR(5)
SET @IDs = @OriginalListOfIDs + ','

WHILE LEN(@IDs) > 1
BEGIN
SET @ID = SUBSTRING(@IDs, 0, CHARINDEX(',', @IDs));
INSERT INTO #ListOfIDs (IDValue) VALUES(@ID);
SET @IDs = REPLACE(',' + @IDs, ',' + @ID + ',', '')
END

SELECT * 
FROM #ListOfIDs

Встановіть підключення до вашої БД за допомогою процедурної мови програмування (тут Python) і виконайте там цикл. Таким чином ви також можете зробити складні петлі.

# make a connection to your db
import pyodbc
conn = pyodbc.connect('''
                        Driver={ODBC Driver 13 for SQL Server};
                        Server=serverName;
                        Database=DBname;
                        UID=userName;
                        PWD=password;
                      ''')
cursor = conn.cursor()

# run sql code
for id in [4, 7, 12, 22, 19]:
  cursor.execute('''
    exec p_MyInnerProcedure {}
  '''.format(id))